Gravar no Banco TEXTO

[marcelocardoso 6]

Galera.
Num editor de noticias por exemplo, usar qualquer editor WYSIWYG para inserir noticias copiadas de outros sites para banco de dados, pergunto:
Qual a maneira correta de limpar todas as TAGS HTML, deixando somente o TEXTO antes de gravar, e TRATAR somente oque quer deixar no TEXTO, tipo: deixar passar somente, <B> <EM> <STRONG>, etc....

Tem alguma função no repositorio que faça isso.
Fica a pergunta e a solicitação de conhecimento...

Até....

[marcelocardoso 6]

Pesquisando bastante, consegui uma função que estou adaptando, bem boa...
Serve para fazer oq se precisa neste caso, UMA SOLUÇÃO:

 

<%
 
   FUNCTION RemoveHTML(strText)
   Dim TAGLIST
       TAGLIST = ";!--;!DOCTYPE;A;ACRONYM;ADDRESS;APPLET;AREA;B;BASE;BASEFONT;BGSOUND;BIG;BLOCKQUOTE;BODY;BR;BUTTON;CAPTION;CENTER;CITE;CODE;COL;COLGROUP;COMMENT;DD;DEL;DFN;DIR;DIV;DL;DT;EM;EMBED;FIELDSET;FONT;FORM;FRAME;FRAMESET;HEAD;H1;H2;H3;H4;H5;H6;HR;HTML;I;IFRAME;IMG;INPUT;INS;ISINDEX;KBD;LABEL;LAYER;LAGEND;LI;LINK;LISTING;MAP;MARQUEE;MENU;META;NOBR;NOFRAMES;NOSCRIPT;OBJECT;OL;OPTION;P;PARAM;PLAINTEXT;PRE;Q;S;SAMP;SCRIPT;SELECT;SMALL;SPAN;STRIKE;STRONG;STYLE;SUB;SUP;TABLE;TBODY;TD;TEXTAREA;TFOOT;TH;THEAD;TITLE;TR;TT;U;UL;VAR;WBR;XMP;"

   Const BLOCKTAGLIST = ";APPLET;EMBED;FRAMESET;HEAD;NOFRAMES;NOSCRIPT;OBJECT;SCRIPT;STYLE;"

   
   Dim nPos1
   Dim nPos2
   Dim nPos3
   Dim strResult
   Dim strTagName
   Dim bRemove
   Dim bSearchForBlock

            nPos1 = InStr(strText, "<")
   DO WHILE nPos1 > 0
            nPos2 = InStr(nPos1 + 1, strText, ">")
         IF nPos2 > 0 Then

            strTagName = Mid(strText, nPos1 + 1, nPos2 - nPos1 - 1)
            strTagName = Replace(Replace(strTagName, vbCr, " "), vbLf, " ")

               nPos3 = InStr(strTagName, " ")
            IF nPos3 > 0 Then
               strTagName = Left(strTagName, nPos3 - 1)
            END IF

                  IF Left(strTagName, 1) = "/" Then
                          strTagName = Mid(strTagName, 2)
                     bSearchForBlock = False
                  ELSE
                     bSearchForBlock = True
                  END IF

                        IF InStr(1, TAGLIST, ";" & strTagName & ";", vbTextCompare) > 0 Then
                                 bRemove = True

                           IF bSearchForBlock Then
                              IF InStr(1, BLOCKTAGLIST, ";" & strTagName & ";", vbTextCompare) > 0 Then
                                 nPos2 = Len(strText)
                                 nPos3 = InStr(nPos1 + 1, strText, "</" & strTagName, vbTextCompare)
                                     IF nPos3 > 0 Then
                                        nPos3 = InStr(nPos3 + 1, strText, ">")
                              END IF

                              IF nPos3 > 0 Then
                                 nPos2 = nPos3
                              END IF

                           END IF

                        END IF

            ELSE
                bRemove = False
            END IF

            IF bRemove Then
               strResult = strResult & Left(strText, nPos1 - 1)
                 strText = Mid(strText, nPos2 + 1)
            ELSE
                           strResult = strResult & Left(strText, nPos1)
                 strText = Mid(strText, nPos1 + 1)
            END IF

         ELSE

            strResult = strResult & strText
                                    strText = ""
         END IF

               nPos1 = InStr(strText, "<")

      LOOP
                      strResult = strResult & strText
         RemoveHTML = strResult
   END FUNCTION
%>

Aí determina oque deseja passar ou não nas TAGLIST e BLOCKLIST.
Muito boa....

Fica a dica...
Valeu galera...