Menu em asp

[fernandinhapop 0]

Bom dia pessoal!Estou com um problema enorme, pois não sei fazer e estou precisando muito para colocar na intranet do meu serviço.Já faz algum tempo que estou tentando e não consigo.se alguém puder me ajudar ficarei muito grata.Valeu.fernandinhapop@ibest.com.br

[WLJ 0]

Que tipo de Menu? Com BD?

[edualmeida 0]

você soh eskeceu de falar o problema... :P rss

[fernandinhapop 0]

Bem é um menu com submenu, onde eu possa atualizar diretamente no banco de dados.fernandinhapop@ibest.com.br

[tebba 0]

Bem é um menu com submenu, onde eu possa atualizar diretamente no banco de dados.

 

fernandinhapop@ibest.com.br

Bom, vou te dar um pontapé inicial fmz?

Esse é uma forma que encontrei de solucionar seu problema, com certeza tem milhares, mas vai uma dica!

 

Vamos fazer um menu de Grupos, por exempo: Principal e seus itens, depois tem um Serviços e seus itens, e por ai vai ok? não sei se eh bem esse seu problema mas vamos lá!

 

Crie uma tabela no seu Banco de Dados e vamos dar os seguintes nomes no exemplo:

Tabela:

Menu

 

Campos:

ID (autonumber)

Prioridade(Integer) ' este é para ordenar o menu por prioridade, não por ordem alfabética

Grupo (texto)

Item (Texto)

Pagina (Texto)

Tranquilo....

Aí oq você vai fazer.... o campo que defini como Grupo será o Título da tabela, ou o ítem principal; mas aqui vamos definir como titulo ok?

Entao você adiciona os campos

 

id Grupo  Prioridade Item          Pagina

1 Principal  1            Calendário    calendario.asp

2 Principal  1                Pilotos        pilotos.asp

3 Principal  1                Etapas        etapas.asp

4 Status  2            Classificação    classificacao.asp

5 Status  2            Resultados    resultados.asp

Ateh aqui tranquilo?

 

Depois de inserir os campos vamos ao código.

você deverá fazer um Select dentro do prórpio select.

 

"Select  Grupo FROM Menu Group By Grupo, Prioridade Order By Prioridade"

Este select acima irá agrupar os itens Grupo em ordem de Prioridade crescente, isso pq o sistema normalmente ordena por ordem alfabetica, entao o seu Principal ficaria depois do Eventos, e isso nao eh legal neh?

 

Entao joga esse select em um recordset, assim o recordset ira armazenar apenas os grupos distintos.

 

após isso você deverá fazer um loop para percorrer todo o Recordset e dentro desse loop um outro selext para imprimir cada item de seu respectivo grupo.

 

'Chamei aqui o Recordset de RsMenu

 

While NOT RsMenu.EOF

e dentro desse Recordset coloque o Seguinte Select:

 

"Select  * FROM Menu Where Grupo='" & RsMenu("Grupo") & "' "

Assim, abrindo um novo Recordset com esse Select ele irá armazenar todos os ítens do respectivo grupo.

Faça novamente um while desse recordset para imprimir os dados:

 

While NOT RsMenuItem.EOF

  Response.Write "<a href='" & RsMenuItem("Pagina") & "'> &  RsMenuItem("Item") & "</a>"

Pronto, essa eh mais ou menos a lógica do menu! Abaixo está o código que fiz aqui pra que possa ver melhor! Nele eu criei as tabelas, entao ao imprimir a tabela sai com o titulo em cima dela, e suas linhas com os Item e seu link.

 

Caso tenha alguma dúvida me contate.... sussa!

 

Espero ter ajudado a abrir um pouco mais suas idéias pra sair desse buraco.

 

tebba@uol.com.br

Thiago E. Bernardes

 

OBS. No meu exemplo abaixo, a variavel strConn eh minha String de Conexão!

<%

Dim strMenu, RsMenu

strMenu = "Select  Grupo FROM Menu Group By Grupo, Prioridade Order By Prioridade"

Set RsMenu = Server.CreateObject("ADODB.Recordset")

RsMenu.Open strMenu, strConn

While NOT RsMenu.EOF

%>

        <table width="130" border="0" cellpadding="0" cellspacing="0" class="Principal">

          <tr>

            <td align="center" valign="middle" class="MenuTitulo"><%= RsMenu("Grupo") %></td>

          </tr>

 

<%

            Dim strMenuItem, RsMenuItem

            strMenuItem = "Select  * FROM Menu Where Grupo='" & RsMenu("Grupo") & "' "

            Set RsMenuItem = Server.CreateObject("ADODB.Recordset")

            RsMenuItem.Open strMenuItem, strConn

            While NOT RsMenuItem.EOF

%>   

              <tr>

            <td align="left" valign="middle">  .: <a href="<%= RsMenuItem("Pagina")  %>"><%= RsMenuItem("Item") %></a></td>

          </tr>

<%

RsMenuItem.MoveNext()

Wend

RsMenuItem.Close()

Set RsMenuItem = Nothing

%>         

 

        </table>

<BR>

<%

RsMenu.MoveNext()

Wend

RsMenu.Close()

Set RsMenu = Nothing

%>

[fernandinhapop 0]

Valeu, muito obrigada.Já peguei o seu código e estou pensando em um outra forma de fazer o menu com o submenu.Muito obrigada.fernandinhapop@ibest.com.br