Jogar dados de um form em asp para um XML

[Luan Messias 0]

Olá Pessoal este é meu primeiro post não sei se estou no lugar correto mas a minha duvida é ASP

então creio eu que estou no lugar correto http://forum.imasters.com.br/public/style_emoticons/default/thumbsup.gif

 

Seguinte, o objetivo da duvida é saber como adicionar itens digitados em um formulário em ASP para um XML

no caso o formulário tem estes campos:

(adicionar foto) (upload)

e os campos que vao para o xml

(titulo)

(area)

(texto)

(foto)

(link)

entre outros, é só um exemplo...

mas a duvida é que eu quero que o asp crie este codigo a baixo dentro de um xml determinado

 

<ticker>

<titulo> form do asp </titulo>

<area> form do asp </area>

<texto>form do asp</texto>

<foto> foto1.jpg </foto>

<link>form do asp</link>

</ticker>

 

 

não sei se expliquei bem mas se não der para entender usarei tudo o que tiver aqui para tentar explicar melhor http://forum.imasters.com.br/public/style_emoticons/default/grin.gif

 

se alguem puder me mandar o código de um formulário em asp com as tags para executar tais ações para min

estudar eu agradeço muito xD

[Ted k' 126]

você pode usar uma página .asp com formatação XML e colocar os request.form("") no lugares adequados ou pode criar um pelo FSO, assim:

http://tedk.com.br/blog/index.php/2008/07/...o-xml-pelo-asp/

[Luan Messias 0]

Bom, primeiramente obrigado por tentar ajudar mas tipo assim... cada vez que uma pessoa digitar este formulário o asp vai criar um arquivo novo em .xml ?

pois se for criado um .xml toda vez que alguem usar o formulário não seria um problema ?

o ideal seria apenas acrescentar tais tags em um xml já existente pois o flash esta puxando o endereço das fotos por um unico .xml :mellow:

sera que é possivel fazer isto ? :huh:

 

encontrei este código... a fonte diz que ele cria a tag desejada

vou colocar aqui pois não entendo qual tag vai criar a tag primaria e secundaria no xml

e se caso alguem também precisar já tem o código ai =)

 

-----------------------------------------------------------------------------

Exemplo:

 

<tagprimaria>

<tag secundaria1> </tag secundaria1>

<tag secundaria2> </tag secundaria2>

<tag secundaria3> </tag secundaria3>

</tagprimaria>

ai minha pergunta qual dos codigos em asp cria a tag primaria e a secundaria ?

no meu modo inexperiente de entender o tal "nó noticias" seria a primaria ? :huh:

-----------------------------------------------------------------------------

segue o codigo asp:

 

(criar.asp)

 

<%@Language=VBScript%>
<%response.buffer=true%>
<%

'recupera os dados do formulário'
xdatap=request.form("Data")
xfonte=request.form("Fonte")
xtitulo=request.form("Titulo")
xtexto=request.form("Texto")

'processamento do DOM'
set docxml=server.createobject("microsoft.xmldom")
existe = docxml.load(server.mappath(“arquivo.xml”))

'verifica se o arquivo já existe'
'se existir, carrega, senão cria'
if existe=True then
	set noticias=docxml.documentElement
else
	set noticias=docxml.createElement("noticias")
	docxml.appendchild(noticias)
end if

'criei o nó noticia'
set noticia=docxml.createelement("noticia")
noticias.appendchild(noticia)

'criando o elemento data'
set datap=docxml.createelement("data")
noticia.appendchild(datap)
datap.SetAttribute "taborder","1"
datap.text = xdatap

'criando o elemento fonte'
set fonte=docxml.createelement("fonte")
noticia.appendchild(fonte)
fonte.SetAttribute "taborder","2"
fonte.text = xfonte

'criando o elemento titulo'
set titulo=docxml.createelement("titulo")
noticia.appendchild(titulo)
titulo.SetAttribute "taborder","3"
titulo.text = xtitulo

'criando o elemento texto'
set texto=docxml.createelement("texto")
noticia.appendchild(texto)
texto.SetAttribute "taborder","4"
texto.text = xtexto

'verifica novamente se o arquivo já existe ou precisa ser criado'
if existe=False then
	'insere o cabecalho ao documento'
	set pi = docxml.createProcessingInstruction("xml","version='1.0' encoding='ISO-8859-1'")
	docxml.insertbefore pi,docxml.childnodes(0)
end if

'salva o xml como arquivo.xml'
docxml.save(server.mappath(“arquivo.xml”))
%>

 

Valeu xD

[Ted k' 126]

dica:

 

ao invés de pedir para o asp criar a tag, pq não faz tipo um leitor de feeds?

ele pega uma página ASP que está formatada para XML e puxa as informações do banco e formata o XML

[Luan Messias 0]

Cara concegui finalmente mas eu travei em uma parte

concegui criar o xml e estruturalo

a minha intenção e criar um nod dentro de outro nod mas nao sei qual tag usar

um exemplo :

 

 

---------------------------------------------------------------------------

Set objtricker = objDom.createElement("tricker")
   
  
   Set objsigla = objDom.createElement("sigla")
   objsigla.Text = Request.Form("sigla")
   objroot.appendchild objsigla

   Set objnome = objDom.createElement("nome")
   objnome.Text = Request.Form("nome")
   objroot.appendchild objnome
   
   
objroot.appendchild objtricker

---------------------------------------------------------------------------

 

o resultado desta tag acima é a seguinte:

 

<?xml version="1.0"?>
<master>

<			 > -------------------------> a tag tricker deveria abrir aqui :blink:


<sigla>teste</sigla>
<nome>teste</nome>


<tricker/>	----------------------->mas percebe-se que esta tag (tricker) so esta fechando e so 
												  falta ela abrir ali em cima da tag sigla  e ai acabo 
 
</master>

-----------------------------------------------------------------------------------------------------------------

 

se você souver o que eu estou afzendo de errado me ajuda ae so falta isso pra min terminar isso

Valeu mano xD

[Luan Messias 0]

Siguinte se quiserem pode fechar o topico concegui resolver....

não sei com explicar na teoria mas vou mandar o codigo errado e o correto:

 

 

ERRADO :

 

Set objTricker = objDom.createElement("Tricker")
   
  
	Set objTitulo = objDom.createElement("Titulo")
   objTitulo.Text = Request.Form("Titulo")
   objroot.appendchild objTitulo

   Set objtema = objDom.createElement("tema")
   objtema.Text = Request.Form("tema")
   objroot.appendchild objtema
   
   Set objdesc = objDom.createElement("desc")
   objdesc.Text = Request.Form("desc")
   objroot.appendchild objdesc
   
   Set objfile = objDom.createElement("file")
   objfile.Text = Request.Form("file")
   objroot.appendchild objfile
   
   
objroot.appendchild objTricker

 

CORRETO:

 

Set objTricker = objDom.createElement("Tricker")
   
  
	Set objTitulo = objDom.createElement("Titulo")
   objTitulo.Text = Request.Form("Titulo")
   objTricker.appendchild objTitulo

   Set objtema = objDom.createElement("tema")
   objtema.Text = Request.Form("tema")
   objTricker.appendchild objtema
   
   Set objdesc = objDom.createElement("desc")
   objdesc.Text = Request.Form("desc")
   objTricker.appendchild objdesc
   
   Set objfile = objDom.createElement("file")
   objfile.Text = Request.Form("file")
   objTricker.appendchild objfile
   
   
objroot.appendchild objTricker

 

 

O erro esta nas tags :

 

objroot.appendchild objTitulo

 

objroot.appendchild objtema

 

objroot.appendchild objdesc

 

objroot.appendchild objfile

 

 

é so comparar os dois modelos

o que vale é a intenção se vale de ajuda ta ae ^_^

[Ted k' 126]

http://forum.imasters.com.br/public/style_emoticons/default/clap.gif