Ir para conteúdo

POWERED BY:

Arquivado

Este tópico foi arquivado e está fechado para novas respostas.

xanburzum

[Resolvido] Navegue por páginas com uma interface agradável

Por , em ASP Clássico

Recommended Posts

xanburzum    169

xanburzum
Postado

Navegue por páginas com uma interface agradável, das suas informações da base de dados.

 

default.asp

<% @Language = "VBScript" %>	
<%
Option Explicit
Response.Buffer = True


'inclua o include na sua pagina, para executar a navegacao entre as paginas
%>
<!-- #include file="navpage.asp" -->

<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<HTML><HEAD>
<TITLE></TITLE>
<META http-equiv=Content-Type content="text/html; charset=iso-8859-1">
</HEAD>
<BODY bgcolor="#F3F3CC" text="#000000" link="#0000ff" vlink="#800080" alink="#ff0000" topmargin=0 leftmargin=0 marginwidth=0 marginheight=0>
<br>

<%

	Dim intCurrentPage, intLastPage


	intLastPage = 15

	Call PageNav(intCurrentPage, intLastPage)

	response.write "<br><br><br><br>"


	response.write "Pagina atual: " & intCurrentPage
%>

</div>
</BODY>
</HTML>

navpage.asp

<%
Public Function PageNav(ByRef intCurrentPage, ByVal intLastPage)

	'--- IntCurrentPage = número de página atual 
'--- IntLastPage = número total de páginas 

'--- Define variáveis
		Dim strQueryString
		Dim strScript
		Dim intStart
		Dim intEnd
		Dim i
		Dim strLang
		Dim strFirstp
		Dim strPrevp
		Dim strNextp
		Dim strLastp
		Dim strFirstpTitle
		Dim strPrevpTitle
		Dim strNextpTitle
		Dim strLastpTitle
		Dim strPagep
		Dim strOfp
		Dim strNorfp
		Dim strSel
		Dim strPaging
		Dim strResult
		Dim strimgDir
		Dim strAll
		Dim strimgFirstMon
		Dim strimgPrevMon
		Dim strimgNextMon
		Dim strimgLastMon
		Dim strimgFirstMoff
		Dim strimgPrevMoff
		Dim strimgNextMoff
		Dim strimgLastMoff

	'--- Config Línguagem (opcional, comentar a próxima linha de Inglês só língua)
'		If instr(UCase(Request.ServerVariables("HTTP_ACCEPT_LANGUAGE")), "IT") > 0 then strLang = "IT" '-- Auto Selecao Línguagem
	If strLang = "IT" Then '--- italian
		strPagep = "Pagina "
		strFirstpTitle = " Primeira "
		strPrevpTitle = " Anterior "
		strNextpTitle = " Próxima "
		strLastpTitle = " Última "
		strOfp = " de "
		strAll = " Todos os registros "
		strNorfp = "Nenhum registro encontrado"
	Else '--- english
		strPagep = "Page "
		strFirstpTitle = " First "
		strPrevpTitle = " Previous "
		strNextpTitle = " Next "
		strLastpTitle = " Last "
		strOfp = " of "
		strAll = " All records shown "
		strNorfp = "No Record Found"
	End if


		strimgDir = ""

		strimgFirstMon = "2first.gif" '--- OnMouseOver
		strimgPrevMon = "2prev.gif" '--- OnMouseOver
		strimgNextMon = "2next.gif" '--- OnMouseOver
		strimgLastMon = "2last.gif" '--- OnMouseOver

		strimgFirstMoff = "22first.gif" '--- OnMouseOut
		strimgPrevMoff = "22prev.gif" '--- OnMouseOut
		strimgNextMoff = "22next.gif" '--- OnMouseOut
		strimgLastMoff = "22last.gif" '--- OnMouseOut

		strFirstp = "<img src=""" & strimgDir & strimgFirstMoff & """ align=absmiddle border=1 alt=""" & strFirstpTitle & strPagep &""" name=""strimgFirst"" style=""border-color:black;"">"
		strPrevp = "<img src=""" & strimgDir & strimgPrevMoff & """ align=absmiddle border=1 alt=""" & strPrevpTitle & "(" & strPagep & intCurrentPage - 1 & ")"" name=""strimgPrev"" style=""border-color:black;"">"
		strNextp = "<img src=""" & strimgDir & strimgNextMoff & """ align=absmiddle border=1 alt=""" & strNextpTitle & "(" & strPagep & intCurrentPage + 1 & ")"" name=""strimgNext"" style=""border-color:black;"">"
		strLastp = "<img src=""" & strimgDir & strimgLastMoff & """ align=absmiddle border=1 alt=""" & strLastpTitle & "(" & strPagep & intLastPage & ")"" name=""strimgLast"" style=""border-color:black;"">"

	'--- Assume paginação que o pedido é variável chamada' página 
	If Not IsEmpty(Request.Querystring("page")) Then
		if IsNumeric(Request.Querystring("page")) Then
			intCurrentPage = CLng(Request.Querystring("page"))
		End if
	End if

	'---Pagima limite de controle
		If intCurrentPage > intLastPage Then
			intCurrentPage = intLastPage
		ElseIf intCurrentPage < 1 Then 
			intCurrentPage = 1
		End if
		
	'--- Incluir o resultado em uma tabela e definir texto estilo
		  strPaging = "<TABLE BORDER=0 CELLPADDING=0 CELLSPACING=0 align=center style=""font-family:verdana,arial;font-size:12;""><TBODY>"
		  strPaging = strPaging & "<form method=POST name=""frmPage"" action=""""><TR><TD valign=middle>"

	If intLastPage = 1 Then
'--- Se houver apenas uma página, 
			strPaging = strPaging & strAll
	Else
	'--- Mostrar página navegação
			For i = 1 To Request.QueryString.Count
				if LCase(Request.QueryString.Key(i)) <> "page" Then
					strQueryString = strQueryString & "&" & Server.URLEncode(Request.QueryString.Key(i)) & "=" & Server.URLEncode(Request.QueryString.Item(i))
				End if
			Next
			For i = 1 To Request.Form.Count
				if LCase(Request.Form.Key(i)) <> "page" Then
					strQueryString = strQueryString & "&" & Server.URLEncode(Request.Form.Key(i)) & "=" & Server.URLEncode(Request.Form.Item(i))
				End if
			Next
			if Len(strQueryString) <> 0 Then
				strQueryString = "?" & Mid(strQueryString, 2) & "&"
			Else
				strQueryString = "?"
			End if
			strScript = Request.ServerVariables("SCRIPT_NAME") & strQueryString
			
   		If intCurrentPage <> 1 Then 
				If intCurrentPage > 2 Then
					strPaging = strPaging & "<A href=""" & strScript & "page=1"" title=""" & strFirstpTitle & strPagep &"""" & _
																	  " onMouseOver=""document.strimgFirst.src='" & strimgFirstMon & "'""" & _
																	  " onMouseOut=""document.strimgFirst.src='" & strimgFirstMoff & "'"">" & _
																		strFirstp & "</A> </TD><TD valign=middle>"
	   		End if
	 			strPaging = strPaging & "<A href=""" & strScript & "page=" & intCurrentPage - 1 & """ title=""" & strPrevpTitle & "(" & strPagep & intCurrentPage - 1 & ")""""" & _
																	  " onMouseOver=""document.strimgPrev.src='" & strimgPrevMon & "'""" & _
																	  " onMouseOut=""document.strimgPrev.src='" & strimgPrevMoff & "'"">" & _
																		strPrevp & "</A> </TD><TD valign=middle>"
   		End if
		
			strPaging = strPaging & " " & strPagep & " </TD><TD valign=middle>"
			strPaging = strPaging & "<select name=""page"" style=""font-family:verdana,arial;font-size:12px;height:18px;background-color:#F3F3F3;color:red;border:solid 1px black;font-weight:bold;"" onchange=""document.location = '?page=' + document.frmPage.page.value;"">"
			For i = 1 to intLastPage
				if i = intCurrentPage Then strSel = " selected style=""color:red;""" Else strSel = " style=""color:black;""" End if
				strPaging = strPaging & "<option value=" & i & strSel & ">" & i & "</option>"
			Next
			strPaging = strPaging & "</select></TD><TD valign=middle> " & strOfp & intLastPage & " "

			If intCurrentPage <> intLastPage Then
   			strPaging = strPaging & "</TD><TD valign=middle> <A href=""" & strScript & "page=" & intCurrentPage + 1 & """ title=""" & strNextpTitle & "(" & strPagep & intCurrentPage + 1 & ")""""" & _
																	  " onMouseOver=""document.strimgNext.src='" & strimgNextMon & "'""" & _
																	  " onMouseOut=""document.strimgNext.src='" & strimgNextMoff & "'"">" & _
																		strNextp & "</A>"
				  If intCurrentPage < intLastPage - 1 Then 
					strPaging = strPaging & "</TD><TD valign=middle> <A href=""" & strScript & "page=" & intLastPage & """ title=""" & strLastpTitle & "(" & strPagep & intLastPage & ")""""" & _
																	  " onMouseOver=""document.strimgLast.src='" & strimgLastMon & "'""" & _
																	  " onMouseOut=""document.strimgLast.src='" & strimgLastMoff & "'"">" & _
																		strLastp & "</A>"
 	   		End if
			End if
 
	End if
   	strPaging = strPaging & "</TD></TR></form></TBODY></TABLE>"
   	
		PageNav = Response.Write(strPaging)

End Function '-- PageNav
'----------------------------------------------------------------------------------------
%>

Compartilhar este post

Link para o post
Compartilhar em outros sites
Ir para a lista de tópicos ASP Clássico
×

Informação importante

Ao usar o fórum, você concorda com nossos Termos e condições.

  Aceito