Ir para conteúdo

POWERED BY:

Arquivado

Este tópico foi arquivado e está fechado para novas respostas.

ericdbx

[Resolvido] IIS Não exibe mais erro!

Por , em ASP Clássico

Recommended Posts

ericdbx    0

ericdbx
Postado

Entao galera to com um probleminha não sei se vcs já passaram por isso.

 

quando programo uma nova página e ela contem erros isso não é exibido

 

abre uma pagina em branco , branco mesmo nada escrito.

 

ai eu tenho q usar outro servidor para ver os erros da pagina.

 

se alguem puder ajudar desde já obrigado!!!

http://forum.imasters.com.br/public/style_emoticons/default/grin.gif

Compartilhar este post

Link para o post
Compartilhar em outros sites

ericdbx    0

ericdbx
Postado

Acho q você não leu o q eu escrevi!!!

 

entao amigo meu navegador já esta configurado assim.

 

o servidor não retorna o erro, ele retorna uma pagina em branco.

Compartilhar este post

Link para o post
Compartilhar em outros sites

hargon    64

hargon
Postado

Ele interpreta normalmente as páginas que estão funcionando?

Compartilhar este post

Link para o post
Compartilhar em outros sites

hargon    64

hargon
Postado

Vá em:

- Painel de controle/ Ferramentas administrativas/ Internet Information Service (IIS)

- Clique com o botão contrário do mouse sobre Sites web padrão e vá em Propriedades.

- Clique na guia (orelha) Erros personalizados

- Aparecerá várias páginas. Verifique se no erro 500/100 está com o arquivo "/iisHelp/common/500-100.asp"

 

Se estiver tudo ok, acesse a pasta "C:\WINDOWS\Help\iisHelp\common", abra o arquivo 500-100.asp e poste aqui o que está nele.

Compartilhar este post

Link para o post
Compartilhar em outros sites

ericdbx    0

ericdbx
Postado

Entao hargon,

 

acessei lah mas minhas paginas dentro desta pasta estão com estensão .html e nao .asp

 

mesmo assim mudei ela para a 500-100 e nada

Compartilhar este post

Link para o post
Compartilhar em outros sites

hargon    64

hargon
Postado

Não era para mudar. A página 500-100.asp tem que está lá.

 

Se não estiver, crie uma.

 

Segue abaixo o código

<%@ language="VBScript" %>
<%
  Option Explicit

  Const lngMaxFormBytes = 200

  Dim objASPError, blnErrorWritten, strServername, strServerIP, strRemoteIP
  Dim strMethod, lngPos, datNow, strQueryString, strURL

  If Response.Buffer Then
	Response.Clear
	Response.Status = "500 Internal Server Error"
	Response.ContentType = "text/html"
	Response.Expires = 0
  End If

  Set objASPError = Server.GetLastError
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 3.2 Final//EN">

<html dir=ltr>

<head>
<style>
a:link			{font:8pt/11pt verdana; color:FF0000}
a:visited		{font:8pt/11pt verdana; color:#4e4e4e}
</style>

<META NAME="ROBOTS" CONTENT="NOINDEX">

<title>Não é possível exibir a página</title>

<META HTTP-EQUIV="Content-Type" Content="text-html; charset=Windows-1252">
</head>

<script> 
function Homepage(){
<!--
// in real bits, urls get returned to our script like this:
// res://shdocvw.dll/http_404.htm#http://www.DocURL.com/bar.htm 

	//For testing use DocURL = "res://shdocvw.dll/http_404.htm#https://www.microsoft.com/bar.htm"
	DocURL=document.URL;
	
	//this is where the http or https will be, as found by searching for :// but skipping the res://
	protocolIndex=DocURL.indexOf("://",4);
	
	//this finds the ending slash for the domain server 
	serverIndex=DocURL.indexOf("/",protocolIndex + 3);

	//for the href, we need a valid URL to the domain. We search for the # symbol to find the begining 
	//of the true URL, and add 1 to skip it - this is the BeginURL value. We use serverIndex as the end marker.
	//urlresult=DocURL.substring(protocolIndex - 4,serverIndex);
	BeginURL=DocURL.indexOf("#",1) + 1;
	urlresult=DocURL.substring(BeginURL,serverIndex);
		
	//for display, we need to skip after http://, and go to the next slash
	displayresult=DocURL.substring(protocolIndex + 3 ,serverIndex);
	InsertElementAnchor(urlresult, displayresult);
}

function HtmlEncode(text)
{
	return text.replace(/&/g, '&amp').replace(/'/g, '"').replace(/</g, '<').replace(/>/g, '>');
}

function TagAttrib(name, value)
{
	return ' '+name+'="'+HtmlEncode(value)+'"';
}

function PrintTag(tagName, needCloseTag, attrib, inner){
	document.write( '<' + tagName + attrib + '>' + HtmlEncode(inner) );
	if (needCloseTag) document.write( '</' + tagName +'>' );
}

function URI(href)
{
	IEVer = window.navigator.appVersion;
	IEVer = IEVer.substr( IEVer.indexOf('MSIE') + 5, 3 );

	return (IEVer.charAt(1)=='.' && IEVer >= '5.5') ?
		encodeURI(href) :
		escape(href).replace(/%3A/g, ':').replace(/%3B/g, ';');
}

function InsertElementAnchor(href, text)
{
	PrintTag('A', true, TagAttrib('HREF', URI(href)), text);
}

//-->
</script>

<body bgcolor="FFFFFF">

<table width="410" cellpadding="3" cellspacing="5">

  <tr>	
	<td align="left" valign="middle" width="360">
	<h1 style="COLOR:000000; FONT: 13pt/15pt verdana"><!--Problem-->Não é possível exibir a página</h1>
	</td>
  </tr>
  
  <tr>
	<td width="400" colspan="2">
	<font style="COLOR:000000; FONT: 8pt/11pt verdana">Ocorreu um problema com a página que você está tentando acessar e não é possível exibi-la.</font></td>
  </tr>
  
  <tr>
	<td width="400" colspan="2">
	<font style="COLOR:000000; FONT: 8pt/11pt verdana">

	<hr color="#C0C0C0" noshade>
	
	<p>Experimente o seguinte:</p>

	<ul>
	  <li id="instructionsText1">Clique no botão 
	  <a href="java script:location.reload()">
	  Atualizar</a> ou tente novamente mais tarde.<br>
	  </li>
	  
	  <li>Abra a 
	  
	  <script>
	  <!--
	  if (!((window.navigator.userAgent.indexOf("MSIE") > 0) && (window.navigator.appVersion.charAt(0) == "2")))
	  {
		   Homepage();
	  }
	  //-->
	  </script>

	  home page e procure os links para as informações desejadas. </li>
	</ul>
	
	<h2 style="font:8pt/11pt verdana; color:000000">HTTP 500.100 - Servidor interno
	Erro - erro do ASP<br>
	Internet Information Services</h2>

	<hr color="#C0C0C0" noshade>
	
	<p>Informações técnicas (para a equipe de suporte)</p>

<ul>
<li>Tipo de erro:<br>
<%
  Dim bakCodepage
  on error resume next
	  bakCodepage = Session.Codepage
	  Session.Codepage = 1252
  on error goto 0
  Response.Write Server.HTMLEncode(objASPError.Category)
  If objASPError.ASPCode > "" Then Response.Write Server.HTMLEncode(", " & objASPError.ASPCode)
  Response.Write Server.HTMLEncode(" (0x" & Hex(objASPError.Number) & ")" ) & "<br>"

  If objASPError.ASPDescription > "" Then 
		Response.Write Server.HTMLEncode(objASPError.ASPDescription) & "<br>"

  elseIf (objASPError.Description > "") Then 
		 Response.Write Server.HTMLEncode(objASPError.Description) & "<br>" 
  end if



  blnErrorWritten = False

  ' Only show the Source if it is available and the request is from the same machine as IIS
  If objASPError.Source > "" Then
	strServername = LCase(Request.ServerVariables("SERVER_NAME"))
	strServerIP = Request.ServerVariables("LOCAL_ADDR")
	strRemoteIP =  Request.ServerVariables("REMOTE_ADDR")
	If (strServername = "localhost" Or strServerIP = strRemoteIP) And objASPError.File <> "?" Then
	  Response.Write Server.HTMLEncode(objASPError.File)
	  If objASPError.Line > 0 Then Response.Write ", line " & objASPError.Line
	  If objASPError.Column > 0 Then Response.Write ", column " & objASPError.Column
	  Response.Write "<br>"
	  Response.Write "<font style=""COLOR:000000; FONT: 8pt/11pt courier new""><b>"
	  Response.Write Server.HTMLEncode(objASPError.Source) & "<br>"
	  If objASPError.Column > 0 Then Response.Write String((objASPError.Column - 1), "-") & "^<br>"
	  Response.Write "</b></font>"
	  blnErrorWritten = True
	End If
  End If

  If Not blnErrorWritten And objASPError.File <> "?" Then
	Response.Write "<b>" & Server.HTMLEncode(  objASPError.File)
	If objASPError.Line > 0 Then Response.Write Server.HTMLEncode(", line " & objASPError.Line)
	If objASPError.Column > 0 Then Response.Write ", column " & objASPError.Column
	Response.Write "</b><br>"
  End If
%>
</li>
<p>
<li>Tipo de navegador: <br>
<%= Server.HTMLEncode(Request.ServerVariables("HTTP_USER_AGENT")) %>
</li>
<p>
<li>Página: <br>
<%
  strMethod = Request.ServerVariables("REQUEST_METHOD")

  Response.Write strMethod & " "

  If strMethod = "POST" Then
	Response.Write Request.TotalBytes & " bytes to "
  End If

  Response.Write Request.ServerVariables("SCRIPT_NAME")

  lngPos = InStr(Request.QueryString, "|")

  If lngPos > 1 Then
	Response.Write "?" & Server.HTMLEncode(Left(Request.QueryString, (lngPos - 1)))
  End If

  Response.Write "</li>"

  If strMethod = "POST" Then
	Response.Write "<p><li>POST Data:<br>"
	If Request.TotalBytes > lngMaxFormBytes Then
	   Response.Write Server.HTMLEncode(Left(Request.Form, lngMaxFormBytes)) & " . . ."
	Else
	  Response.Write Server.HTMLEncode(Request.Form)
	End If
	Response.Write "</li>"
  End If

%>
<p>
<li>Hora: <br>
<%
  datNow = Now()

  Response.Write Server.HTMLEncode(FormatDateTime(datNow, 1) & ", " & FormatDateTime(datNow, 3))
  on error resume next
	  Session.Codepage = bakCodepage 
  on error goto 0
%>
</li>
</p>
<p>
<li>Mais informações: <br>
 <%  strQueryString = "prd=iis&sbp=&pver=5.0&ID=500;100&cat=" & Server.URLEncode(objASPError.Category) & _
	"&os=&over=&hrd=&Opt1=" & Server.URLEncode(objASPError.ASPCode)  & "&Opt2=" & Server.URLEncode(objASPError.Number) & _
	"&Opt3=" & Server.URLEncode(objASPError.Description) 
	   strURL = "http://www.microsoft.com/ContentRedirect.asp?" & _
	strQueryString
%>
<a href="<%= strURL %>">Suporte da Microsoft</a>
</li>
</p>

	</font></td>
  </tr>
  
</table>
</body>
</html>

Compartilhar este post

Link para o post
Compartilhar em outros sites

ericdbx    0

ericdbx
Postado

PERFEITO!!!!

 

desculpa a demora nao tive tempo pra resolver isto mas agora q deu uma aliviada resolvi!!!

 

vlw funciono direitinho!!!

 

thks hargon e a todos q ajudaram!!!

Compartilhar este post

Link para o post
Compartilhar em outros sites
Ir para a lista de tópicos ASP Clássico
×

Informação importante

Ao usar o fórum, você concorda com nossos Termos e condições.

  Aceito