Pegar URL

[gpassarelli 1]

Galera to montando um esquema de bookmarks para a minha página e gostaria de saber como posso pegar a URL q o usuario está e jogar na variavel X para que quando ele clicar no botao de bookmark ele enviar a URL completa. http://www......../arquivo.asp?id=2 entenderam?

 

Abracos

[otaviojames 0]

Você fala deixar a URL amigavel?

 

Pegar a url seusite.com.br/noticias/show/index.php?id=1 e transformar em seusite.com.br/noticias/show/index/id/1

[xanburzum 169]

existem algumas para isso no laboratório de script, dê uma pesquisada, pode te ajudar...

[gpassarelli 1]

Você fala deixar a URL amigavel?

 

Pegar a url seusite.com.br/noticias/show/index.php?id=1 e transformar em seusite.com.br/noticias/show/index/id/1

 

Caro otaviojames, url amigáveis é uma outra coisa que gostaria de procurar mas já fiquei sabendo onde tem...

A razao deste post é a seguinte, gostaria de salvar a URL completa em q o usuario está na variavel X. por exemplo:

se o usuario esta na pagina: http://www.seusite.com.br/pagina1.asp ele vai jogar para a variavel X o valor:http://www.seusite.com.br/pagina1.asp

so isso,entendeu?

 

Abracos

[xanburzum 169]

Às vezes, você pode querer obter a URL da página atual que é mostrado na janela de URL do navegador.

 

<%
function curPageURL()
 dim s, protocol, port

 if Request.ServerVariables("HTTPS") = "on" then
   s = "s"
 else
   s = ""
 end if  
 
 protocol = strleft(LCase(Request.ServerVariables("SERVER_PROTOCOL")), "/") & s 

 if Request.ServerVariables("SERVER_PORT") = "80" then
   port = ""
 else
   port = ":" & Request.ServerVariables("SERVER_PORT")
 end if  

 curPageURL = protocol & "://" & Request.ServerVariables("SERVER_NAME") &_
              port & Request.ServerVariables("SCRIPT_NAME")
end function

function strLeft(str1,str2)
 strLeft = Left(str1,InStr(str1,str2)-1)
end function
%>

Agora você pode obter o URL da página atual usando a linha

 

<%
  response.write(curPageURL())
%>

Se a sua página tinha Querystring informações que você deseja, assim você pode experimentar um código como este:

 

<%
  response.write(curPageURL() & "?" & Request.ServerVariables("QUERY_STRING"))
%>

Se a sua página tinha informações de formulário que pode ter sido enviado para ele, então use o seguinte código:

<%
  response.write(curPageURL() & "?" & Request.Form)
%>

Às vezes é necessário para obter o nome da página só. O seguinte exemplo mostra como fazê-lo

 

<%
function curPageName()
 dim pagename

 pagename = Request.ServerVariables("SCRIPT_NAME") 

  if inStr(pagename, "/") > 0 then 
    pagename = Right(pagename, Len(pagename) - instrRev(pagename, "/")) 
  end if 

 curPageName = pagename
end function

response.write("The current page name is " & curPageName())
%>