Cotação Do Euro

[Bruno Saito 0]

Aew pessoal, tenho uum site e preciso das cotações do Euro e do Dolar, mas não serve somente o dolar como o que eu tenho do BCB, o que preciso mesmo eh de um codigo ou algo de preferencia em ASP, jah que meu site não funciona com PHP, que busque informações de um outro site, que pege os dados e jogue no meu site, e sempre que lá é atualizado o meu site também é.. preciso disso de preferencia com o EURO, pq o Dolar eu jah consegui...

por favor alguem me ajude

[jrcardozo 4]

primeiro você deve ter o site onde tem as informações desejadas, depois você cria um xmlhttp e tenta capturar esses valores pra jogar no seu site

[Bruno Saito 0]

Eu sou mt leigo ainda nisso..você poderia me da uma luz e me falar onde tem um tutorial disso?

[hargon 64]

Fiz este código semana passada. Está buscando os dados do site da Folha. Caso seu servidor não possua o Dynu.HTTP é só alterar o componente.

<%
'#################################################
'#   Criado por: hargon
'#   Data: 03/03/2007
'#################################################

	set oHTTP = Server.Createobject("Dynu.HTTP")
	
	oHttp.SetURL "http://www.folha.uol.com.br/"

	conteudo = lcase(oHttp.PostURL())
	
	posicao = instr(conteudo,"trj-homepage-indicadores")
	total = len(conteudo)
	conteudo = mid(conteudo,posicao,total)	
	
	posicao = instr(conteudo,vbCrLf)
	total = len(conteudo)
	conteudo = mid(conteudo,posicao+1,total)	
	
	posicao = instr(conteudo,"<td class="&chr(34)&"financierDataKicker"&chr(34)&">")
	total = len(conteudo)
	conteudo = mid(conteudo,posicao+1,total)	
	
	posicao = instr(conteudo,">")
	total = len(conteudo)
	conteudo = mid(conteudo,posicao+1,total)

	dim indicadores
	redim indicadores(6,2)
	indicadores(1,1) = "Bovespa"
	indicadores(2,1) = "Nasdaq"
	indicadores(3,1) = "Dólar comercial"
	indicadores(4,1) = "Dólar paralelo"
	indicadores(5,1) = "Dólar turismo"
	indicadores(6,1) = "Euro"

	xy = 0
	for xy=1 to 6
		posicao = instr(conteudo,lcase(indicadores(xy,1)))
		if posicao > 0 then
			total = len(conteudo)		
			conteudo = mid(conteudo,posicao,total)	

			posicao = instr(conteudo,chr(34)&">")
			if posicao > 0 then
				total = len(conteudo)
				conteudo = mid(conteudo,posicao+2,total)

				posicao = instr(conteudo,"</td>")
				if posicao > 0 then
					total = len(conteudo)
					conteudo = mid(conteudo,posicao+5,total)
					posicaofim = instr(conteudo,"</td>")
					if posicaofim > 0 then
						total = len(conteudo)	
						indicadores(xy,2) = left(conteudo,posicaofim-1)
						if instr(indicadores(xy,2)," ") then
							indicadores(xy,2) = replace(indicadores(xy,2)," ","")
						end if
					end if
				end if
			end if
		end if
	next

	conteudo = empty
	set oHTTP = nothing
	
	for xy=1 to 6
		if len(indicadores(xy,2)) > 0 then
			response.write indicadores(xy,1) & ": " & UCASE(indicadores(xy,2)) & "<br />"
		end if
	next
%>

Se usar o código acima, mantenha os créditos por favor. http://forum.imasters.com.br/public/style_emoticons/default/thumbsup.gif

[Bruno Saito 0]

Valew Atur, mas eu não consegui utilizar essa codificação, e nem altera-la...

o que pode ser feito pra alterar ela..?

eu achei esse site: http://cotacoes.agronegocios-e.com.br/inve...p;title=%20Euro

neme tem o que eu quero, mas eu queria saber como pegar os dados de lah..

poderia me ajudar?

[hargon 64]

Qual componente o seu servidor possui? ASPHTTP, XMLHTTP?

[Bruno Saito 0]

Qual componente o seu servidor possui? ASPHTTP, XMLHTTP?

O Que eu to Usando para o Dolar é o XMLHTTP, mas o meu site é todo feito em ASP..se você conhece algo poderia me passar pra me ajudar =D

[hargon 64]

Taí o código com XMLHTTP. Só que ele está retornando apenas Bovespa, Nasdaq e Euro.

<%
'#################################################
'#   Criado por: hargon
'#   Data: 03/03/2007
'#################################################

	Set objXMLHTTP = CreateObject("Msxml2.XMLHTTP")
	Url = "http://www.folha.uol.com.br/"
	objXMLHTTP.Open "GET", URL, FALSE
	objXMLHTTP.send()
	conteudo = objXMLHTTP.responseText
	set objXMLHTTP = nothing

'	set oHTTP = Server.Createobject("Dynu.HTTP")
'	oHttp.SetURL "http://www.folha.uol.com.br/"
'	conteudo = lcase(oHttp.PostURL())
'	set oHTTP = nothing
	
	posicao = instr(conteudo,"trj-homepage-indicadores")
	total = len(conteudo)
	conteudo = mid(conteudo,posicao,total)	
	
	posicao = instr(conteudo,vbCrLf)
	total = len(conteudo)
	conteudo = mid(conteudo,posicao+1,total)	
	
	posicao = instr(conteudo,"<td class="&chr(34)&"financierDataKicker"&chr(34)&">")
	total = len(conteudo)
	conteudo = mid(conteudo,posicao+1,total)	
	
	posicao = instr(conteudo,">")
	total = len(conteudo)
	conteudo = mid(conteudo,posicao+1,total)

	dim indicadores
	redim indicadores(6,2)
	indicadores(1,1) = "Bovespa"
	indicadores(2,1) = "Nasdaq"
	indicadores(3,1) = "Dólar comercial"
	indicadores(4,1) = "Dólar paralelo"
	indicadores(5,1) = "Dólar turismo"
	indicadores(6,1) = "Euro"

	xy = 0
	for xy=1 to 6
		posicao = instr(lcase(conteudo),lcase(indicadores(xy,1)))
		if posicao > 0 then
			total = len(conteudo)		
			conteudo = mid(conteudo,posicao,total)	

			posicao = instr(conteudo,chr(34)&">")
			if posicao > 0 then
				total = len(conteudo)
				conteudo = mid(conteudo,posicao+2,total)

				posicao = instr(conteudo,"</td>")
				if posicao > 0 then
					total = len(conteudo)
					conteudo = mid(conteudo,posicao+5,total)
					posicaofim = instr(conteudo,"</td>")
					if posicaofim > 0 then
						total = len(conteudo)	
						indicadores(xy,2) = left(conteudo,posicaofim-1)
						if instr(indicadores(xy,2)," ") then
							indicadores(xy,2) = replace(indicadores(xy,2)," ","")
						end if
					end if
				end if
			end if
		end if
	next

	conteudo = empty
	
	for xy=1 to 6
		if len(indicadores(xy,2)) > 0 then
			response.write indicadores(xy,1) & ": " & UCASE(indicadores(xy,2)) & "<br />"
		end if
	next
%>