[Resolvido] Persits.MailSender e SMTP.GMAIL.COM

[luiscarlos5046 3]

Olá Galera!

 

Já procurei em muitos lugares e não consegui encontrar uma solução funcional para ASP.

Eu tenho esse código que utiliza o "Persits.MailSender" para enviar o email e um anexo.

 

Set Mail = Server.CreateObject("Persits.MailSender")
Mail.Host = "SMTP.GMAIL.COM"
Mail.Username = "noreply@site.com.br"
Mail.Password = "senha_do_email"
'Mail.TLS = True
Mail.Port = 587
Mail.From = email
Mail.FromName = nome
Mail.Subject = "Curriculum enviado através do site"
Mail.AddAddress "email_to@site.com.br"
Mail.IsHTML = true
Mail.Body = corpo

If Not Upload.Files("Attachment") Is Nothing Then
  Mail.AddAttachment Upload.Files("Attachment").Path
End If

On Error Resume Next
Mail.Send

 

Me parece que o GMail não está aceitando alguma coisa nestas definições acima. Não funciona.

 

Alguem tem uma solução ?

 

Luis Carlos

[xanburzum 169]

ele esta gerando algum erro ?

[luiscarlos5046 3]

Sim,

 

Se deixar o TLS habilitado dá esse erro:

Microsoft VBScript runtime error '800a01b6'

Object doesn't support this property or method: 'TLS'

/trabalhe_send.asp, line 29 

 

e se deixar comentado a linha do TLS dá esse erro:

530 5.7.0 Must issue a STARTTLS command first. il8sm23694935obc.18 

[xanburzum 169]

não existe esa propriedade no MailSender, tem certeza que esse TLS, realmente existe ?

você verificou se o componente tem esse comando TLS ?

veja no site do fabricante, ou seja direto no Persits.MailSender.

 

e existem alguns exemplo que coloquei de como enviar email usando o gmail, e verifique também se no gmail esta habilitado o POP e SMTP dentro do painel do gmail.

[luiscarlos5046 3]

Xanburzum,

Eu vi isso nos exemplos do site do fabricante mesmo. Mas deve ser caso de versões, sei lá.

 

Tem outra coisa: Estou usando o componente da Persits, mas caso você tenha algum exemplo com CDO que envie usando o SMTP do Gmail, pode me indicar ?

 

Olha só que recebi a poucos:

Hi Friend,

In your code make sure the smtp.EnableSsl = true; should be present because gmail required secure socket (SSL)
               SmtpClient smtp = new SmtpClient();
               smtp.EnableSsl = true;
Smtp.Client.EnableSsl = true;
               smtp.Send(message); 

other than that in web.config check for following settings.

 

Acho que isso é pra .Net... só que estou usando ASP clássico.

Tem algum outro componente que habilite isso?

 

Luis Carlos

[luiscarlos5046 3]

Ae pessoal, pra envio de email somente eu achei uma solução com CDO.

Agora falta o envio de anexos.

Segue abaixo código:

<%
nome = Upload.form("nome")
email = Upload.form("email")
fone = Upload.form("fone")
objetivo = Upload.form("objetivo")
celular = Upload.form("celular")

On Error Resume Next

assunto = "Contato enviado através do site [ NOME DO SITE ]"
servidorsmtp = "smtp.gmail.com"
contaautenticada = "noreply@servidor.com.br"
senhaparaenvio = "suasenha"
emailorigem = email
emaildestino = "nomemail@destino.com.br"

strBody = ""
strBody = strBody & "<span style='font-family:Tahoma, Geneva, sans-serif; font-size:14px;'>"
strBody = strBody & "Curriculum enviado através do site [ <strong>NOME DO SITE</strong> ] <br /><br />"
strBody = strBody & "Nome : <strong>"& nome &"</strong> <br /><br />"
strBody = strBody & "Email : <a href='mailto:"& email &"'><strong>" & email & "</strong></a><br /><br />"
strBody = strBody & "Fone : <strong>"& fone &"</strong> <br /><br />"
strBody = strBody & "Celular : <strong>"& celular &"</strong> <br /><br />"
strBody = strBody & "OBJETIVO DO TRABALHO :<br /><br />"
strBody = strBody & "<strong>"& objetivo &"</strong> <br />"
strBody = strBody & "</span>"

Set objCDOSYSMail = Server.CreateObject("CDO.Message")
Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")

objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com"
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport")= 465
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objCDOSYSCon.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusername") = "noreply@servidor.com.br"
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "suasenha"
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
objCDOSYSCon.Fields.update 

Set objCDOSYSMail.Configuration = objCDOSYSCon
objCDOSYSMail.BodyPart.Charset = "iso-8859-1"
objCDOSYSMail.From = emailorigem
objCDOSYSMail.To = emaildestino
objCDOSYSMail.Subject = assunto
'objCDOSYSMail.TextBody = strBody
objCDOSYSMail.HtmlBody = strBody

'objCDOSYSMail.ReplyTo = "emailDeResposta@dominio.com"
'objCDOSYSMail.Cc = "destinatario@dominio.com"
'objCDOSYSMail.Bcc = "destinatario@dominio.com"

objCDOSYSMail.Send

Set objCDOSYSMail = Nothing
Set objCDOSYSCon = Nothing

if err.number <> 0 then
%>
<script>
	alert(" Desculpe, houve um erro ao enviar seu contato. \n Tente novamente. \n Erro nº <%=err.number%>.");
	history.back();
</script>
<%
else
%>
<script>
	alert("Seu contato foi enviado com sucesso!");
	window.location='index.asp?link=trabalhe';
</script>
<%
end if
%>

[xanburzum 169]

eu uso assim com CDO

 

Dim objCDOSYSMail

Dim objCDOSYSCon
Set objCDOSYSMail = Server.CreateObject("CDO.Message")

Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com"
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'Aqui estava o meu problema: SSL tem que ser TRUE!
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True

'o e-mail completo que você utiliza no google apps (não esqueça de habilitar SMTP no painel fo Google apps!
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusername") = "eu@teste .org"
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "senha"
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 30

objCDOSYSCon.Fields.update 
Set objCDOSYSMail.Configuration = objCDOSYSCon

objCDOSYSMail.From = "Newsletter teste "
objCDOSYSMail.To = "Nome <email@teste .org>"
objCDOSYSMail.Subject = "teste - Newsletter "
objCDOSYSMail.HtmlBody = email
objCDOSYSMail.Send

Set objCDOSYSMail = Nothing 
Set objCDOSYSCon = Nothing 

 

O Google libera o envio de apenas 500 e-mails por conta para evitar o uso indevido do Google Apps, por isso você pode utilizar duas ou mais contas se for necessário o envio de Newsletter assim. Por exemplo, crie as contas:

 

news1@andafter.org

news2@andafter.org

news3@andafter.org

news4@andafter.org

 

Assim você pode realizar o disparo de 2.000 mensagens a cada 24h, configurando cada grupo de usuário para ser atendido por uma conta de e-mail.

 

e para enviar com anexo

você pode especificar o caminho do arquivo usando Server.MapPath também

ObjSendMail.AddAttachment "c:\myweb\somefile.jpg"

[luiscarlos5046 3]

Obrigado xanburzum !

 

Essa parte está encerrada.