Pegar Nome do Arquivo ASP em Tempo de Execução

[marceloadeo 0]

Boa Tarde Galera,

 

 

Estou precisando pegar, capturar o nome do arquivo ASP que está em execução, mas não sei como fazer isso, ou melhor, não sei qual função ASP utilizar.

 

Vejamos se me entendem: Digamos que esteja executando o arquivo teste.asp que se encontre dentro de uma pasta projeto na raiz do site site.com.br, ou seja, o caminho virtual dele seria: http://site.com.br/projeto/teste.asp, o que eu desejo é capturar somente o nome do arquivo que está em execução, no caso em tela, seria o nome: teste.asp.

 

Se alguém souber como se faz isto, por favor me ajudem, ok?

 

No aguardo.

 

 

Marcelo.

[xanburzum 169]

olha este exemplo:

 

Public function GetFilename(ByVal strGetPath)
   Dim nPos, strFilename
   Dim strDir
   strFilename = ""
       strGetPath = cstr(strGetPath)
       if Not len(strGetPath) = 0 Then
           nPos = InStrRev(strGetPath, "\", Len(strGetPath))
           if nPos > 0 Then
               strFilename = Right(strGetPath, Len(strGetPath) - nPos)
               'Response.Write strFilename
           End if
           nPos = InstrRev(strGetPath, "\", Len(strGetPath) - nPos)
           if nPos > 0 Then
               strDir = Right(strGetPath, Len(strGetPath) - nPos)
           Else
               strDir = ""
           End if 
       End if
       GetFilename = strFilename
   End function

[augustoclaro 2]

Acredito que Request.ServerVariables("SCRIPT_NAME") funcione..

 

EDIT

Eu não tenha certeza se isto pega somente o nome do arquivo ou se pega o virtual path também. Caso pegue o Virtual Path, use:

 

<%

arr = Split(Request.ServerVariables("SCRIPT_NAME"),"/")

filename = arr(Ubound(arr))

%>

[xanburzum 169]

Este código obtem a URL da página atual que é mostrado na janela de URL do navegador.

 

Adicione o seguinte código a uma página:

 

<%
function curPageURL()
dim s, protocol, port

if Request.ServerVariables("HTTPS") = "on" then
  s = "s"
else
  s = ""
end if  

protocol = strleft(LCase(Request.ServerVariables("SERVER_PROTOCOL")), "/") & s 

if Request.ServerVariables("SERVER_PORT") = "80" then
  port = ""
else
  port = ":" & Request.ServerVariables("SERVER_PORT")
end if  

curPageURL = protocol & "://" & Request.ServerVariables("SERVER_NAME") &_
             port & Request.ServerVariables("SCRIPT_NAME")
end function

function strLeft(str1,str2)
strLeft = Left(str1,InStr(str1,str2)-1)
end function
%>

 

Agora você pode obter a URL da página atual usando a linha:

 

<%
 response.write(curPageURL())
%>

 

Se a sua página tem informação Querystring ,e você deseja, assim você pode tentar um código como este:

 

<%
 response.write(curPageURL() & "?" & Request.ServerVariables("QUERY_STRING"))
%>

 

Se a sua página possui formulário , use o seguinte código:

 

<%
 response.write(curPageURL() & "?" & Request.Form)
%>

 

Você pode obter o nome da página, assim:

<%
function curPageName()
dim pagename

pagename = Request.ServerVariables("SCRIPT_NAME") 

 if inStr(pagename, "/") > 0 then 
   pagename = Right(pagename, Len(pagename) - instrRev(pagename, "/")) 
 end if 

curPageName = pagename
end function

response.write("The current page name is " & curPageName())
%>