Botão para adicionar.

[Clynton 0]

Bom dia amigos,

Gostaria de saber como crio um botão no formulário para adicionar imagens.

Grato pela atenção!

 

Abraço...

[Julien.Sorel 0]

Olá Clynton,

 

Imagino que você deseja inserir imagens em uma tabela a partir do clique em um botão, em um formulário...

 

Caso se isso, fácil; basta dá uma olhada abaixo. Caso não, foi mal - aguardo maiores explicações...

 

 

1 - O cara que chama a função, passando o campo do formulário/tabela que receberá a imagem...

 

Private Sub inserirLogoLabel_Click()

   On Error GoTo Err_Trat

       If MsgBox("Deseja inserir o logotipo?", vbQuestion + vbYesNo, C_Title) = vbYes Then
           Call InserirOLE(Form_frmOrigem.ORG_LOGO)
       Else
           Exit Sub
       End If


Exit_Trat:
   Exit Sub

Err_Trat:
   C_MsgErr
   Resume Exit_Trat

End Sub

 

 

2 - Procedure que realiza a inserção da imagem no formulário/tabela:

 

Sub InserirOLE(NmCampo As Object)

   Dim strPath As String
   strPath = modFileDialog("bmp")

   With NmCampo
       .OLETypeAllowed = acOLEEmbedded
       .SourceDoc = strPath
       .Action = acOLECreateEmbed
   End With

End Sub

 

 

3 - Caixa de diálogo para selecionar o arquivo de imagem:

 

Function modFileDialog(Ext As String) As String

   Dim fd As FileDialog
   Dim vrtSelectedItem As Variant

   'Rotina padrão para a seleção de arquivos via dialog
   Set fd = Application.FileDialog(msoFileDialogFilePicker)

   With fd
       .InitialFileName = CurrentProject.Path 'Informa o folder padrão
       .Filters.Add "File ." & Ext, "*." & Ext, 1 'Filtra tipo de extensão
       .Title = "Select a file" 'Texto da barra

       Dim strCaminho As String
       If .Show = -1 Then
           For Each vrtSelectedItem In .SelectedItems
               strCaminho = vrtSelectedItem 'Atribuição do path
           Next vrtSelectedItem
       End If

   End With
   Set fd = Nothing
   modFileDialog = strCaminho 'Função recebe o caminho conseguido

End Function

 

 

 

PS: você precisa habilitar "Microsoft Office 12.0 Object Library” no ambiente de desenvolvimento VBA – ir até Ferramentas > Referências e selecione a opção mencionada acima. Ou acesse o link, que possuir maiores explicações...

 

 

 

Sem mais,

 

Julien Sorel

_________________________________________________________________

 

ef3cinco.worpress.com | Programação - não importa a linguagem...

 

ememestore.com.br | Onde você encontra...

[Clynton 0]

Julien, agradeço primeiramente pela sua atenção.

Demorei por que não tenho o costume de acessar, embora eu tenha pedido ajuda.

Ainda não domino o Access, por isso te peço mais um help.

Você entendeu certo, o que eu quero é realmente um botão que me permita inserir uma imagem na tabela, através do Form num campo Objeto OLE, porém não sei onde devo colocar os códigos que você passou.

Já habilitei o Microsoft Office no Editor do VBA, mas não sei mesmo onde vou colocar esses códigos e quando eu colocar, tenho que mudar algum nome?

O botão que eu criar pode ter qualquer nome ou tem que ter um nome específico para o código funcionar?

Antes de inserir o código, tenho que alterar alguma propriedade do botão?

 

Grato.

Abraço...

[Julien.Sorel 0]

Olá Clynton,

 

Você pode deve manter os nomes das funções "InserirOLE" e "modFileDialog", mas pode inserir qualquer nome no botão e não é necessário alterar nenhuma propriedade no botão.

 

E acho que é só...

 

 

 

 

Sem mais,

 

Julien Sorel

_________________________________________________________________

 

ef3cinco.worpress.com | Programação - não importa a linguagem...

 

ememestore.com.br | Onde você encontra...

[Clynton 0]

Bom dia Julien,

 

Depois de criar a botão, onde devo inserir os códigos que você me passou anteriormente?

 

Abraço...