Ir para conteúdo

POWERED BY:

Arquivado

Este tópico foi arquivado e está fechado para novas respostas.

Arlene Paula

[Resolvido] Botão de editar não edita...

Por , em ASP Clássico

Recommended Posts

Arlene Paula    0

Arlene Paula
Postado

Pedi ajuda aqui hoje e recebi ajuda pra fazer aparecer os botões de editar e excluir, que não estvam aparecendo. Agora apareceram, mas o botão de editar não está editando e eu não sei como funciona a lógica dessa página, pois peguei ela semi-pronta, pra mudar pouquiíssimas coisas. Alguem pode me ajudar a entender o que está acontecendo?

 

Vou colocar aki só o que interessa na minha página, ok?

 

df_consulta.asp

 

<script language="JavaScript">
<!--
function abre_foto(width, height, nome) {
  var top; var left;
  top = ( (screen.height/2) - (height/2) )
  left = ( (screen.width/2) - (width/2) )
  window.open('',nome,'width='+width+',height='+height+',scrollbars=yes,toolbar=no,location=no,status=no,menubar=no,resizable=no,lef
t='+left+',top='+top);
}
function confirm_delete(form) {
  if (confirm("Tem certeza que deseja excluir o registro?")) {
	document[form].action = '<%=Request.ServerVariables("SCRIPT_NAME")%>';
	document[form].submit();
  }
}
//-->
</SCRIPT>
.
.
.
<td height="76" colspan="8"><p class="texto_pagina">
	<% dim solut
	solut= request("solut")
	
	if solut="" then %> 
	Links: <a href="<%=pagina_consulta%>" class="texto_pagina">Página de Consulta</a> | <a href="<%=pagina_inclusao%>" class="texto_pagina">Página de Inclusão</a>
	| <a href="../../ATN/Admin/PPrincipal.asp">Voltar para Administrador</a>
	<% end if%>
	</p>	  
	<a href="<%=pagina_inclusao%>" class="texto_pagina"><hr size=1 color=gainsboro>
	  </a><span class="texto_pagina">
	  <%
If Request.QueryString("PagAtual") = "" Then
  PagAtual = 1
  NumPagMax = VarPagMax
Else
  NumPagMax = CInt(Request.QueryString("NumPagMax"))
  PagAtual = CInt(Request.QueryString("PagAtual"))
  Select Case Request.QueryString("Submit")
	Case "Anterior" : PagAtual = PagAtual - 1
	Case "Proxima" : PagAtual = PagAtual + 1
	Case "Menos" : NumPagMax = NumPagMax - VarPagMax
	Case "Mais" : NumPagMax = NumPagMax + VarPagMax
	Case Else : PagAtual = CInt(Request.QueryString("Submit"))
  End Select
  If NumPagMax < PagAtual then
	NumPagMax = NumPagMax + VarPagMax
  End If
  If NumPagMax - (VarPagMax - 1) > PagAtual then
	NumPagMax = NumPagMax - VarPagMax
  End If
End If

Set objCon = Server.CreateObject("ADODB.Connection")
objCon.Open strCon

  If (Session("login") = "logado") Then
  If Request.Form("recordno") <> "" Then
	Set objRS_delete = Server.CreateObject("ADODB.Recordset")
	objRS_delete.CursorLocation = 3
	objRS_delete.CursorType = 0
	objRS_delete.LockType = 3

	strQ_delete = Request.Form("strQ")
	indice = Trim(Request.Form("indice"))
	If indice <> "" Then strQ_delete = " SELECT * FROM tabprodutos WHERE " & indice

	objRS_delete.Open strQ_delete, objCon, , , &H0001
	If indice = "" Then objRS_delete.Move Request.Form("recordno") - 1
	If Not objRS_delete.EOF Then
	  objRS_delete.Delete
	  objRS_delete.UpdateBatch
	End IF

	objRS_delete.Close
	Set objRS_delete = Nothing
	Set strQ_delete = Nothing
  End If
  End If

Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.CursorLocation = 3
objRS.CursorType = 2
objRS.LockType = 1
objRS.CacheSize = RegPorPag
strQ = "SELECT * FROM tabprodutos"

If Trim(Request("string_busca")) <> "" Then
  If Trim(Request("campo_busca")) <> "" Then
	strQ = strQ & " Where " & Trim(Request("campo_busca")) & " LIKE '%" & Trim(Request("string_busca")) & "%'"
  Else
	strQ = strQ & " Where 1 <> 1"
	strQ = strQ & " Or codigobd LIKE '%" & Trim(Request("string_busca")) & "%'"
	strQ = strQ & " Or lancamento LIKE '%" & Trim(Request("string_busca")) & "%'"
	strQ = strQ & " Or foto LIKE '%" & Trim(Request("string_busca")) & "%'"
	strQ = strQ & " Or titulo LIKE '%" & Trim(Request("string_busca")) & "%'"
	strQ = strQ & " Or autor LIKE '%" & Trim(Request("string_busca")) & "%'"
	strQ = strQ & " Or assunto LIKE '%" & Trim(Request("string_busca")) & "%'"
	strQ = strQ & " Or release LIKE '%" & Trim(Request("string_busca")) & "%'"
	strQ = strQ & " Or paginas LIKE '%" & Trim(Request("string_busca")) & "%'"
	strQ = strQ & " Or formato LIKE '%" & Trim(Request("string_busca")) & "%'"
	strQ = strQ & " Or preco LIKE '%" & Trim(Request("string_busca")) & "%'"
	strQ = strQ & " Or pchave LIKE '%" & Trim(Request("string_busca")) & "%'"
	strQ = strQ & " Or status LIKE '%" & Trim(Request("string_busca")) & "%'"
	'Ver dps o q tah acontecendo com essa lnha abaixo; pciso fzr uma cosulta p deixar os lançamentos na frente
	'RS.Open "SELECT * FROM tabprodutos WHERE lancamento = " & Text1.Text & "" & " ORDER BY lancamento" 
  End If
End If
'If Trim(Request.QueryString("Ordem")) <> "" Then
 ' strQ = strQ & " ORDER BY " & Request.QueryString("Ordem")
	strQ = strQ & " ORDER BY lancamento Desc, titulo ASC"

'End If
objRS.Open strQ, objCon, , , &H0001
objRS.PageSize = RegPorPag

Set objRS_indice = Server.CreateObject("ADODB.Recordset")
objRS_indice.CursorLocation = 2
objRS_indice.CursorType = 0
objRS_indice.LockType = 2
strQ_indice = "SELECT * FROM tabprodutos WHERE 1 <> 1"
objRS_indice.Open strQ_indice, objCon, , , &H0001
indice = ""
For Each item In objRS_indice.Fields
  If item.properties("IsAutoIncrement") = True Then
	indice = item.name
	Exit For
  End If
Next
objRS_indice.Close
Set objRS_indice = Nothing
Set strQ_indice = Nothing

Set objRS.ActiveConnection = Nothing
objCon.Close
Set objCon = Nothing
%>
	  <B>Consultar Registros</B><BR>Visualize os registros da 
tabela abaixo:<BR>
	  </span>
	  <FORM name="form_busca" method="post" action="<%=Request.ServerVariables("SCRIPT_NAME")%>">
		<span class="texto_pagina">
  Pesquizar por  <INPUT type=text name=string_busca value="<%=Request("string_busca")%>" class=texto_pagina>
  em  <SELECT name=campo_busca class=texto_pagina>
	<OPTION value="" selected>Registros</OPTION>
	<OPTION value="titulo" <% If Trim(Request("campo_busca")) = Trim("titulo") Then : Response.Write "selected" : End If %>>Título</OPTION>
	<OPTION value="autor" <% If Trim(Request("campo_busca")) = Trim("autor") Then : Response.Write "selected" : End If %>>Autor</OPTION>
	<OPTION value="assunto" <% If Trim(Request("campo_busca")) = Trim("assunto") Then : Response.Write "selected" : End If %>>Assunto</OPTION>
	<OPTION value="preco" <% If Trim(Request("campo_busca")) = Trim("preco") Then : Response.Write "selected" : End If %>>Preço R$</OPTION>
  </SELECT>
  <INPUT type="submit" name="submit" value="ok" class=texto_pagina style="color: black">
		</span>
	  </FORM>
	  <span class="texto_pagina">
	  <%
If Not(objRS.EOF) Then
  objRS.AbsolutePage = PagAtual
  TotPag = objRS.PageCount
%>
Foram encontrados <%= objRS.RecordCount%> registros<BR>
<BR>
	  </span>
	  <TABLE width="100%" border=0 cellpadding=0 cellspacing=0>
  <TR class=titulos_registros>
	<%
If (Session("login") = "logado") Then
  Response.Write "<TD align=""center"" style=""background-color: crimson; color: white"" width=""1%"" nowrap><b>Editar</b></TD>"
End IF

If Right(Request.QueryString("Ordem"), 3) = "desc" Then
  Ordem = "desc"
Else
  Ordem = "asc"
End IF
%>
	<TD colspan="10" valign=top nowrap style="cursor: hand" onClick="window.open('<%=Request.ServerVariables("SCRIPT_NAME")%>?Ordem=codigobd+<%=Ordem%>', '_self')"> </TD>
  </TR>
  <%
For Cont = 1 to objRS.PageSize
%>
  <TR class=exibe_registros>
	<%
If (Session("login") = "logado") Then
  Response.Write "<FORM name=""form_edit_" & Cont & """ action=""" & pagina_alteracao & """ method=post>"
  Response.Write "<TD  align=""center"" nowrap style=""background-color: gainsboro""  nowrap> "
  If indice <> "" Then Response.Write "<input type=""hidden"" name=""indice"" value=""" & indice & "=" & objRS.Fields.Item(indice).Value & """>"
  Response.Write "<INPUT type=hidden name=recordno value=""" & (objRS.AbsolutePosition) & """>"
  Response.Write "<INPUT type=hidden name=strQ value=""" & strQ & """>"
  Response.Write "<INPUT type=image src=""imagens\edit.gif"" alt=""Alterar Registro"" name=alterar value=alterar>"
  If (Session("login") = "logado") Then
Response.Write " <IMG src=""imagens\delete.gif"" alt=""Excluir Registro"" name=delete border=0 style=""cursor:hand"" OnClick=""confirm_delete('form_edit_" & Cont & "')"">"
End If
  Response.Write " </TD>"
  Response.Write "</FORM>"
End If
%>
	<TD width="14%" rowspan="6" class="texto_pagina"><a href="<%=(objRS.Fields.Item("link").Value)%>" onClick="abre_foto(350, 350, 'janela_foto')" target="janela_foto"><img src="<%=(objRS.Fields.Item("foto").Value)%>" border=0 width=100 height="125"></a></TD>
	<TD width="3%" class="texto_pagina">
	  <%If Left(Request.QueryString("Ordem"), 6) = "titulo" Then : Response.Write "<img src=""imagens\ordem_" & Ordem & ".gif"" width=9 height=10> " : End If%>	</TD>
	<TD width="7%" class="texto_pagina"><b>Título:</b></TD>
	<TD width="24%" class="texto_pagina"><%=(objRS.Fields.Item("titulo").Value)%></TD>
	<TD colspan="6" class="texto_pagina">
	  <%If Left(Request.QueryString("Ordem"), 7) = "release" Then : Response.Write "<img src=""imagens\ordem_" & Ordem & ".gif"" width=9 height=10> " : End If%>
	  <b>Release do livro</b></TD>
  </TR>
  <TR class=exibe_registros>
	<TD class="texto_pagina">
	  <%If Left(Request.QueryString("Ordem"), 5) = "autor" Then : Response.Write "<img src=""imagens\ordem_" & Ordem & ".gif"" width=9 height=10> " : End If%>	</TD>
	<TD class="texto_pagina"><b>Autor:</b></TD>
	<TD class="texto_pagina"><%=(objRS.Fields.Item("autor").Value)%></TD>
	<TD colspan="6" rowspan="5" class="texto_pagina"><%=(objRS.Fields.Item("release").Value)%></TD>
  </TR>
  <TR class=exibe_registros>
	<TD class="texto_pagina">
	  <%If Left(Request.QueryString("Ordem"), 7) = "assunto" Then : Response.Write "<img src=""imagens\ordem_" & Ordem & ".gif"" width=9 height=10> " : End If%>	</TD>
	<TD class="texto_pagina"><b>Assunto:</b></TD>
	<TD class="texto_pagina"><%=(objRS.Fields.Item("assunto").Value)%></TD>
  </TR>
  <TR class=exibe_registros>
	<TD class="texto_pagina">
	  <%If Left(Request.QueryString("Ordem"), 7) = "paginas" Then : Response.Write "<img src=""imagens\ordem_" & Ordem & ".gif"" width=9 height=10> " : End If%>	</TD>
	<TD class="texto_pagina"><b>Páginas:</b></TD>
	<TD class="texto_pagina"><%=(objRS.Fields.Item("paginas").Value)%></TD>
  </TR>
  <TR class=exibe_registros>
	<TD class="texto_pagina">
	  <%If Left(Request.QueryString("Ordem"), 7) = "formato" Then : Response.Write "<img src=""imagens\ordem_" & Ordem & ".gif"" width=9 height=10> " : End If%>	</TD>
	<TD class="texto_pagina"><b>Formato:</b></TD>
	<TD class="texto_pagina"><%=(objRS.Fields.Item("formato").Value)%></TD>
  </TR>
  <TR class=exibe_registros>
	<TD class="texto_pagina">
	  <%If Left(Request.QueryString("Ordem"), 5) = "preco" Then : Response.Write "<img src=""imagens\ordem_" & Ordem & ".gif"" width=9 height=10> " : End If%>	</TD>
	<TD class="texto_pagina"><b>Preço:</b></TD>
	<TD class="texto_pagina style61"><%=(objRS.Fields.Item("preco").Value)%></TD>
  </TR>
  <TR>
	<TD class="texto_pagina"><a href="<%=(objRS.Fields.Item("link").Value)%>"><img src="imagens/comprar.jpg" width="99" height="42" border="0"></a></TD>
	<TD> </TD>
	<TD colspan="2"><span class="style62"><%=(objRS.Fields.Item("status").Value)%></span></TD>
	<TD width="3%"> </TD>
	<TD width="10%"> </TD>
	<TD width="10%"> </TD>
	<TD width="10%"> </TD>
	<TD width="10%"> </TD>
	<TD width="9%"> </TD>
  </TR>
  <TR>
	<TD colspan="10" background="imagens/linha_horizontal1.jpg"> </TD>
  </TR>
  <%
  objRS.MoveNext
  If objRS.Eof then Exit For
Next
Set Cont = Nothing
%>
  <TR>
	<TD colspan="13" class="texto_pagina">
	  <%LinksNavegacao()%>	</TD>
  </TR>
</TABLE>
<p>
  <span class="texto_pagina">
  <%
  If indice = "" Then
	Response.Write "<BR><B>ATENÇÃO:</B> Crie um campo do tipo <i>AutoIncrement</i> com qualquer nome em sua tabela para evitar erros na alteração dos dados. "
	Response.Write "<a href=""http://www.dataform.com.br/criar_campo_autoincrement.asp"" target=""_blank"">Clique aqui</a> para mais detalhes."
  End If
  objRS.Close
  Set objRS = Nothing
Else
%>
  <BR>
  <B>Nenhum registro foi encontrado</B><BR>
  </span><BR>
  <%
End If
%>
.
.
.
<%
Sub LinksNavegacao()
'O código a seguir insere uma tabela com todos os links de navegação das páginas
Response.Write "<TABLE border=0 cellPadding=2 cellSpacing=0 class=tabela_paginacao>"
Response.Write "<TR><TD align=center vAlign=top noWrap colspan=5>"
Response.Write "Página " & PagAtual & " de " & TotPag
Response.Write "</TD></TR><TR><TD width=33% align=right vAlign=top noWrap>"
If PagAtual > 1 Then
  Response.Write "<A href=""" & Request.ServerVariables("SCRIPT_NAME") & "?solut=1&PagAtual=" &  PagAtual &"&VarPagMax=" & VarPagMax & "&NumPagMax=" & NumPagMax & "&Submit=Anterior&Ordem=" & Request.QueryString("Ordem")& "&string_busca=" & Server.URLEncode(Request("string_busca")) & "&campo_busca=" & Server.URLEncode(Request("campo_busca"))  & """ class=links_paginacao>< Anterior</A>"
End If
Response.Write "</TD><TD width=33% align=middle vAlign=top noWrap>"
If NumPagMax - VarPagMax <> 0 then
  Response.Write " <A href=""" & Request.ServerVariables("SCRIPT_NAME") & "?solut=1&PagAtual=" & NumPagMax - VarPagMax & "&VarPagMax=" & VarPagMax & "&NumPagMax=" & NumPagMax - VarPagMax & "&Submit=Menos&Ordem=" & Request.QueryString("Ordem") & "&string_busca=" & Server.URLEncode(Request("string_busca")) & "&campo_busca=" & Server.URLEncode(Request("campo_busca")) & """ class=links_paginacao><<</A>  "
End If
for i = NumPagMax - (VarPagMax - 1) to NumPagMax
  If i <= TotPag then
	If i <> CInt(PagAtual) then
	  Response.Write " <A href=""" & Request.ServerVariables("SCRIPT_NAME") & "?solut=1&PagAtual=" & PagAtual & "&VarPagMax=" & VarPagMax & "&NumPagMax=" & NumPagMax & "&Submit=" & i & "&Ordem=" & Request.QueryString("Ordem") & "&string_busca=" & Server.URLEncode(Request("string_busca")) & "&campo_busca=" & Server.URLEncode(Request("campo_busca")) & """ class=links_paginacao>" & i & "</A> "
	Else
	  If PagAtual <> TotPag Then
		Response.Write " " & i & " "
	  End If
	End If
  End If
Next
If NumPagMax  < TotPag then
  Response.Write "  <A href=""" & Request.ServerVariables("SCRIPT_NAME") & "?solut=1&PagAtual=" & NumPagMax + 1 & "&VarPagMax=" & VarPagMax & "&NumPagMax=" & NumPagMax + VarPagMax & "&Submit=Mais&Ordem=" & Request.QueryString("Ordem") & "&string_busca=" & Server.URLEncode(Request("string_busca")) & "&campo_busca=" & Server.URLEncode(Request("campo_busca")) & """ class=links_paginacao>>></A>"
End If
Response.Write "</TD><TD width=33% align=left vAlign=top noWrap>"
If PagAtual <> TotPag Then
  Response.Write "  <A href=""" & Request.ServerVariables("SCRIPT_NAME") & "?solut=1&PagAtual=" & PagAtual & "&VarPagMax=" & VarPagMax & "&NumPagMax=" & NumPagMax & "&Submit=Proxima&Ordem=" & Request.QueryString("Ordem") & "&string_busca=" & Server.URLEncode(Request("string_busca")) & "&campo_busca=" & Server.URLEncode(Request("campo_busca")) & """ class=links_paginacao>Proxima ></A>"
End If
Response.Write "</TD></TR></TABLE>"
End Sub
%>

 

Se não for pedir mto, alguem pode me ajudar a entender onde está o problema?

 

Se pcisar de mais informação, me avisem tah!

Compartilhar este post

Link para o post
Compartilhar em outros sites

xanburzum    169

xanburzum
Postado

dá uma olhada nesta logica, onde temos a parte de administracao, contendo as opções de atualizar,excluir,pesquisar e inserir, esse código é muito fácil.

 

administração.asp

<%response.buffer=true%>
<%
'------------------------------------------------------------------------------------------------
' Este ASP exibe td´z as opçoes para o admin fazer o controle de seu 
' usuarios podendo ter total controle no BD,atualizar,incluir,excluir e pesquisa
'------------------------------------------------------------------------------------------------
%>

<HTML>
<HEAD>
<TITLE>Administração</TITLE>


</HEAD>



<BODY bgColor=#ffffff leftMargin=18 topMargin=12>
<RightClick> <FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="2" COLOR="#666666"><B><FONT COLOR="#336699">:: 
Aqui você poderá administrar sua conta, e navegar nas áreas 
restritas a você cliente.<BR> </FONT> <BR> <BR> <BR> <BR> <BR> </B></FONT> 
<P><FONT FACE="Arial, Helvetica, sans-serif" SIZE="1"><B>

 <% 'declaro as var.
	 dim conexao, varmsg, rs, SQL, conDBQ, constring, varmsgeof, varloginsession, data
   
   'recupero as var.
   varmsgeof=request.querystring("msgeof")
   varmsg=request.querystring("msg")
   varloginsession=Session("login")
   %> 
   
   <script LANGUAGE="JavaScript">
function novajan3(){
window.open ("proibidox.asp","Proibido","width=180,height=200,scrollbar=no,status=yes,resize=no")
}
</SCRIPT> <script LANGUAGE="JavaScript">
function novajan2(){
window.open ("proibido.asp","Erro","width=180,height=200,scrollbar=no,status=yes,resize=no")
}
</SCRIPT> <script LANGUAGE="JavaScript">
function novajan(){
window.open ("sucesso_treina.asp","Login","width=180,height=200,scrollbar=no,status=yes,resize=no")
}
</SCRIPT> <% Select case varmsgeof  
	  case 11  'sem ser o admin - xanburzum gera o erro
	  response.write("<script>novajan2();</script>")
	  case 12  ' proibido excluir-me, o admin
   		response.write("<script>novajan3();</script>")
   end select

 Select case varmsg
	case 1  'mensagem de sucesso do incluir
	response.write("<script>novajan();</script>")
	case 2  ' mensagem de sucesso do atualizar
	response.write("<script>novajan();</script>")
	case 3  'mensagem de sucesso do excluir
	response.write("<script>novajan();</script>")
  end select
  
  
  'crio a conexao%>
 <!--#include file="conn/conexao1.asp"--> 
<% call abreconexao
			
  'crio o rs
  set rs=Server.CreateObject("ADODB.Recordset")
  'crio o SQL
  SQL="SELECT * FROM login ORDER BY login"
  rs.open SQL,conexao,1,3
   %>
	</B></FONT></P><TABLE WIDTH="95%" BORDER="0" CELLPADDING="0" CELLSPACING="0" BGCOLOR="#666666" ALIGN="center"> 
<TR BGCOLOR="#336699"> <TD WIDTH="2%"> <DIV ALIGN="left"><B><IMG SRC="file:///A|/asp/imgs/curva.gif" WIDTH="10" HEIGHT="19"></B></DIV></TD><TD WIDTH="98%"> 
<DIV ALIGN="center"><B><FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="2" COLOR="#FFFFFF">:: 
Seja Bem-Vindo <%=Ucase(varloginsession)%></FONT></B></DIV></TD></TR> <TR BGCOLOR="#336699"> 
<TD HEIGHT="10" COLSPAN="2"> <DIV ALIGN="center"><B><FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="1" COLOR="#66ffff">Administração 
de Usuários</FONT></B></DIV></TD></TR> <TR BGCOLOR="#336699"> <TD COLSPAN="2" HEIGHT="2"> </TD></TR> 
<TR BGCOLOR="#336699"> <TD COLSPAN="2" HEIGHT="16"> <DIV ALIGN="right"><A HREF="pesquisa_form_treina.asp"><IMG SRC="imgs/busca2.gif" BORDER="0" ALT="Pesquisar na base de dados" WIDTH="78" HEIGHT="21"></A> </DIV></TD></TR> 
<TR BGCOLOR="#336699"> <TD COLSPAN="2" HEIGHT="2"> <DIV ALIGN="right"><A HREF="incluir_form_treina.asp"><IMG SRC="imgs/busca2.gif" BORDER="0" ALT="Incluir" WIDTH="78" HEIGHT="21"></A> </DIV></TD></TR> </TABLE><TABLE WIDTH="95%" BORDER="1" BORDERCOLOR="#666666" BGCOLOR="#e6e6e6" ALIGN="center"> 
<TR> <TD WIDTH="16%"> <DIV ALIGN="center"><FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="1" COLOR="#666666"><B>Login</B></FONT></DIV></TD><TD WIDTH="15%"> 
<DIV ALIGN="center"><FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="1" COLOR="#666666"><B>Senha</B></FONT></DIV></TD><TD WIDTH="25%"> 
<DIV ALIGN="center"><FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="1" COLOR="#666666"><B>Email</B></FONT></DIV></TD><TD WIDTH="20%"> 
<DIV ALIGN="center"><FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="1" COLOR="#666666"><B>Atualizar</B></FONT></DIV></TD><TD WIDTH="24%"> 
<DIV ALIGN="center"><FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="1" COLOR="#666666"><B>Excluir</B></FONT></DIV></TD></TR> 
<%  while not rs.eof%> 
<TR> <TD WIDTH="16%"> <DIV ALIGN="center"><FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="1" COLOR="#000000"><B><%=rs("login")%></B></FONT></DIV></TD><TD WIDTH="15%"> 
<DIV ALIGN="center"><FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="1" COLOR="#000000"><B><%=rs("senha")%></B></FONT></DIV></TD><TD WIDTH="25%"> 
<DIV ALIGN="center"><FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="1" COLOR="#000000"><B><%=rs("email")%></B></FONT></DIV></TD><TD WIDTH="20%"> 
<DIV ALIGN="center"><FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="1" COLOR="#000000"><B><A HREF="atualizar_form_treina.asp?codigo=<%=rs("codigo")%>">Atualizar</A></B></FONT></DIV></TD><TD WIDTH="24%"> 
<DIV ALIGN="center"><FONT FACE="Verdana, Arial, Helvetica, sans-serif" SIZE="1" COLOR="#000000"><B><A HREF="excluir_form_treina.asp?codigo=<%=rs("codigo")%>">Excluir</A></B></FONT></DIV></TD></TR> 
<% rs.movenext
	  wend
	set rs=nothing
   call fechaconexao
%> </TABLE><P><BR></P>
</BODY></HTML>

atualizar_form

<%  'aplicaçaun para atua;izar os dados do usuário na base de dados do access
	'onde através do request.querystring do código ,faremos uma SELECT (SQL)
	'e jogaremos no value do form ,sendo postado através do post pra
	'atualizar_action.asp k fará o UPDATE
	
	Option explicit
	'declaro as var
	dim conexao, conDBQ, constring, rs, SQL, varcodigo
	'recupero a var
	varcodigo=request.querystring("codigo")
	
	'crio a conexao 
	' pasta conn dentro de wwwroot
	%>
<!--#include file="conn/conexao1.asp"-->
	<%call abreconexao
	'crio o recordset
	set rs=Server.CreateObject("ADODB.Recordset")
	SQL="SELECT * FROM login WHERE codigo="&varcodigo&""
	rs.open SQL,conexao,1,3
	'crio o form para jogar os rs'z no value %>	
<html>
<head>
<title>Atualização de Usuários</title>

</head>

<body bgcolor="#FFFFFF" text="#000000" link="#FFFFFF" vlink="#0000FF" alink="#FF0000">
<table width="75%" border="0" cellpadding="0" cellspacing="0" align="center"> 
<tr> <td width="2%" bgcolor="#666666"> <div align="center"><b><img src="file:///A|/asp/imgs/curva.gif" width="10" height="19"></b></div></td><td width="98%" bgcolor="#336699"> 
<div align="center"><b><font face="Verdana, Arial, Helvetica, sans-serif" size="3" color="#FFFFFF">:: 
</font><font face="Verdana, Arial, Helvetica, sans-serif" size="2" color="#FFFFFF">Atualizar 
Dados do Usuário</font></b></div></td></tr> <tr bgcolor="#336699"> <td colspan="2" height="19"> </td></tr> 
<tr bgcolor="#336699"> <td height="72" colspan="2">
 <form name="form1" method="post" action="atualizar_action_treina.asp"> 
<p><b><font face="Verdana, Arial, Helvetica, sans-serif" size="2" color="#e6e6e6">Login:</font></b> 
<input type="text" name="login" size="12" maxlength="12" value="<%=rs("login")%>"> 
<input type="hidden" name="codigo" value="<%=rs("codigo")%>"> </p><p><b><font face="Verdana, Arial, Helvetica, sans-serif" size="2" color="#e6e6e6">Email:</font><font face="Verdana, Arial, Helvetica, sans-serif" size="1" color="#000000"> 
<input type="text" name="email" size="48" maxlength="48" value="<%=rs("email")%>"> 
</font></b></p><p><b><font face="Verdana, Arial, Helvetica, sans-serif" size="2" color="#e6e6e6">Senha:</font><font face="Verdana, Arial, Helvetica, sans-serif" size="1" color="#000000"> 
<input type="password" name="senha" size="8" maxlength="8" value="<%=rs("senha")%>"> 
</font></b></p><p align="center"> 
		  <input type="image" border="0" name="imageField" src="imgs/enviar.gif" width="87" height="22"> 
</p></form></td></tr>
 <% 'FECHO O RS
	set rs=nothing
	'fecha a conexao
	call fechaconexao%> </table>
</body>
</html>

atualizar_action

<%	'aplicacaun para fazer o update dos dados do form atualizar_form.asp
	  'onde recupero todos os dados dos campos do form,dou um replace nos ' por ""
	'e crio a SQL para efetuar o update depois redireciono p/ administracao.asp
	' com passagem de parametro na URL msg=2
	
	option explicit
	'declaro as var
	dim conexao, conDBQ, constring, rs, SQL, varcodigo, varlogin, varsenha, varemail
	'recupero as var
	varcodigo=trim(request.form("codigo"))
	varlogin=trim(request.form("login"))
	varsenha=trim(request.form("senha"))
	varemail=trim(request.form("email"))
	' retiro qqer erro de digitaçao do user ,no caso ( aspas simples ')
	varlogin=replace (varlogin,"'","")
	varsenha=replace  (varsenha,"'","")
	varemail=replace(varemail,"'","")
	'crio a conexao%>
	<!--#include file="conn/conexao1.asp"-->
	<% 'abro a conexao
	call abreconexao
	'crio o rs
	set rs=Server.createobject("ADODB.Recordset")
	'crio a SQL
	SQL="UPDATE login SET login='"&varlogin&"',senha='"&varsenha&"',email='"&varemail&"' WHERE codigo="&varcodigo&""
	rs.open SQL,conexao,1,3
		if session("login") = "admin" then
			response.redirect("administracao_treina.asp?msg=2")
		else
			response.redirect("administracao1.asp?msg=2")
		end if
	'fecho o rs
	set rs=nothing
	'fecho a conexao
	call fechaconexao%>

Compartilhar este post

Link para o post
Compartilhar em outros sites

Arlene Paula    0

Arlene Paula
Postado

Loko, é exatamente isso que acontece! Não retornoa nenhum erro... eu clico em editar, ele vai p página de edição e mudo algo, clico em atualizar e ele volta p página do catálogo, onde jah deveria aparecer a mudança no texto, figura, título, autor, qualquer coisa, mas ele simplesmente, não altera. É como se eu nem tivesse mexido em nada. Fica completamente inalterado, do jeito que estava antes! Estranho não?

 

Xanburzum... vou tentar entender tah!! Obrigada msm pela dica... sou meio leiga nisso ainda, mas vou fzr meu máximo p tentar entender o que tah pegando, beleza? :D valeu msm!

Compartilhar este post

Link para o post
Compartilhar em outros sites

Arlene Paula    0

Arlene Paula
Postado

Meninos, obrigada pela ajuda!!

 

Descobri que tinha um erro não na página df_consulta.asp, mas sim na página df_alteracao.asp. Essa página tinha o alvo para outro BD e eu não tinha percebido!!

Agora ele altera, mas por algum motivo estranho, o status do livro não muda. Por exemplo, quando lançamos algum livro aqui, o status dele é LANÇAMENTO. Se já se passou algum tempo ou temos outras novidades na área, eu devo editar o registro retirando a palavra lançamento e deixando em branco. Porém, quando eu clico em atualizar a bendita palavra LANÇAMENTO ainda está lá, mas eu tinha alterado ele na página de edição. O que pode ser?

 

...........................................

 

Meninos, obrigada + uma vez!!

 

Meu marido veio aki trazer o meu cunhado no dentista, aproveitei e pedi uma ajuda... ele descobriu q na página de edição faltava isso:

 

If objRS.Fields("status").properties("IsAutoIncrement") = False Then

objRS("status") = Trim(Request.Form("status"))

End If

 

Vou prestar + atenção da próxima vez! Bjs!

Compartilhar este post

Link para o post
Compartilhar em outros sites
Ir para a lista de tópicos ASP Clássico
×

Informação importante

Ao usar o fórum, você concorda com nossos Termos e condições.

  Aceito