[Resolvido] classe linkedtube

[saloeric 1]

olá, desenvolvi esta classe que faz uso do linkedtube ,

 

<%
Class linkedtube

	private p_leitor
	
	public altura 
	public largura 
	public txtbotao
	public urlbotao
	public titulo
	public texto
	public modo
	
	'inicializar classe 
	Private Sub Class_Initialize() 
 	altura = 144 
 	largura = 225 
		txtbotao = ""
		urlbotao = ""
		titulo = ""
		texto = ""
		modo = "never"
	End Sub 
 	
	'fechar classe 
	Private Sub Class_Terminate() 
	End Sub 
 	
	'leitor 
	Public Property get leitor() 
		leitor = p_leitor 
	End Property 
	Public Property let leitor(p_data) 
		p_leitor = p_data 
	End Property 
 	
	'Funções Privadas 
	Private Function obterid(endereco) 
		endereco = Mid(endereco,inStr(endereco,"=")+1,len(endereco)) 
		if inStr(endereco,"&") > 0 then 
 		endereco = left(endereco,inStr(endereco,"&") - 1) 
		end if 
 	obterid = endereco 
	End Function 
 	
	'Funções Públicas 
	Public Sub video(url) 
		o_leitor = "<object classid='clsid:d27cdb6e-ae6d-11cf-96b8-444553540000' codebase='http://fpdownload.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=8,0,0,0' type='application/x-shockwave-flash' width='"&largura&"' height='"&altura&"'>"_
		&"<param name='movie' value='http://www.linkedtube.com/static/flash/player.swf?sum="&texto&"&btn="&txtbotao&"&txt="&titulo&"&vis="&modo&"&url="&urlbotao&"&vid="&obterid(url)&"'/>"_
		&"<param name='quality' value='high' />"_
		&"<param name='wmode' value='transparent' />"_ 
		&"<param name='menu' value='false' />"_
		&"<embed src='http://www.linkedtube.com/static/flash/player.swf?sum="&texto&"&btn="&txtbotao&"&txt="&titulo&"&vis="&modo&"&url="&urlbotao&"&vid="&obterid(url)&"' width='"&largura&"' height='"&altura&"' quality='high' menu='false' wmode='transparent' pluginspage='http://www.macromedia.com/go/getflashplayer' type='application/x-shockwave-flash'></embed>"_
		&"</object>"
		me.leitor = o_leitor 
	End Sub 
 	
End Class

'exemplo

set y = New linkedtube
 	y.largura = 400 'largura do vídeo
 y.altura = 200 'altura do vídeo
 y.txtbotao = "Clique aqui" 'nome a dar ao botão que aparece no vídeo
 y.urlbotao = "http://www.google.com" 'url para o botão
 y.titulo = "Google" 'título que aparece ao lado do botão
 	y.texto = "Promoção xpto" 'frase que aparece por baixo do título
 y.modo = "hover" 'modo como é apresentado o botão, 3 maneiras, never, hover ou static
 	call y.video("http://www.youtube.com/watch?v=MrjUwb2ERBw&feature=fvw") 'aqui chamamos a função que vai carregar o vídeo com as variáveis anteriores
 	response.write y.leitor 'aqui apresentamos o leitor
set y = nothing


%>