Log de acessos

[kania 0]

Olá pessoal,

 

Estou fazendo um sistema de Log de Acessos para um site, e estou tendo dificuldades na momntagem da URL' de onde veio e qual pagina acessou, vejam meu código:

 

ID = Session("ID")
NOME = Session("NOME")
DATAHORA = Now()
IP = Request.ServerVariables("REMOTE_HOST")
VEIODE =  Request.ServerVariables("SERVER_NAME")&Request.ServerVariables("URL")
ACESSOU = Request.ServerVariables("PATH_INFO")

DIA = Day(DATAHORA)
MES = Month(DATAHORA)
ANO = Year(DATAHORA)
HORA = TimeValue(DATAHORA)

DATAHORABD = ANO&"-"&MES&"-"&DIA&" "&HORA

response.Write ID&"<br>"
response.Write NOME&"<br>"
response.Write DATAHORABD&"<br>"
response.Write IP&"<br>"
response.Write VEIODE&"<br>"
response.Write ACESSOU

Resultado do Log:

 

1
ERIKA PAULA PIGA
2008-11-23 12:25:16
200.181.168.144
www.autoescolaorleans.com.br/2008/admin/default.asp
/2008/admin/default.asp

O meu problema esta nas URL's de onde veio o acesso e qual pagina acessou, poruqe eu utilizo Strings dentro da URL, o endereço correto por exemplo de onde o cara veio deveria ser

 

http://www.autoescolaorleans.com.br/2008/admin/default.asp?pag=noticias.asp

Porem ele não mostra o que vem depois do ponde de interrogação "?" Algém sabe como posso pegar esta aprte da URL? Pensei em usar a QueryString, mas ai ela vai pegar sempre a apgian que eu esotu e não de onde vim.

[xanburzum 169]

olha esta funcao para pegar a pagina:

<%
function curPageURL()
 dim s, protocol, port

 if Request.ServerVariables("HTTPS") = "on" then 
   s = "s"
 else 
   s = ""
 end if  
 
 protocol = strleft(LCase(Request.ServerVariables("SERVER_PROTOCOL")), "/") & s 

 if Request.ServerVariables("SERVER_PORT") = "80" then
   port = ""
 else
   port = ":" & Request.ServerVariables("SERVER_PORT")
 end if  

 curPageURL = protocol & "://" & Request.ServerVariables("SERVER_NAME") &_ 
			  port & Request.ServerVariables("SCRIPT_NAME")
end function

function strLeft(str1,str2)
 strLeft = Left(str1,InStr(str1,str2)-1)
end function
%>

você pode obter o URL da página atual usando a linha:

 

<%
  response.write(curPageURL())
%>

 

e para pegar as querystring

 

<%
  response.write(curPageURL() & "?" & Request.ServerVariables("QUERY_STRING"))
%>

para obter o nome da página somente. O exemplo a seguir mostra como fazer:

 

<%
function curPageName()
 dim pagename

 pagename = Request.ServerVariables("SCRIPT_NAME") 

  if inStr(pagename, "/") > 0 then 
	pagename = Right(pagename, Len(pagename) - instrRev(pagename, "/")) 
  end if 

 curPageName = pagename
end function 

response.write("o nome da pagina atual é " & curPageName())
%>