Sistema com templates

Web Design Valdeci · Dezembro 20, 2007

Fala pessoal,

Gostaria de saber se alguem conhece algum script ou sistema que utiliza templates, ou seja, o site é todo dinâmico, você pode modificar o conteúdo e escolher o modelo de template que usará em uma lista. Exemplo este site aqui ://www.redehost.com.br/construtor/?l=gl7

O que quero mesmo é saber como faço para chamar um template html e rodar meu código asp em cima dele.

vi este tópico aqui mas nao ajudou em nada. ://forum.imasters.com.br/index.php?showtopic=16090&hl=template

Valeu.

Ted k' · Dezembro 22, 2007

rapaz, fiz um esquema desses e é fácil, muito fácil mesmo mais só que ñ tenho como explicar assim, você aprende e coloca funções com o tempo, o projeto que desenvolvi foi grande e chato, muitas adaptações e erros, hoje ele roda legal e sempre tenho que ficar atualizando, nada que umas funções de inserir, deletar, atualizar e selecionar ñ resolva.

Não conheço nenhum script pronto mais se você dê uma olhada nesses sites de codigo fonte você pode ter mais sorte

scriptfacil.com.br

scriptbrasil.com.br

wmonline.com.br

dentre outros!

DSerma · Dezembro 22, 2007

Se você quiser mudar apenas as cores, o alinhamento ou a posição dos objetos da página, ou alguma outra coisa que não mude MUITO a página... você pode usar o CSS...

Crie alguns arquivos CSS e faça uma função para quando o cara clicar em algum botão, o arquivo CSS seja trocado....

Eu faço assim.... é só uma idéia...

Abraços...

Web Design Valdeci · Dezembro 28, 2007

rapaz, fiz um esquema desses e é fácil, muito fácil mesmo mais só que ñ tenho como explicar assim, você aprende e coloca funções com o tempo, o projeto que desenvolvi foi grande e chato, muitas adaptações e erros, hoje ele roda legal e sempre tenho que ficar atualizando, nada que umas funções de inserir, deletar, atualizar e selecionar ñ resolva.

Não conheço nenhum script pronto mais se você dê uma olhada nesses sites de codigo fonte você pode ter mais sorte

scriptfacil.com.br

scriptbrasil.com.br

wmonline.com.br

dentre outros!

Seguinte cara, se você quiser me vender eu compro este sistema. Qualquer coisa manda um e-mail pra mim valdeci.alves@gmail.com. Valeu

Se você quiser mudar apenas as cores, o alinhamento ou a posição dos objetos da página, ou alguma outra coisa que não mude MUITO a página... você pode usar o CSS...

Crie alguns arquivos CSS e faça uma função para quando o cara clicar em algum botão, o arquivo CSS seja trocado....

Eu faço assim.... é só uma idéia...

Abraços...

valeu cara mas eu preciso de modificar td mesmo, vou ter templates prontos e o cara so escolhe. mas valeu mesmo.

Diego Darlan (DDarlan) · Novembro 30, 2008

Estrutura básica de template, para sistema em ASP. segue o coddigo abaixo.

{}

class_template.asp

<%
Class Template
Private CorpoTmp, RegVars

Public Sub Registrar(RegNome)
RegVars = split(RegNome,",")
End Sub

Public Sub Parse()
Dim Tmp, Itens
For Each Itens in RegVars
Tmp = Replace(CorpoTmp,"<#"+Itens+">",Session(Itens))
CorpoTmp = Tmp
Next
CorpoTmp = Tmp
End Sub

Public Sub Print()
Response.Write(CorpoTmp)
End Sub

Public Sub Arquivo(Nome)
Dim FSO, TS
Const Leitura = 1
Set FSO = CreateObject("Scripting.FileSystemObject")
Set TS = FSO.OpenTexTFile(Nome, Leitura)
CorpoTmp = TS.ReadAll
TS.Close()
End Sub

End Class
%>

default.asp

<!-- #include file="class_template.asp" -->
<%
Dim Conteudo, Titulo

Session("Conteudo") = "lbarbosa@grupo5.com.br"
Session("Titulo") = "Testando Template"

Set Test = new Template
Test.Arquivo(Server.MapPath("test.html"))
Test.Registrar("Titulo,Conteudo")
Test.Parse
Test.Print
%>

test.html

<Html>
<head>
<title><#Titulo></title>

<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
</head>

<center>
<h1><#Conteudo></h1>
</center>

<body>

</body>
</html>

PS.: Bom até fácil, agora eu quero fazer um tipo assim:
<loop name="categorias">
<center>
<h1><#Conteudo></h1>
</center>
</loop>
sendo que "categorias" é o vetor no ASP registrado do template, oq a classe template vai fazer é saber quantos itens tem esse vetor e depois repetir ele nessas linhas:
<center>
<h1><#Conteudo></h1>
</center>
Jogando "<#Conteudo>" o conteúdo de cada vetor "Categorias" até terminar os itens

xanburzum · Novembro 30, 2008

Este código formata páginas em um site dinâmico, baseando o layout, cores e formatação contidos em um arquivo modelo HTML com algumas tags personalizadas.

buildpage.asp

<%
'===============================================
'Você pode usar o código e as funções dentro desta 
'aplicação de modelo  em qualquer site da web 
'-----------------------------------------------
strTemplateLocation = request.cookies("templatesample")("templatepath")

'-----------------------------------------------
'Se o cookie é em branco (ou seja, não existe) 
'Então vamos definir o nosso modelo para um padrão.
'-----------------------------------------------
If request.cookies("templatesample")("templatepath") ="" then
	strTemplateLocation="templates/skin_default/"
	response.cookies("templatesample")("templatepath") =""
End if

'-----------------------------------------------
'Para o datastamp, vamos criar uma string de HTML 
'Em que podemos adicionar a página mais tarde. Qualquer 
'Outro texto dinâmico que precisa ser incluída 
'Em cada página pode ser criada nesta 
'E armazenada como uma seqüência de HTML.
'-----------------------------------------------
strDateStampHTML = Ucase(day(now()) & " " & monthname(month(now())) & " " & year(now()))

'-----------------------------------------------
'Esta função permite-nos ler a página HTML 
'A partir do modelo e guarda-la como uma string. 
'Então ajustar o caminho das imagens (para que os nossos 
'Páginas na raiz usando o link para o modelo 
'O caminho correto do modelo da imagem 
'Pasta. Em seguida, substitua o "tags" especiais xxx 
'No modelo com o conteúdo dessa seqüência 
'Como data que criamos acima. Finalmente, damos 
'Split em toda a string em uma página
'Array, com a separação feita em torno do 
'XxxPAGECONTENTxxx tag. As duas secções de 
'HTML serão posteriormente acrescentados acima e abaixo da 
'Conteúdo essencial em cada extremidade dianteira página.
'-----------------------------------------------

Function ReadFromTemplate(strTemplateLocation,aryPageTemplate,strDateStampHTML)

	'------------------------------------
	'Loop através de arquivo modelo conteúdo
	'------------------------------------
	Set FileObject = Server.CreateObject("Scripting.FileSystemObject")
	BodytextFile = Server.MapPath(strTemplateLocation & "main/template.htm")
	Set InStream= FileObject.OpenTextFile (BodytextFile, 1, False, False)
	While not InStream.AtEndOfStream
	strPageBaseText = strPageBaseText & InStream.ReadLine & vbcrlf
	Wend
	Set Instream = Nothing

	'------------------------------------
	'Página formato HTML string
	'------------------------------------
		strPageBaseText = Replace(strPageBaseText,"../images",strTemplateLocation & "images")
		'Fix caminho do modelo imagens

		strPageBaseText = Replace(strPageBaseText,"../","")
		'Ajustar hyperlinks no modelo de caminho correto

		strPageBaseText = Replace(strPageBaseText,"xxxDATESTAMPxxx",strDateStampHTML)
		'Adicione a data para a página, substituindo a xxxDATESTAMP com a string que criamos acima

		aryPageTemplate = split(strPageBaseText ,"xxxPAGECONTENTxxx",-1)
		'Crie uma two-box array através da splitting da página HTML ao redor do xxxPAGECONTENTxxx tag
	

	ReadFromTemplate = aryPageTemplate

END Function

%>

default.asp

<%@ LANGUAGE="VBSCRIPT" %>
<!--#include file="buildpage.asp"-->
<%
'-----------------------------------------------
'Ler página modelo a partir do arquivo					
'-----------------------------------------------
Call ReadFromTemplate(strTemplateLocation,aryPageTemplate,strDatestampHTML)

'-----------------------------------------------
''Escrever primeira parte da página HTML					
'-----------------------------------------------
response.write(aryPageTemplate(0))


%>
<table border="0" cellpadding="5" cellspacing="0" width="100%">
  <tr>
	<td class="largebold">This is the First Page </td>
  </tr>
  <tr>
	<td class="medium">Esta é a primeira página da amostra. Ao clicar sobre o 
	   menu links nesta página, você pode ver mais páginas. As páginas devem 
	   aparecem usando o mesmo modelo. 
	   <p> Mas, se você clicar no link abaixo, o navegador vai ser encaminhada através 
	   uma outra página ASP, o que poderá criar um cookie e voltar a esta página. O 
	   cookie vai dizer a função que formata a esta página 
	   utilizar um outro modelo. Você estará vendo essa mesma página, mas será 
	   formatado utilizando um modelo diferente. O conteúdo será o mesmo, mas o 
	   page layout, cores e fontes serão diferentes.</p>
	  <p><a href="entrypoints/entrypoint2.asp">Ver site usando o modelo alternativo </ a> </ p> 
	   <p> Ok, preferi o primeiro modelo.</p>
	  <p><a href="entrypoints/entrypoint1.asp">Volta para o primeiro modelo utilizando</a> </td>
  </tr>
</table>
<%
'-----------------------------------------------
'última metade da página HTML				
'-----------------------------------------------
response.write(aryPageTemplate(1))
%>

page2.asp

<%@ LANGUAGE="VBSCRIPT" %>
<!--#include file="buildpage.asp"-->
<%
'-----------------------------------------------
'Ler página modelo a partir do arquivo					
'-----------------------------------------------
Call ReadFromTemplate(strTemplateLocation,aryPageTemplate,strDatestampHTML)

'-----------------------------------------------
''Escrever primeira parte da página HTML					
'-----------------------------------------------
response.write(aryPageTemplate(0))


%>
<table border="0" cellpadding="5" cellspacing="0" width="100%">
  <tr>
	<td class="largebold">Esta é a Segunda Pagina </td>
  </tr>
  <tr>
	<td class="medium">Neste pequeno exemplo, a escolha de qual modelo a utilizar é armazenado na 
	   um cookie. Você poderia rígido código-lo apenas se você deseja executar um modelo. 
	   <p> As vantagens desta «pele» que o sistema se você tiver uma melhor 
	   separação entre o conteúdo das páginas e as formatações dos mesmos. 
	   Incluir arquivos podem ir de alguma maneira a fazer isto, mas não possibilitam a 
	   mudar totalmente o layout de um site ao editar uma página modelo visualmente. </ p> 
	   <p> Além disso, utilizando modelos permite exibir páginas diferentes para 
	   propósitos especiais. Em nosso próprio site, nós temos uma "impressão" sobre cada link 
	   Página a página, que simplesmente lembra uma querystring, mas passa a contar a 
	   buildpage.asp função de utilizar um modelo especial imprimir. Isto mostra a 
	   mesmo conteúdo da página, mas em simples preto e branco e sem menus 
	   gráfica de cabeçalhos. Você poderia até usar fontes diferentes também, dado que cada 
	   modelo tem o seu próprio estilo. </td>
  </tr>
</table>
<%
'-----------------------------------------------
'última metade da página HTML				
'-----------------------------------------------
response.write(aryPageTemplate(1))
%>

page3.asp

<%@ LANGUAGE="VBSCRIPT" %>
<!--#include file="buildpage.asp"-->
<%
'-----------------------------------------------
'Ler página modelo a partir do arquivo				
'-----------------------------------------------
Call ReadFromTemplate(strTemplateLocation,aryPageTemplate,strDatestampHTML)

'-----------------------------------------------
''Escrever primeira parte da página HTML				
'-----------------------------------------------
response.write(aryPageTemplate(0))


%>
<table border="0" cellpadding="5" cellspacing="0" width="100%">
  <tr>
	<td class="largebold">Esta é a última página </td>
  </tr>
  <tr>
	<td class="medium">Desta forma torna-se especialmente útil 
	   onde você tem um aplicativo que consistem em conteúdos funcionais ou páginas 
	   que precisam ser marcados de maneira diferente para diferentes sites corporativos. O 
	   caminho diferente é ter cópias de todos os scripts e páginas de conteúdo 
	   - Isso causa pesadelos quando você precisar atualizar o conteúdo ou 
	   funcionalidade. Se você construiu um conjunto de funções para gerar todas as páginas, você 
	   teriam de gerar HTML a maneira mais difícil com declarações Response.Write  
	   o que impede o desenvolvimento rápido de editores visual  e não tratar o 
	   principalmente em páginas de conteúdo estático. 
	   <p> Com este modelo, mesmo a única versão do conteúdo 
	   e scripts podem ser exibidos completamente diferente dependendo de onde o 
	   usuário clica. Passando-os através de uma página de entrada, podemos marca o 
	   site para eles e manter essa marca como eles se movem ao redor do local. </ p> 
	   <p> Trata-se evidentemente de uma simples demonstração. Este princípio poderia ser 
	   facilmente adaptado para executar alta e baixa versões de um site, otimizar páginas 
	   para telas pequenas / WebTV / handhelds e até mesmo apresentar os motores de busca com uma 
	   conteúdo mais rico documento HTML para indexação fins. Mas mesmo 
	   você só quero uma maneira de rebrand rapidamente todo o seu site, editando 
	   um arquivo no FrontPage ou o Dreamweaver, este é ainda valha a pena considerar. </td>
  </tr>
</table>
<%
'-----------------------------------------------
'última metade da página HTML				
'-----------------------------------------------
response.write(aryPageTemplate(1))
%>

entrypoint2.asp

<%
'-----------------------------------------------
'SET modelo cookie e redirecionar para o site principal
'-----------------------------------------------
response.cookies("templatesample")("templatepath") = "templates/skin_alt/"
response.redirect("../default.asp")
%>

entrypoint1.asp

<%
'-----------------------------------------------
'SET modelo cookie e redirecionar para o site principal
'-----------------------------------------------
response.cookies("templatesample")("templatepath") = "templates/skin_default/"
response.redirect("../default.asp")
%>

e dentro da pasta C:\Inetpub\wwwroot\templating_demo\templates\skin_default\main

o template.htm

<html>

<head>

<style>
<!--
.small			{ font-size: 7.5pt; font-family: Verdana,Arial; font-weight: normal }
.smallbold		{ font-size: 7.5pt; font-family: Verdana,Arial; font-weight: bold }
.medium			{ font-size: 9pt; font-family: Verdana,Arial; font-weight: normal }
.mediumbold		{ font-size: 9pt; font-family: Verdana,Arial; font-weight: bold }
.largebold		{ font-size: 14pt; font-family: Verdana,Arial; font-weight: bold }

a:link		{ color: blue; text-decoration: underline; }
a:visited	{ text-decoration: underline; color:blue; }
a:hover		{ text-decoration: underline; color:red; }
-->
</style>

<title>Template  1</title>
</head>

<body>
<table border="0" cellpadding="2" cellspacing="0" width="600">
  <tr>
	<td width="600" colspan="2"><img border="0" src="../images/pageheader.gif" width="582" height="56"></td>
  </tr>
  <tr>
	<td width="600" colspan="2" class="smallbold"><a href="../../../default.asp">Pagina 1</a> |
	  <a href="../../../page2.asp"> Page 2</a> | <a href="../../../page3.asp">Pagina
	  3</a></td>
  </tr>
  <tr>
	<td width="150" class="small" valign="top">xxxDATESTAMPxxx</td>
	<td width="450" valign="top">xxxPAGECONTENTxxx</td>
  </tr>
</table>
</body>

</html>

e também na pasta C:\Inetpub\wwwroot\templating_demo\templates\skin_alt\main

template.htm

<html>

<head>

<style>
<!--
.small			{ font-size: 7.5pt; font-family: Arial; font-weight: normal; color: white;  }
.smallbold		{ font-size: 7.5pt; font-family: Arial; font-weight: bold; color: white; }
.medium			{ font-size: 9pt; font-family: Arial; font-weight: normal; color: white; }
.mediumbold		{ font-size: 9pt; font-family: Arial; font-weight: bold; color: yellow; }
.largebold		{ font-size: 14pt; font-family: Arial; font-weight: bold; color: white; }

a:link		{ color: #9999FF; text-decoration: underline; }
a:visited	{ text-decoration: underline; color:#9999FF; }
a:hover		{ text-decoration: underline; color:red; }
-->
</style>

<title> Template 2</title>
</head>

<body bgcolor="#000000">
<table border="0" cellpadding="2" cellspacing="0" width="100%" bgcolor="#666666">
  <tr>
	<td class="mediumbold" valign="top" colspan="2">Agora, este modelo parece 
	   completamente diferente ... 
	   <p> Repare que o background, fontes, cores,tabela o
	   dimensionamento são todas diferentes. Mas o conteúdo da página é o mesmo. Estas páginas 
	   poderia facilmente ter complexas font de dados ou de funcionalidade apenas conteúdo estático. </ p> 
	   <p> Você pode voltar ao primeiro modelo, clicando no menu Pág. 1 
	   (lado direito da página agora!) e, em seguida, clicando no link em baixo que 
	   Página.</p>
	  <p> </p>
	</td>
  </tr>
  <tr>
	<td valign="top">xxxPAGECONTENTxxx</td>
	<td valign="top" class="medium" width="150" align="center"><p><a href="../../../default.asp">Page 1</a></p>
	  <p><a href="../../../page2.asp">Pagina 2</a></p>
	  <p><a href="../../../page3.asp">Pagina 3</a></p></td>
  </tr>
  <tr>
	<td class="smallbold" colspan="2" align="right">xxxDATESTAMPxxx</td>
  </tr>  
</table>
</body>

</html>

Salgado · Novembro 30, 2008

Pessoal, tenham mais atenção. Esse tópico tem quase um ano de sua última postagem.

Entrar

Arquivado

Sistema com templates

Recommended Posts

Web Design Valdeci 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

Ted k' 126

Compartilhar este post

Link para o post

Compartilhar em outros sites

DSerma 19

Compartilhar este post

Link para o post

Compartilhar em outros sites

Web Design Valdeci 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

Diego Darlan (DDarlan) 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

xanburzum 169

Compartilhar este post

Link para o post

Compartilhar em outros sites

Salgado 4

Compartilhar este post

Link para o post

Compartilhar em outros sites

Fixar div até atingir uma certa altura

Ajuda com Extends e envio para o banco

PHP+Codeginiter - Orientação para Impressão

Este projeto é apoiado pelas empresas

Fóruns

Tempo Real

Informação importante