Como remover todas as letras através do Replace

[Eduardo Fonseca 0]

Olá Amigos!

 

Preciso saber como remover todas as letras de uma string, deixando apenas a vírgula e os números disponíveis?

 

minha_var = Replace(minha_var, "<o que eu coloco aqui>", "")

 

 

Quero remover o alfabeto inteiro, do A ao Z e qualquer outra coisa que não seja a VÍRGULA e os NÚMEROS.

 

 

 

No momento é só!

 

Agradecido!

[xanburzum 169]

dá uma procurada no forum você pode fazer atraves de Regular Expression e da uma olhada nesta funcao , você poe adaptá-la

 

<%
Dim Input, Disallowed

 ' String para limpar
Input =	"sjsvnw)68&Y469$T_W$(*T+}D|3567808SDK49SO" & _
		"DJ0570570Gosdnp SNDFG_S(*GH-S570570GN*4 jwt jtj+W$T )"

 ' Permitir espaços, sublinhados e qualquer inteiro ou letra do alfabeto. 
'Remover qualquer outra coisa ...
Disallowed = "[]+=)(*&^%$#@!|\/?><,{}:;.-~`'" & chr(34) & vbCrLf & vbTab
Response.Write RmChr(Input, Disallowed) & "<BR>"

 ' remover espaços, tabulações, linefeed carriagereturns ...
Disallowed = " " & vbTab & vbCrLf
Response.Write RmChr(Input, Disallowed) & "<BR>"

 ' remove numeros...
Disallowed = "0123456789"
Response.Write RmChr(Input, Disallowed) & "<BR>"

 ' remove lower case...
Disallowed = lcase("abcdefghijklmnopqrstuvwxyz")
Response.Write RmChr(Input, Disallowed) & "<BR>"

 ' remove upper case ...
Disallowed = ucase("abcdefghijklmnopqrstuvwxyz")
Response.Write RmChr(Input, Disallowed) & "<BR>"
%>

 

<%
Private Function RmChr(byVal string, byVal remove)
	Dim i, j, tmp, strOutput
	strOutput = ""
	for j = 1 to len(string)
		tmp = Mid(string, j, 1)
		for i = 1 to len(remove)
			tmp = replace( tmp, Mid(remove, i, 1), "")
			if len(tmp) = 0 then exit for
		next
		strOutput = strOutput & tmp
	next
	RmChr = strOutput
End Function
%>

[Mário Monteiro 179]

não tem uma função que faça isso

 

precisa criar

 

um exemplo, talvez não seja o melhor

 

Function SoNumeros(Valor)
Temp = ""
For I = 1 To Len(Valor)
	  If IsNumeric(Mid(Valor, I, 1)) Then
		 Temp = Temp & Mid(Valor, I, 1)
	  End If
Next
SoNumeros= Temp 
End Function

E chame assim

 

Response.write(SoNumeros("A1B2C3"))

[Erick de Camargo 0]

Cara, acho que o jeito mais fácil (que encontrei até hoje) é usando Expressão Regular (Regular Expression = RegExp)

 

usa isso aqui que com certeza resolve, e você pode usar várias vezes:

 

VarOrigem = "letraletraletra0letra3letra87,14letra17letra"
Set RENumber = New RegExp
RENumber.Pattern = "[^,0-9]"
RENumber.IgnoreCase = True
RENumber.Global = True
varTratada = RENumber.Replace(VarOrigem,"")
response.write varTratada

Abraços