[Resolvido] Contador Texto / Imagem

[xanburzum 169]

Este é um contador de páginas que podem ser exibidos como imagens ou textos. A página registra o IP passado, para visitar sua página e será incrementado cada vez que o atual muda ip visitando.

 

<%@ Language = VBSCRIPT %>
<% Option Explicit %>
<% 
' Variable Section
    Const ForReading = 1
    Const ForWriting = 2
    Const UseText = 0 		'Use esta constante se você quiser usar o texto para a visualização do contador
    Const UseImages = 1		' Use esta constante se você quiser usar imagens para a visualização do contador
    Dim objCounterFile, objFSO, strFilePath, strImageName, displayOption, imageDirectory
    Dim strCounterNumber, iCounterNumber, strCurrentIP, strLastIP

'Defina igual a 0 ou 1, torná-lo igual ou UseImages de UseText
'Dependendo do que você deseja usar para mostrar o seu contador.

    displayOption = 0		

'Set a string igual ao sub-diretórios que você segue para seu diretório de imagens
'Esta é a partir do diretório que contém o arquivo que executa "counter.asp"

    imageDirectory = "images/"		

'
'Coletando informações
    strCurrentIP = Request.ServerVariables("REMOTE_ADDR")
    strFilePath = Server.MapPath("counter.txt")
    Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
'
' Verificando o arquivo contador.txt
    If (objFSO.FileExists(strFilePath)) then
      Set objCounterFile = objFSO.OpenTextFile(strFilePath, ForReading)
' Lendo as informações do arquivo de texto
      iCounterNumber = Cdbl(objCounterFile.ReadLine) + 1
      strLastIP = Cstr(objCounterFile.ReadLine)
      objCounterFile.Close
    Else
'Se o não existe iniciar a contagem em 1

      iCounterNumber = 1
    End If
'
' Se o IP do visitante atual é diferente do último visitante de IP , inicie a nova informação
    If (strLastIP <> strCurrentIP) then
      Set objCounterFile = objFSO.CreateTextFile(strFilePath, True)
      objCounterFile.WriteLine(iCounterNumber)
      objCounterFile.WriteLine(strCurrentIP)
      objCounterFile.Close
    Else 
      iCounterNumber = iCounterNumber - 1
    End If
'
'Destruir os objetos
    Set objCounterFile = Nothing
    Set objFSO = Nothing
'
'  Configurando o número a ser exibido
'  Esta configuração permite a posterior mudança de imagens a partir do texto
    strCounterNumber = CStr(iCounterNumber)
    While (Len(strCounterNumber) > 0)
      strImageName = Left(strCounterNumber, 1)
      If (displayOption = UseText) then
	Response.Write (strImageName)
      Elseif (displayOption = UseImages) then
	Response.Write ("<IMG SRC=""" & imageDirectory & strImageName & ".gif"" BORDER=0>")
      End If
      strCounterNumber = Mid(strCounterNumber, 2)
    Wend
%>