Ir para conteúdo

POWERED BY:

Arquivado

Este tópico foi arquivado e está fechado para novas respostas.

Thiago Paschoalin

[Resolvido] Upload Completo ("Nome,Largura,Altura,Peso,Extensão)

Por , em ASP Clássico

Recommended Posts

Thiago Paschoalin    0

Thiago Paschoalin
Postado

Olá, usei muito tempo um sisteminha de upload sem componentes, pois sempre fazia o que precisava (upload de imagens simples), porém agora preciso de mais que um simples upload, e agora estou cheio de dúvidas.

 

Bom, estou usando o AspSmartUpload, que é qual tenho em meu server, e estou caçando em foruns e na net em geral sobre auxilio de códigos para upload, mas não consigo achar resposta práticas ou afirmativas ou até que deram certo para mim ! Bom, venho aqui 'chorar as pitangas' para vocês.

 

Vou colocar o meu código mais abaixo.

 

 

Seguinte, eu faço o upload e depois recupero o nome da imagem e salvo no MySql, até ai beleza, meu código faz isso, mas agora preciso implemetá-lo:

 

- Salvar no MySql: largura, altura, tamanho(peso), extensão da imagem

 

-* E PRINCIPALMENTE: Renomar a imagem através de um <input type="text" name="NovoNome">

Ou seja, terá 2 campos:

<form method="post" enctype="multipart/form-data" action="?upload=imagem">
<input type="file" name="IMAGEM">
<input type="text" name="NovoNome">
</form>

E quando fosse fazer o upload, ele já renomeasse o arquivo, inclusive antes do upload né, assim o ASP já pegaria o novo nome para salvar no MyuSql, não é ? ou ele pegaria o nome antigo? se for o caso, tudo bem, salvaria o nome da imagem no MySql pelo campo ('NovoNome' & '.jpg')

 

Preciso de um código SIMPLES que façam estas funções, alguém poderia me SALVAR disso? Meu trabalho está MUITO empacado por causas desses problemas, e o natal está ai, preciso terminar isso este ano ainda !!!!!

 

Meu Código, bem simples tb:

 

<!--#include file="../ConnDB.asp"-->
<%
Dim objUpload
Set objUpload = Server.CreateObject("aspSmartUpload.SmartUpload")

'Tamanho Máximo por Upload - 1.000.000 bytes = 1 MB
objUpload.MaxFileSize = 1000000

'Extensões permitidas
objUpload.AllowedFilesList = "gif,jpeg,jpg,png"

objUpload.Upload

'Pasta para ser salva.
objUpload.Save(Server.MapPath("../perfil"))

'Recupera o nome da foto, depois a variável & NomeDaFoto.FileName & para mostrar.
Set NomeDaFoto = objUpload.Files("IMAGEM")

Set objUpload = Nothing
		
Conn.Execute ("UPDATE menuperfil SET img01perfil='" & NomeDaFoto.FileName & "'")
Response.Redirect("../perfil.asp")
%>

Grato desde já.

Compartilhar este post

Link para o post
Compartilhar em outros sites

xanburzum    169

xanburzum
Postado

olha este exemplo que tenho, mas utilizando o Persits Upload, e existe um componente

AutoImageInfo ,um componente (COM e .net) que pega as propriedades sobre arquivos de imagem ASP e ASP.NET. Adquire tal informação como largura de imagem, altura, tamanho de arquivo, ultima modificação, etc.

 

<!--#include file="conexao.asp"--> 
<html> 
<body> 

<% 

'Aqui definimos o caminho físico em que os arquivos iram ser salvos, tanto os thumbs quanto os finais 

Dirfinal = "C:\Inetpub\wwwroot\ASP\imagem\fotos\" 

'Criamos e instânciamos o objeto responsavel pro fazer o Upload da imagem que vamos tratar (ASPUpload) 

Set Upload = Server.CreateObject("Persits.Upload.1") 

'Mandamos com que ele salve dos os arquivos recebidos pelo Formulário no diretório específicado 

Upload.Save(Dirfinal) 

'Queremos poder oferecer algumas informações sobre o arquivo modificado então referenciamos ele através da varialvel Arquivo 

Set Arquivo = Upload.Files("File") 

'Nessas variáveis são armazenados o caminho do arquivo, e através de um Split o nome e sua extensão. 

Caminho = Arquivo.Path 
Nome = Split(Caminho,"\") 
Fim = ubound(Nome) 

Extensao = Split(Nome(Fim),".") 

'Instanciamos novamente outro objeto que agora irá tratar a imagem para nós 

Set Imagem = Server.CreateObject("Persits.Jpeg") 

'Abrimos o arquivo e modificamos ele da forma que queremos 

Imagem.Open Caminho 

Largura = Imagem.Width 
Altura = Imagem.Height 

Imagem.Width = 100 
Imagem.Height = 100 

Imagem.Sharpen 1, 150 

'Instrução que salva o arquivo modificado com o nome de foto_small.jpg para sabermos sempre qual arquivo abrir como thumb 

Imagem.Save Dirfinal & Extensao(0) & "_small." & Extensao(1) 

'Objeto ASP que trabalha com arquivos e irá nos fornecer as informações sobre o arquivo final, modificado. 

Set fso = Server.CreateObject("Scripting.FileSystemObject") 

Set ObjArquivo = fso.GetFile(Dirfinal & Extensao(0) & "_small." & Extensao(1)) 

'Com base nas informações que temos, podemos recuperar as informações do novo arquivo e exibi-las 

ArqINo = Nome(Fim) 
ArqICa = Arquivo.Path 
ArqITa = (Arquivo.Size / 1024) 

ArqFNo = Extensao(0) & "_small." & Extensao(1) 
ArqFCa = Dirfinal & Extensao(0) & "_small." & Extensao(1) 
ArqFTa = (ObjArquivo.Size / 1024) 

Response.Write "Arquivo: " & ArqINo & "<BR>" 
Response.Write "Extensão: " & Extensao(1) & "<BR>" 
Response.Write "Caminho: " & ArqICa & "<BR>" 
Response.Write "Tamanho: " & ArqITa & " Kb - " & Largura & "x" & Altura & "<BR><BR>" 

Response.Write "Arquivo: " & ArqFNo  & "<BR>" 
Response.Write "Extensão: " & Extensao(1) & "<BR>" 
Response.Write "Caminho: " & ArqFCa & "<BR>" 
Response.Write "Tamanho: " & ArqFTa & " Kb - " & 100 & "x" & 100 & "<BR><BR>" 

'Rotina do arquivo de inclusão que abre a conexão com o banco de dados 

AbrirConexao() 

'Instrucao SQL que vai armazenar as informações dos arquivos no banco de dados, para mais tarde exibi-los 

SQL = "INSERT INTO tb_imagens (nome_big, nome_small, caminho_big, caminho_small, altura, largura) VALUES ('" & _ 
ArqINo & "','" & ArqFNo & "','" &Replace(ArqICa, "\", asc("\")) & "','" & Replace(ArqFCa, "\", Asc("\")) & _ 
"'," & Altura & "," & Largura & ")" 

'Executando a query... 

conn.execute SQL 

Response.Write "Imagem Inserida com Sucesso!" 

'Fechamento de todos os nossos objetos para liberar memória 

FecharConexao() 

Set conn = Nothing 
Set Imagem = Nothing 
Set fs = Nothing 
%> 

</body> 
</html>

e para ver a imagem

<!--#include file="conexao.asp"--> 
<html> 
<head> 
<title>Ver Imagens</title> 
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1"> 
<script> 
//funcao java script criada no DreamWeaver que abre um popup recebendo alguns parametros 

var popUpWin=0; 
function popUpWindow(URLStr, left, top, width, height) 
{ 
  if(popUpWin) 
  { 
	if(!popUpWin.closed) popUpWin.close(); 
  } 
  popUpWin = open(URLStr, 'popUpWin', 'toolbar=no,location=no,directories=no,status=no,menub ar=no,scrollbar=no,resizable=no,copyhistory=yes,width='+width+',height='+height+',left='+left+', top='+top+',screenX='+left+',screenY='+top+''); 
} 

</script> 
</head> 
<body> 
<% 

'Instanciando um Recordset que será responsável por armazenar os dados dos arquivos 
Set rs = Server.CreateObject("ADODB.Recordset") 

'Query de Busca 
SQL = "SELECT * FROM tb_imagens" 


'Abrindo conexao com o banco novamente e executando a instruçao SQL 
AbrirConexao() 

rs.Open SQL, conn 

%> 
<table width="100%"  border="0" cellspacing="0" cellpadding="0"> 
<% 

'Após os dados retornados, colocamos dentro de um laço utilizando HTML para exibir apenas 3 thumbnails por linha 
Do Until rs.EOF 
Response.Write "<tr>" & vbNewLine 
   For i = 0 To 2 
	  IF Not rs.EOF Then 
		 %> 
		 <td align="center"> 
			<table border="0" cellspacing="0" cellpadding="0"> 
			  <tr> 
			   <td align="center" valign="middle"><%=rs.Fields("nome_small").Value%></td> 
			  </tr> 
<% 'Passamos no link da imagem a função Javascript com os dados do caminho do arquivo para abrirmos o popup, junto com o tamanho da imagem via query para um arquivo que ira exibir a imagem%> 
			  <tr> 
			   <td align="center" valign="top"><a href="java script: popUpWindow('popup.asp?nome=<%=rs.Fields("nome_big").Value%>', 0, 0, <%=rs.Fields("Largura").Value%>,<%=rs.Fields("Altura").Value%>);"><img src="fotos/<%=rs.Fields("nome_small").Value%>" border="0"></a></td> 
			  </tr> 
			  <tr> 
			   <td align="center" valign="middle"><%=rs.Fields("Largura").Value%>x<%=rs.Fields("Altura").Value%></td> 
			  </tr> 
			</table> 
		 </td> 
		 <% 
		 rs.MoveNext 
	  ELSE 
		 Response.Write("<td></td>" & vbNewLine) 
	  End If 
	   
'Fim dos laços e fechamento dos objetos 
	   
   Next 
Response.Write "</tr>" & vbNewLine 
Loop 

FecharConexao() 

Set conn = Nothing 
Set rs = nothing 
%> 
</table> 

</body> 
</html>

Compartilhar este post

Link para o post
Compartilhar em outros sites

Salgado    4

Salgado
Postado
Olá, usei muito tempo um sisteminha de upload sem componentes, pois sempre fazia o que precisava (upload de imagens simples), porém agora preciso de mais que um simples upload, e agora estou cheio de dúvidas.

 

Bom, estou usando o AspSmartUpload, que é qual tenho em meu server, e estou caçando em foruns e na net em geral sobre auxilio de códigos para upload, mas não consigo achar resposta práticas ou afirmativas ou até que deram certo para mim ! Bom, venho aqui 'chorar as pitangas' para vocês.

 

Vou colocar o meu código mais abaixo.

 

 

Seguinte, eu faço o upload e depois recupero o nome da imagem e salvo no MySql, até ai beleza, meu código faz isso, mas agora preciso implemetá-lo:

 

- Salvar no MySql: largura, altura, tamanho(peso), extensão da imagem

 

-* E PRINCIPALMENTE: Renomar a imagem através de um <input type="text" name="NovoNome">

Verifique em sua hospedagem se eles disponibilizam algum componente para manipulação de imagens, caso positivo facilita um pouco.

 

Renomear, tamanho e Extensão você consegue com o AspSmartUpload;

Altura e Largura tem um script no "Laboratório de Scripts" que faz isso usando FSO.

Compartilhar este post

Link para o post
Compartilhar em outros sites

Thiago Paschoalin    0

Thiago Paschoalin
Postado

'Queremos poder oferecer algumas informações sobre o arquivo modificado então referenciamos ele através da varialvel Arquivo

 

Set Arquivo = Upload.Files("File")

 

'Nessas variáveis são armazenados o caminho do arquivo, e através de um Split o nome e sua extensão.

 

Caminho = Arquivo.Path

Nome = Split(Caminho,"\")

Fim = ubound(Nome)

 

Extensao = Split(Nome(Fim),".")

Isto eu vou tentar fazer agora e vamos no que dá !

 

 

 

'Instanciamos novamente outro objeto que agora irá tratar a imagem para nós

 

Set Imagem = Server.CreateObject("Persits.Jpeg")

 

'Abrimos o arquivo e modificamos ele da forma que queremos

 

Imagem.Open Caminho

 

Largura = Imagem.Width

Altura = Imagem.Height

 

Imagem.Width = 100

Imagem.Height = 100

 

Imagem.Sharpen 1, 150

Isto acima eu já tentei fazer no SmartUpload, mas aponta um erro de VB, falando que o metodo não existe 'Width' ou 'Height' !!! o que pode ser ? alterar os nomes para um permitido no SmartUpload ? e qual seria este código aceito por ele ?

 

 

 

'Instrução que salva o arquivo modificado com o nome de foto_small.jpg para sabermos sempre qual arquivo abrir como thumb

 

Imagem.Save Dirfinal & Extensao(0) & "_small." & Extensao(1)

 

'Objeto ASP que trabalha com arquivos e irá nos fornecer as informações sobre o arquivo final, modificado.

 

Set fso = Server.CreateObject("Scripting.FileSystemObject")

 

Set ObjArquivo = fso.GetFile(Dirfinal & Extensao(0) & "_small." & Extensao(1))

 

'Com base nas informações que temos, podemos recuperar as informações do novo arquivo e exibi-las

 

ArqINo = Nome(Fim)

ArqICa = Arquivo.Path

ArqITa = (Arquivo.Size / 1024)

 

ArqFNo = Extensao(0) & "_small." & Extensao(1)

ArqFCa = Dirfinal & Extensao(0) & "_small." & Extensao(1)

ArqFTa = (ObjArquivo.Size / 1024)

 

Response.Write "Arquivo: " & ArqINo & "<BR>"

Response.Write "Extensão: " & Extensao(1) & "<BR>"

Response.Write "Caminho: " & ArqICa & "<BR>"

Response.Write "Tamanho: " & ArqITa & " Kb - " & Largura & "x" & Altura & "<BR><BR>"

 

Response.Write "Arquivo: " & ArqFNo & "<BR>"

Response.Write "Extensão: " & Extensao(1) & "<BR>"

Response.Write "Caminho: " & ArqFCa & "<BR>"

Response.Write "Tamanho: " & ArqFTa & " Kb - " & 100 & "x" & 100 & "<BR><BR>"

 

'Rotina do arquivo de inclusão que abre a conexão com o banco de dados

 

AbrirConexao()

 

'Instrucao SQL que vai armazenar as informações dos arquivos no banco de dados, para mais tarde exibi-los

 

SQL = "INSERT INTO tb_imagens (nome_big, nome_small, caminho_big, caminho_small, altura, largura) VALUES ('" & _

ArqINo & "','" & ArqFNo & "','" &Replace(ArqICa, "\", asc("\")) & "','" & Replace(ArqFCa, "\", Asc("\")) & _

"'," & Altura & "," & Largura & ")"

 

'Executando a query...

 

conn.execute SQL

 

Response.Write "Imagem Inserida com Sucesso!"

 

'Fechamento de todos os nossos objetos para liberar memória

 

FecharConexao()

 

Set conn = Nothing

Set Imagem = Nothing

Set fs = Nothing

%>

Vou tentar também isso agora ! vamos ver...

 

Mas não existe nada explicado sobre AspSmartUpload ? pq realmente achei milhares de exemplos, inclusive aqui, mas 99% são do persist ! e quando tento colocar aqui, dá um monte de erros... de metodos !

 

 

 

Verifique em sua hospedagem se eles disponibilizam algum componente para manipulação de imagens, caso positivo facilita um pouco.

 

Renomear, tamanho e Extensão você consegue com o AspSmartUpload;

Altura e Largura tem um script no "Laboratório de Scripts" que faz isso usando FSO.

Tá, que componentes seriam estes ?

Eu consigo isto com AspSmartUpload ? Então me diga COMO ! pq se estou aqui perguntando é pq eu não sei !

Bom, já que vocÊ não pode me passar o que eu vou procurar lá, vou ver se acho no laboratório de scripts... jájá eu acho onde fica isso !

 

 

Bom, vou fazer esses 2 testes com os códigos do xanburzum, e depois volto para contar os resultados ! mas quem puder mandar mais opções, fico grato !

Compartilhar este post

Link para o post
Compartilhar em outros sites

Salgado    4

Salgado
Postado
Verifique em sua hospedagem se eles disponibilizam algum componente para manipulação de imagens, caso positivo facilita um pouco.

 

Renomear, tamanho e Extensão você consegue com o AspSmartUpload;

Altura e Largura tem um script no "Laboratório de Scripts" que faz isso usando FSO.

Boas Thiago,

 

Rapaz, que raiva toda é essa? Estou tentando te ajudar e vens com pedradas?

 

Vamos a algumas respostas:

Tá, que componentes seriam estes ?

Como já disse lá em cima: componente para manipulação de imagens, o suporte de sua hospedagem deverá lhe informar o nome do componente, caso eles ofereçam algum, por exemplo: ASPImage, ASPJpeg e outros.

Eu consigo isto com AspSmartUpload ? Então me diga COMO ! pq se estou aqui perguntando é pq eu não sei !

Sim consegue, e fazendo uma pesquisa (que todo programador iniciante deve fazer) no :google: encontrei esse excelente site com a documentação do componente, algo que todo programador deve ter, ou saber localizar, pois guardar todas as propriedades, funções e coleções de todos os objetos é virtualmente impossível.

Bom, já que vocÊ não pode me passar o que eu vou procurar lá, vou ver se acho no laboratório de scripts... jájá eu acho onde fica isso !
O caminho completo para o nosso "Laboratório de Scripts" tá aqui:

 

iMasters Fóruns » Programação » ASP » Laboratório de scripts (ASP)

Mas você pode encontrá-lo, olhando no fórum de ASP, tá lá em cima, é o segundo subfórum.

Pode também usar a BUSCA DO FÓRUM, que poderia lhe levar a esse tópico: Verificar dimensões e resolução de cores com FSO

 

Mas isso é complexo demais, apenas dizer que existe não lhe atende, temos que mastigar tudo.

Bom, vou fazer esses 2 testes com os códigos do xanburzum, e depois volto para contar os resultados ! mas quem puder mandar mais opções, fico grato !

Humildade e respeito, duas qualidades que devemos ter e trabalhar, ainda mais em uma comunidade, ainda mais quando necessitamos de ajuda, ainda mais se queremos ser respeitados.

 

Sempre respeito a todos, sempre que sei e posso ajudar indico as possibilidades de solução, até ajudo a fazer algumas coisas. Não entrego código porque assim não estarei ensinando e simplesmente entregando "comida mastigada".

 

Espero que resolva seu problema.

 

Abraços.

Compartilhar este post

Link para o post
Compartilhar em outros sites

Thiago Paschoalin    0

Thiago Paschoalin
Postado

Desculpa Salgado, mas não lhe faltei com respeito, simplesmemte fui claro com você, alguns possam confundir isso, mas então peço minhas humildes desculpas.

 

Eu sempre tento exclarecer ao maximo a minha dúvida para que eu consiga uma resposta também bem esclarecida, me perdoa mas sua resposta foi muito vaga e acabou me dando mais dúvidas ainda. Estou com muita pressa sobre este problema, e sei que isso não é problema seu e nem de ninguém, mas estava procurando uma resposta que me resolvesse o problema, entende !

 

Então mais uma vez ! Me perdoe se fui grosseiro, só tentei ser claro !

 

Vou tentar fazer aqui, e qualquer dúvida volto ! Abraços.

Compartilhar este post

Link para o post
Compartilhar em outros sites

Thiago Paschoalin    0

Thiago Paschoalin
Postado

*Desculpe o reply, mas achei uma coisa e precisava da ajuda de vcs !

 

Eu procurando sobre como conseguir pegar altura e largura de uma imagem em um upload usando AspSmartUpload e achei um tipo de função, mas originalmente é para alterar a largura e altura de uma imagem já salva... como poderia fazê-lo para recuperar os dados ???

 

Olhem o código:

 

dim iWidth, iheight
sub ImgDimension(img)
dim myImg, fs
Set fs= CreateObject("Scripting.FileSystemObject")
if not fs.fileExists(img) then exit sub
set myImg = loadpicture(img)
iWidth = round(myImg.width / 26.4583)
iheight = round(myImg.height / 26.4583)
set myImg = nothing
end sub

ImgDimension(Server.MapPath("server image file"))

Com isso eu poderia pegar a altura e largura de uma imagem ? mesmo que depois do upload, só para eu poder salvar esses valores no MySql ?

Grato desde já.

Compartilhar este post

Link para o post
Compartilhar em outros sites

xanburzum    169

xanburzum
Postado

tem o AutoImageInfo um componente que pega as propriedades sobre arquivos de imagem . como largura de imagem, altura, tamanho de arquivo, ultima modificação, etc. mas você quer Redimensionar Durante O Upload ?

Compartilhar este post

Link para o post
Compartilhar em outros sites

Salgado    4

Salgado
Postado

Thiago, aparentemente há uma classe criada por usuário (loadpicture), caso esteja com o código completo seria só as propriedades dessa classe. Retire o trecho da divisão e a função ROUND e verifique se as variaveis iWidth e iHeight correspondem com as dimensões originais da imagem.

 

Caso tenha duvidas de como fazer isso poste novamente.

 

Outro detalhe, entre em contato com o suporte de sua hospedagem e verifique se eles usam algum componente de manipulação de imagens, isso pode vir a facilitar caso precise de algo mais futuramente.

Compartilhar este post

Link para o post
Compartilhar em outros sites

Thiago Paschoalin    0

Thiago Paschoalin
Postado

xanburzum:

Eu quero que após o upload, ele recupere todos os dados da imagem, para depois eu poder gravar no DB !

 

como no que estou usando:

Dim SmartUpload
Dim file

Set SmartUpload = Server.CreateObject("aspSmartUpload.SmartUpload")
SmartUpload.MaxFileSize = 2000000
SmartUpload.AllowedFilesList = "gif,jpeg,jpg,png"
SmartUpload.Upload

For each file In SmartUpload.Files

If not file.IsMissing Then
Imagem = file.FileName

file.SaveAs(Server.MapPath("../SmartUpload/" & Imagem))

tamanho = file.Size
extensao = file.FileExt
End If
Next

Conn.Execute "INSERT INTO imagens(datadia, nome, tamanho, extensao) VALUES "&_
"('" & now() & "', '" & Imagem & "', '" & tamanho & "', '" & extensao & "')"
Response.Redirect("../imagens.asp?imagem=adicionada")

Salgado:

este código eu peguei ele assim, não tinha mais nada na explicação, então provavelmente eu peguei o forum pela metade e não vi o código inteiro.

 

Eu tentei fazer o que falou, mas tb não deu certo não, tirei o ROUND, mas deu pau tb.

 

Eu vi lá os componentes que eles tem... são eles: ServerObjects - Image Size (free), Persits - AspJpeg e Persits - AspPDF

 

com algum deles eu consigo recuperar a largura e altura no meu upload ?

 

Grato desde já.

Compartilhar este post

Link para o post
Compartilhar em outros sites

xanburzum    169

xanburzum
Postado

olha aquele código que postei acima,com Persits.Upload,Persits.Jpeg

Compartilhar este post

Link para o post
Compartilhar em outros sites

Salgado    4

Salgado
Postado
Salgado:

este código eu peguei ele assim, não tinha mais nada na explicação, então provavelmente eu peguei o forum pela metade e não vi o código inteiro.

 

Eu tentei fazer o que falou, mas tb não deu certo não, tirei o ROUND, mas deu pau tb.

 

Eu vi lá os componentes que eles tem... são eles: ServerObjects - Image Size (free), Persits - AspJpeg e Persits - AspPDF

 

com algum deles eu consigo recuperar a largura e altura no meu upload ?

 

Grato desde já.

Exemplo básico retirado daqui mesmo: iMasters Fóruns

Compartilhar este post

Link para o post
Compartilhar em outros sites

Thiago Paschoalin    0

Thiago Paschoalin
Postado

show de bola salgado !!!! funcionou !!!!

Muito obrigado !!!

 

Agora, aguarda um pouco que me apareceu mais um problema, vou ver se consigo resolver, senão corro para cá novamente ^^

Compartilhar este post

Link para o post
Compartilhar em outros sites

xanburzum    169

xanburzum
Postado

dá uma analisada no código que postei acima, e você pode implementar do seu jeito...

 

Set Imagem = Server.CreateObject("Persits.Jpeg") 

'Abrimos o arquivo e modificamos ele da forma que queremos 

Imagem.Open Caminho 

Largura = Imagem.Width 
Altura = Imagem.Height

Compartilhar este post

Link para o post
Compartilhar em outros sites

Thiago Paschoalin    0

Thiago Paschoalin
Postado

era exatamente sobre isso mesmo que me deixou em dúvidas....

 

eu queria ver o que o Persists.Jpeg recuperava da imagem, e dependendo usaria somente ele para ruperar todos os dados da mesma !

 

Inclusive o que achei SHOW de bola foi isso:

Caminho = Arquivo.Path 
Nome = Split(Caminho,"\") 
Fim = ubound(Nome) 
Extensao = Split(Nome(Fim),".") 
.........
Imagem.Save Dirfinal & Extensao(0) & "_small." & Extensao(1)
Para separar o nome da imagem da extensão !

 

Eu gostei disso pelo seguinte motivo, e já se cria OUTRA dúvida, hehehe:

Imagem.Save Dirfinal & Extensao(0) & "_small." & Extensao(1)
Nesta parte eu poderia colocar o nome que eu quisesse não poderia ??

 

Exemplo:

Formulário:
<form>
<input type="text" name="NomeDaFoto">
</form>

e depois que fizer o upload e eu chamo o Persists.Jpeg e reconfiguro a imagem e salvo ela assim:

NomeDaFoto = Imagem.Form("NomeDaFoto")

Imagem.Save Dirfinal & NomeDaFoto & "." & Extensao(1)

Daria certo né ????

 

Acho que a minha idéia está mais para uma gambiarra, mas isso estiver correto, eu poderia fazer o upload, salvo a imagem na pasta, recupero ela, renomeio e depois eu salvo no MySql !

 

não é isso mesmo ? ou estou fazendo errado ?

Compartilhar este post

Link para o post
Compartilhar em outros sites

xanburzum    169

xanburzum
Postado

deu certo...

se o que fez deu certo, independente de gambiarra, dando certo, beleza

o que você precisa verificar é otimizar o código, pois alguns códigos-gamb, pode

dar problema de desempenho.

Compartilhar este post

Link para o post
Compartilhar em outros sites

Thiago Paschoalin    0

Thiago Paschoalin
Postado

é verdade, mas primeiro vou aprender a lidar com os códigos, depois vou otimizando ele !

 

Inclusive até acho que jájá, estou mudando para Persits.Upload !!! ^^

 

 

 

Mas é isso, Muito Obrigado ao salgado e a você xanburzum !!!!

Compartilhar este post

Link para o post
Compartilhar em outros sites
Ir para a lista de tópicos ASP Clássico
×

Informação importante

Ao usar o fórum, você concorda com nossos Termos e condições.

  Aceito