Webmail para IIS

[Rodrigo Joe 0]

Boa tarde, Alguém pode indicar um webmail fácil para eu usar em meu servidor? Possuo servidor próprio em um datacenter e tenho acesso direto a ele, podendo, inclusive, alterar configurações do sistema. Rodrigo

[explore 3]

Entra na parte de codigos ASP la tem um webmail muito bom o JMAIL. vem simples mais você depois configura e insere outras coisa como contatos e etc...

 

Nesses dois sites tem o download!!!!! caso você queira em ASp é claro!

 

 

www.wmonline.com.br

www.scriptbrasil.com

[Fabio Oliver 0]

OláExistem varios webmails no mercado, mas depende do que você ta rodando no servidor.Me passa os detalhe e de dou uns toques, tb tenho um dedicado e tive que pesquisar pacas para achar alguns proigramas expecificos para servidor.Se tiver MSN, posta ele.okFabio

[Rodrigo Joe 0]

Estou tentando o JMail, mas aparece o erro abaixo:Microsoft VBScript runtime error '800a004c' Path not found /inbox.asp, line 88 Uso o Mailenable como servidor de e-mail, mas a versão instalada não possui webmail.Rodrigo AzevedoMSN: rodrigoenexus@hotmail.com

[explore 3]

Posta o linha 88 ai da pagina inbox.asp pq comigo não deu erro!!!!!!Falo

[explore 3]

  explore disse:

Posta o linha 88 ai da pagina inbox.asp pq comigo não deu erro!!!!!!Falo

Coloca a linha 88 ai que eu do uma olhada!!!!!!!

[Rodrigo Joe 0]

A página inbox.asp completa:

 

<% @LANGUAGE=VBSCRIPT %>

<% Server.ScriptTimeout = 300 %>

 

<!--#include file ="verify.asp"-->

 

<!-- INBOX.ASP -->

 

<!--#include file ="config.asp"-->

<!--#include file ="include.asp"-->

 

<%

'===WriteJSFunctions()========================================

' Write any JavaScript funcrions that are needed on this page

'=============================================================

Sub WriteJSFunctions()

Comment "BEGIN: JavaScript Functions"

Response.Write "<script language=JavaScript>" & vbCrLf

'====================================================================

' Function checkCheckboxes() - make sure something has been checked!

'====================================================================

Response.Write "function checkCheckboxes() {" & vbCrLf

Response.Write " var docForm=document.inboxForm;" & vbCrLf

Response.Write " var len = docForm.elements.length;" & vbCrLf

Response.Write " for( var i=0 ; i<len ; i++) {" & vbCrLf

Response.Write " if (docForm.elements.name == 'delCheck') {" & vbCrLf

Response.Write " if (docForm.elements.checked != '')" & vbCrLf

Response.Write " return true;" & vbCrLf

Response.Write " }" & vbCrLf

Response.Write " }" & vbCrLf

Response.Write " return false;" & vbCrLf

Response.Write "}" & vbCrLf

'==========================

' Function confirmDelete()

'==========================

Response.Write "function confirmDelete() {" & vbCrLf

Response.Write " if ( !checkCheckboxes() ) {" & vbCrLf

Response.Write " alert('You have not selected anything!');" & vbCrLf

Response.Write " return false;" & vbCrLf

Response.Write " }" & vbCrLf

Response.Write " if ( confirm( ""Are you sure you want to delete the selected messages?"" ) ) {"

Response.Write " document.inboxForm.submit();" & vbCrLf

Response.Write " }" & vbCrLf

Response.Write " return false;" & vbCrLf

Response.Write "}" & vbCrLf

'==============================================================

' Function showMessage()

' This is done by using a function instead of a an HREF link

' so that other behind-the-scenes stuff can be done later

' This seems to create prblems for NS so may have to ditch it!

'==============================================================

Response.Write "function showMessage( ID ) {" & vbCrLf

Response.Write " window.location.href = ""message.asp?ID=""+ID" & vbCrLf

Response.Write " return false;" & vbCrLf

Response.Write "}" & vbCrLf

'==============================================================

Response.Write "</SCRIPT>" & vbCrLf

End Sub

%>

 

<%

'===POPToFile()===============================================

' POPs whole or partial inbox then writes header info to file.

' This info will be retrieved by DisplayPOPHeaders.

'=============================================================

Sub POPToFile(POPType)

Dim doPartialPOP

doPartialPOP = 0

 

If POPType = "partial" Then

doPartialPOP = CInt(messagesPerPage)

End If

 

'=================================================

' In case someone tries to interrupt the process

' A half finished userfile is no good! So we reset

' POPPEDALL and restore it when we're finished.

'=================================================

Session("POPPEDALL") = ""

 

Dim FSO

Set FSO = server.CreateObject ("Scripting.FileSystemObject")

 

'========================================

' Create users folder if it doesn't exist

'========================================

If FSO.FolderExists( usersPhysicalPath ) = False Then

dim fa

set fa=FSO.CreateFolder( usersPhysicalPath )

set fa=nothing

End If

 

'=========================================

' Create user file. Overwrite if it exists

'=========================================

Set foPOPFile = FSO.CreateTextFile(userFileName, true)

 

'===================================

' Open/Create temp user cache file.

'===================================

forAppending = 8

If fso.FileExists( userTempFileName ) = True AND POPType <> "complete" Then

Set foUserTempFile = FSO.OpentextFile(userTempFileName, forAppending)

Else

Set foUserTempFile = FSO.CreateTextFile(userTempFileName, true)

End If

 

Set pop3 = Server.CreateObject( "JMail.POP3" )

 

'======================

' Make a POP connection

'======================

On Error Resume Next

pop3.Connect MyUsername, MyPassword, POP3Server

If Err <> 0 Then

Session("ATTACHMENTS") = ""

Session("USERNAME") = ""

Session("PASSWORD") = ""

Session("MAILACCESS") = ""

Session("CURRENTPAGE") = ""

Session("POPPEDALL") = ""

Response.redirect "login.asp?error=1"

End If

 

pop3Count = pop3.Count

 

'==============================================

' If there are not so many messages then there

' is no point in doing a partial POP

'==============================================

If pop3Count <= messagesPerPage Then

doPartialPOP = 0

End If

 

'=============================

' See how many messages to POP

'=============================

If doPartialPOP > 0 Then

'=================================================

' Partial POP so only POP enough to fill the page

'=================================================

If Request.QueryString("PG") = "" Then

thisPage = 0

Else

thisPage = Request.QueryString("PG")

End If

 

startMsg = (thisPage * messagesPerPage) + 1

endMsg = startMsg + messagesPerPage - 1

If endMsg > pop3Count Then

endMsg = pop3Count

End If

Else

'=====================

' POP the whole inbox

'=====================

startMsg = 1

endMsg = pop3Count

End If

 

'========================================================

' The first line just contains the pop3Count value.

' This is useful because it avoids getting an empty file.

'========================================================

foPOPFile.writeLine( pop3Count )

 

if pop3Count > 0 then

For j = startMsg To endMsg

'======================================================

' strPOPItem will contain all the info for this message

'======================================================

strPOPItem = ""

 

'==============================================================

' Get messages in reverse order so the latest appear at the top

'==============================================================

messageID = pop3Count + 1 - j

 

'=============

' 0: messageID

'=============

strPOPItem = strPOPItem & messageID

 

Set msg = pop3.Messages.item( messageID )

 

'===============================================================

' strReplyFrom is the first recipient with a valid email@domain

' which will be used as "FROM" address when replying.

'===============================================================

strReplyFrom = ""

 

' Note the first element of this array is 1

' since the POP3 server starts counting at 1

ReTo = ""

ReCC = ""

 

Set Recipients = msg.Recipients

separator = ", "

 

' We now need to get all the recipients,

' both normal and Carbon Copy (CC) recipients

' and store them in a variable

For i = 0 To Recipients.Count - 1

If i = Recipients.Count - 1 Then

separator = ""

End If

 

Set re = Recipients.item(i)

 

If re.ReType = 0 Then

' Add to TO list

ReTo = ReTo & re.EMail & separator

' Set strReplyFrom if not set

If ( strReplyFrom = "" ) AND ( GetFromAddress(re.EMail) <> "" ) Then

strReplyFrom = re.EMail

End If

else

' Add to CC list

ReCC = ReCC & re.EMail & separator

' Set strReplyFrom if not set

If ( strReplyFrom = "" ) AND ( GetFromAddress(re.EMail) <> "" ) Then

strReplyFrom = re.EMail

End If

End If

Next

 

'============

' 1: msg.From

'============

strPOPItem = strPOPItem & msgTOKEN & msg.From

 

 

'==================

' 2: msg.Attachment

'==================

Set Attachment = msg.Attachments

If Attachment.Count > 0 Then

strPOPItem = strPOPItem & msgTOKEN & 1

Else

strPOPItem = strPOPItem & msgTOKEN & 0

End If

 

'=====================

' 3: Unique URL (MSG)

'=====================

strPOPItem = strPOPItem & msgTOKEN & DateToNumber(msg.Date) & "." & msg.From

 

'===============

' 4: msg.Subject

'===============

If msg.Subject <> "" Then

strPOPItem = strPOPItem & msgTOKEN & msg.Subject

Else

strPOPItem = strPOPItem & msgTOKEN & "(no subject)"

End If

 

'============

' 5: msg.Date

'============

strPOPItem = strPOPItem & msgTOKEN & Left(msg.Date, 10)

 

'=====================

' 6: strReplyFrom

'=====================

strPOPItem = strPOPItem & msgTOKEN & strReplyFrom

 

'======================================

' Write the complete strPOPItem to file

'======================================

foPOPFile.writeLine( strPOPItem )

foUserTempFile.writeLine( strPOPItem )

 

'=====================

' Get the next message

'=====================

Next 'For j = startMsg To endMsg

 

End if ' If popCount > 0

 

foPOPFile.close

foUserTempFile.close

set foPOPFile = nothing

set foUserTempFile = nothing

pop3.Disconnect

Set FSO = nothing

 

If doPartialPOP > 0 Then

Session("POPPEDALL") = ""

Else

Session("POPPEDALL") = "yes"

End If

End Sub

 

'===DisplayPOPHeaders()========================================

' This displays the whole inbox as saved in the userfile.

' First the page head + selector menu, then a list of message

' headings displayed in date order (newest at the top)

'==============================================================

Sub DisplayPOPHeaders()

Dim arrPOPArray

arrPOPArray = fileToArray(userFileName)

 

'=========================================================

' Remember: the first line contains the number of messages

'=========================================================

pop3Count = CInt(arrPOPArray(0))

 

'==============================================================

' Double check before we start. Is arrPOPArray really an array

' and if it is...does it contain a list of messages.

'==============================================================

If VarType(arrPOPArray) <> 0 AND UBound(arrPOPArray) > 0 Then

'===============

' Start display

'===============

If Request.QueryString("PG") = "" Then

thisPage = 0

Else

thisPage = Request.QueryString("PG")

End If

 

startMsg = (thisPage * messagesPerPage) + 1

endMsg = startMsg + messagesPerPage - 1

If endMsg > pop3Count Then

endMsg = pop3Count

End If

 

Comment "BEGIN: draw main page table"

 

Response.Write "<TABLE class=tableOuter cellpadding=""1"" cellspacing=""1"" WIDTH=""100%""><TR><TD>" & vbCrLf

 

Comment "BEGIN: page top half - titles + page menu"

Response.Write "<form name=inboxForm action=""deleteSelected.asp?action=doDelete"" method=post>"

Response.Write "<table class=tableCaption cellspacing=0 cellpadding=0 border=0 width=100% bgcolor=""#444444"">" & vbCrLf

Response.Write "<tr class=captionRow><td align=left>" & vbCrLf

Response.Write "<span class=captionHeading> Inbox - " & MyUsername & "</span>" & vbCrLf

Response.Write "</td><td align=right> " & vbCrLf

Response.Write "<a HREF=""inbox.asp?PG=" & thisPage & "&REFRESH=all""><img align=absmiddle border=0 src=""pop.gif"" alt=""POP the whole inbox""></a> " & vbCrLf

Response.Write "<a HREF=""inbox.asp?PG=" & thisPage & "&REFRESH=true""><img align=absmiddle border=0 src=""refresh.gif"" alt=""Refresh this page""></a> " & vbCrLf

Response.Write "<a href=""compose.asp""><img align=absmiddle border=0 src=""compose.gif"" alt=""Compose a new message""></a> " & vbCrLf

Response.Write "<a href=""logout.asp""><img align=absmiddle border=0 src=""logout.gif"" alt=""Logout""></a>" & vbCrLf

Response.Write "</td></tr></table>" & vbCrLf & vbCrLf

 

Response.Write "<table class=tableInner bgcolor=""#444444"" cellspacing=1 cellpadding=1 border=0 width=""100%"">" & vbCrLf

 

Response.Write "<tr class=inboxTopRow height=60>" & vbCrLf

Response.Write "<td colspan=6>" & vbCrLf

Response.Write "<TABLE width=""100%""><TR><TD><SPAN class=inboxTopHeading>" & vbCrLf

Response.Write "You have " & pop3Count & " messages." & vbCrLf

Response.Write "</SPAN><BR></TD><TD align=right>" & vbCrLf

drawPageMenu thisPage, startMsg, endMsg, pop3Count

Response.Write "</td></tr></TABLE>" & vbCrLf

Response.Write "</td></tr>" & vbCrLf

 

if pop3Count > 0 then

 

Comment "BEGIN: list of message titles"

'===================================================

' Create the headings for the list of message titles

'===================================================

Response.Write "<tr class=titleRow>" & vbCrLf

Response.Write "<td> </td>" & vbCrLf

 

Response.Write "<td> <font class=inboxFieldTitle>From</font></td>" & vbCrLf

Response.Write "<td> <font class=inboxFieldTitle>Subject</font></td>" & vbCrLf

Response.Write "<td> <font class=inboxFieldTitle>Date</font></td>" & vbCrLf

Response.Write "<TD><A class=defaultLink HREF=""#"" onclick=""return confirmDelete()"">"

Response.Write "<img align=absmiddle border=0 width=20 height=20 src=""delete.gif"" alt=""Delete selected messages""></A>" & vbCrLf

Response.Write "</TD>" & vbCrLf

 

Response.Write "</tr>" & vbCrLf

 

'====================================

' Output the list of message titles

'====================================

For j = startMsg To endMsg

 

Comment "Message: " & j

 

'========================================================================

' Remember: If this is a partial POP there will only be "messagesPerPage"

' items in the list so messageID will have to be adjusted accordingly

'========================================================================

If UBound(arrPOPArray) > messagesPerPage+1 AND Session("POPPEDALL") = "yes" Then

messageID = j

Else

messageID = j - (messagesPerPage*thisPage)

End If

 

arrMsgItem = split( arrPOPArray(messageID) , msgTOKEN )

 

'==================

' List of messages

'==================

Response.Write "<TR class=messageRow>" & vbCrLf

 

Response.Write "<TD align=center>" & vbCrLf

Response.Write "<img border=0 width=3 height=10 src=""dotclear.gif"" alt="""">"

Response.Write "<A class=""defaultLink"" HREF=""reply.asp"

Response.Write "?ID=" & arrMsgItem(msgID)

Response.Write "&TO=" & arrMsgItem(msgSTRREPLYFROM)

Response.Write """><img align=absmiddle border=0 width=20 height=20 src=""oldmail.gif"" alt=""Reply""></A> " & vbCrLf

Response.Write "</TD>"

 

Response.Write "<TD> " & arrMsgItem(msgFROM) & " </TD>" & vbCrLf

Response.Write "<TD> "

 

If showAttachments > 0 Then

If arrMsgItem(msgATTACHMENT) <> "0" Then

Response.Write "<img src=""clip.gif"" width=11 height=16 border=0> "

End If

End If

 

Response.Write "<A class=""messageLink"" HREF=""message.asp"

Response.Write "?MSG=" & arrMsgItem(msgUNIQUEURL) & """"

 

'Response.Write " onClick=""return(showMessage(" & arrMsgItem(msgID) & "))"""

Response.Write ">"

Response.Write arrMsgItem(msgSUBJECT)

 

Response.Write "</A></TD>" & vbCrLf

Response.Write "<TD NOWRAP> " & arrMsgItem(msgDATE) & " </TD>" & vbCrLf

 

' Menu items [reply] [delete]

Response.Write "<TD width=5 align=center valign=middle><input type=checkbox name=delCheck value=""" & arrMsgItem(msgID) & """></TD>" & vbCrLf

Response.Write "</TD></tr>" & vbCrLf

 

'===========================================

' Get the next message string from the array

'===========================================

Next 'For j = startMsg To endMsg

 

End if

Response.Write "</form>"

Response.Write vbCrLf & "</TABLE>" & vbCrLf

Response.Write "</TD></TR></TABLE>" & vbCrLf

 

'=======================

' End displayPOPHeaders

'=======================

End If 'If VarType(arrPOPArray) <> 0 AND UBound(arrPOPArray) > 0

 

End Sub

 

'===drawPageMenu()=======================================================

' This draws the page menu for when there are more messages in the inbox

' than the messagesPerPage limit which is set in config.asp

'========================================================================

Sub drawPageMenu( thisPage, startMsg, endMsg, messageCount )

Comment "BEGIN: Draw page menu"

Comment "startMsg:" & startMsg & ", endMsg:" & endMsg & ", messageCount:" & messageCount

 

'======================================================

' If messageCount = 0 then don't display the page menu

'======================================================

If messageCount = 0 Then

Response.Write "<SPAN class=menuHeading>"

Response.Write " "

Response.Write "</SPAN><BR>" & vbCrLf

Comment "END: Draw page menu - nothing drawn"

Exit Sub

End If

 

Response.Write "<SPAN class=menuHeading>"

Response.Write "message " & startMsg & " to " & endMsg

Response.Write "</SPAN><BR>" & vbCrLf

remainder = messageCount mod messagesPerPage

numPages = (messageCount-remainder)/messagesPerPage

numPages = CInt(numPages)

thisPage = CInt(thisPage)

 

If remainder > 0 Then

numPages = numPages + 1

End If

 

If thisPage > 0 Then

previousPage = thisPage - 1

Response.Write "<A class=pageMenu HREF=""inbox.asp?PG=" & previousPage

Response.Write """ alt=""previous page"">[<<]</A> " & vbCrLf

Else

Response.Write "<SPAN class=inactiveLink>[<<]</SPAN> " & vbCrLf

End If

 

For i = 0 to numPages-1

If i = thisPage Then

Response.Write "<SPAN class=thisPage>" & (i+1) & "</SPAN> " & vbCrLf

Else

Response.Write "<A class=pageMenu HREF=""inbox.asp?PG=" & i

Response.Write """>" & (i+1) & "</A> " & vbCrLf

End If

Next

 

If thisPage < numPages-1 Then

nextPage = thisPage + 1

Response.Write "<A class=pageMenu HREF=""inbox.asp?PG=" & nextPage

Response.Write """ alt=""next page"">[>>]</A>" & vbCrLf

Else

Response.Write "<SPAN class=inactiveLink>[>>]</SPAN>" & vbCrLf

End If

Comment "END: Draw page menu"

End Sub

%>

 

<!--#include file ="top.inc"-->

 

<%

Session("ATTACHMENTS") = ""

 

WriteJSFunctions

%>

 

<%

'=========================================

' For debugging purposes only

'=========================================

'Comment "Browser detected: " & browserID

'Comment "POP3Server: " & Session("MAILSERVER")

'Comment "SMTPServer: " & Session("SMTPSERVER")

'Comment "DomainName: " & GetDomainName( Session("USERNAME") )

'================================================================

' POPToFile is called if this is the first login or a specific

' refresh of the inbox is requested.

' If Session("POPPEDALL") = "yes" then the whole inbox has been

' POP'ed and so the existing list (cached in userfile) is used on

' every subsequent return to the inbox until user re-POPs.

'================================================================

Dim FSO

Set FSO = server.CreateObject ("Scripting.FileSystemObject")

If FSO.FileExists( userFileName ) = False OR Session("POPPEDALL") <> "yes" OR Request.Querystring("REFRESH") <> "" Then

If Request.Querystring("refresh") = "all" OR Session("PARTIALLOGIN") = "off" Then

PopToFile("complete")

Session("PARTIALLOGIN") = ""

Else

PopToFile("partial")

End If

End If

 

DisplayPOPHeaders

Set FSO = nothing

%>

 

<!--#include file ="bottom.inc"-->

[gastao 0]

isso ae, é o gastao de volta....procure por cmailserver no google...é um servidopr de email junto com um webmal, fantastico!!! depois pega o crack

[Rodrigo Joe 0]

Infelizmente não tem como usar sofware pirata em meu servidor que fica em um datacenter. Se alguém souber de webmails gratuitos de qualidade.

[explore 3]

Cara ta dando erro na linha 88!!!!!

 

Primeiro esqueci de avisar, você deve configurar a pagina config.asp!!!!!

 

la tem vo explicar como configurar

 

Aqui você configura os dados de conexão, ou seja verificação

da existencia do seu suporte a Webmail!!!!

 

ASP [/tr][tr]MyAddresses = "seuserver@seuprovedor.com.br"

 

MyName = "Seu Nome"

'

MyDomain = "seuDominio.com.br"

[/tr]

 

Depois você configura a parte de pop3, resgata as confiruações de Envio e Recebimento de MSG!!!!!!

 

ASP [/tr][tr]MyPOP3 = "pop3.seuservervidor.com.br"

MySMTP = "smtp.seuservidor.com.br"

[/tr]

 

Ai tem uma coisa, se seu servidor quarda os email dos clientes separado por pastas, Você deve configurar a pagina config.asp para achar o @ no input (digitado no Form)!

 

Tive que fazer isto no webmail, o servidor mudou e separo tudo por pasta, tive que configurar o @ do input digitado!!!!!!!

 

Falo!!!!!!!!!!

[Rodrigo Joe 0]

Acredito que o problema esteja ocorrendo devido a configuração do local dos e-mails. Meu servidor de e-mail organiza as mensagens conforme abaixo:C:\Program Files\Mail Enable\Postoffices\portaldocomercio.com\MAILROOT\rodrigo\Inboxonde:"portaldocomercio.com" é o domínio"rodrigo" refere-se a conta rodrigo@portaldocomercio.com Nem imagino como fazer para configurar o webmail para procurar nesta pasta.

[explore 3]

  Rodrigo Joe disse:

Nem imagino como fazer para configurar o webmail para procurar nesta pasta.

Não cara!!!!!!!

 

Isso é feito no Servidor, é automatico a unica coisa que você deve fazer é configurar o recebimento e e envio como te passei la em cima!!!!!!!

 

Aqui vai ser assim, vo colocar o meu email e minha config para você ter uma ideia!

 

ASP [/tr][tr]MyAddresses = "ProgramadorWeb@provedor1.com.br" 'aqui seu email, esse email não interfere em nada é só para o servidor verificar o provedor depois do @

 

MyName = "Provedor1" 'nome do dominio

'

MyDomain = "provedor1.com.br" 'seu dominio sem www.

[/tr]

 

Envio e recebimento de msg!

 

ASP [/tr][tr]MyPOP3 = "pop3.provedor1.com.br" ' aqui você muda de acordo com o seu

MySMTP = "smtp.provedor1.com.br" ' aqui você muda de acordo com o seu

[/tr]

 

Cara posta só a linha 88 e não o codigo inteiro!!!!!!!!

 

 

Falo!!!!!

[Rodrigo Joe 0]

A linha 88 é a seguinte: set fa=FSO.CreateFolder( usersPhysicalPath ) Esta inserida dentro de: '======================================== ' Create users folder if it doesn't exist '======================================== If FSO.FolderExists( usersPhysicalPath ) = False Then dim fa set fa=FSO.CreateFolder( usersPhysicalPath ) set fa=nothing End IfRodrigo :blink:

[explore 3]

tenta assim:

 

ASP [/tr][tr]

If FSO.FolderExists( usersPhysicalPath ) = False Then

dim fa, FSO

set FSO.CreateFolder( usersPhysicalPath )

if fa = FSO then

set fa=nothing

End If

End if

[/tr]

[Rodrigo Joe 0]

Ocorre o erro:Microsoft VBScript compilation error '800a0411' Name redefined /inbox.asp, line 87 dim fa, FSO--------^A variável FSO já foi definida no início do código, mas não deu certo.

[Mário Monteiro 179]

você já definiu esta variavel antes dve tirar os essa ou a definição anterior....

[Rodrigo Joe 0]

'======================================== ' Create users folder if it doesn't exist '======================================== If FSO.FolderExists( usersPhysicalPath ) = False Then dim faset FSO.CreateFolder( usersPhysicalPath )if fa = FSO thenset fa=nothingEnd IfEnd if Está correto? Mas mesmo assim dá erro ao acesso a páginaA página não pode ser exibida Há um problema com a página que você está tentando acessar e ela não pode ser exibida. --------------------------------------------------------------------------------Tente o seguinte:Abra a mail.portaldocomercio.com home page, e procure os links para as informações desejadas. Clique no botão Atualizar ou tente novamente mais tarde.Clique em Pesquisar para procurar informações na Internet. Você também pode ver uma lista de sites relacionados. HTTP 500 - erro interno do servidor Internet Explorer

[explore 3]

Cara acredito que esteja certo mesmo pq aqui funciona!!!!!Olhe as configurações do Server deve ser por isso!!!!!!!Falo!!!!!!!!!!!

[Mário Monteiro 179]

cara erro interno de servidor...desabilita as mensagem de erro amigaveis em seu navegador que mostrará o erro real...

[Rodrigo Joe 0]

Exibiu este erro:Microsoft VBScript compilation error '800a03f3' Expected '=' /inbox.asp, line 88 set FSO.CreateFolder( usersPhysicalPath )-----------------------------------------^ Mas a linha 88 é a seguinte:set FSO.CreateFolder( usersPhysicalPath ) E faz parte do conjunto abaixo: If FSO.FolderExists( usersPhysicalPath ) = False Then dim faset FSO.CreateFolder( usersPhysicalPath )if fa = FSO thenset fa=nothingEnd IfEnd if E agora quem poderá me ajudar? :-)