Componentes

thi.ASP · Abril 9, 2004

Pessoal, podem me dar uma forcinha?- Como faço para saber quais componentes tenho no meu iis?- Como adiciono um novo?- Tem algum de UpLoad gratuito?valeu ...Abraço!

mrlogan · Abril 10, 2004

Olá tente este código me ajudou muito.

<% @ Language="VBScript" %>

<% Option Explicit %>

<%

Dim theComponent(13)

Dim theComponentName(13)

' componentes

theComponent(0) = "ADODB.Connection"

theComponent(1) = "SoftArtisans.FileUp"

theComponent(2) = "AspHTTP.Conn"

theComponent(3) = "AspImage.Image"

theComponent(4) = "LastMod.FileObj"

theComponent(5) = "Scripting.FileSystemObject"

theComponent(6) = "SMTPsvg.Mailer"

theComponent(7) = "CDONTS.NewMail"

theComponent(8) = "Jmail.smtpmail"

theComponent(9) = "SmtpMail.SmtpMail.1"

theComponent(10) = "Persits.Upload.1"

theComponent(11) = "UnitedBinary.AutoImageSize"

theComponent(12) = "aspSmartUpload.SmartUpload"

theComponent(13) = "DAO.DBEngine.35"

' apelido do componente!

theComponentName(0) = "ADODB"

theComponentName(1) = "SA-FileUp"

theComponentName(2) = "AspHTTP"

theComponentName(3) = "AspImage"

theComponentName(4) = "LastMod"

theComponentName(5) = "FileSystemObject"

theComponentName(6) = "ASPMail"

theComponentName(7) = "CDONTS"

theComponentName(8) = "JMail"

theComponentName(9) = "SMTP"

theComponentName(10) = "Persits Upload"

theComponentName(11) = "AutoImageSize"

theComponentName(12) = "ASpSmartUpload"

theComponentName(13) = "DBEngine"

Function IsObjInstalled(strClassString)

On Error Resume Next

IsObjInstalled = False

Err = 0

Dim xTestObj

Set xTestObj = Server.CreateObject(strClassString)

If 0 = Err Then IsObjInstalled = True

Set xTestObj = Nothing

Err = 0

End Function

%>

<html>

<head>

<title>Componentes instalados</title>

</head>

<body>

<table width="100%" cellpadding="0" cellspacing="0">

<tr>

<td align="center"><div align="left"><b>Componentes instalados no Servidor:</b>

</div>

<hr noshade></td>

</tr>

<tr>

<td>

<table border=0>

<%

Dim i

For i=0 to UBound(theComponent)

If Not IsObjInstalled(theComponent(i)) Then

Else

Response.Write "<tr>" & vbCrLf

Response.Write "<td width=""100%"">" & vbCrLf

Response.Write "" & theComponentName(i) & "" & vbCrLf

Response.Write "</td>" & vbCrLf

Response.Write "</tr>" & vbCrLf

End If

Next

%>

</table>

</td>

</tr>

</table>

</BODY>

</HTML>