Ir para conteúdo

POWERED BY:

Arquivado

Este tópico foi arquivado e está fechado para novas respostas.

xanburzum

[Resolvido] Excluir Um Registro Com Comando Sql

Por , em ASP Clássico

Recommended Posts

xanburzum    169

xanburzum
Postado

Banco de dados - excluir um registro com comando SQL

 

Instruções SQL pode ser usado para apagar dados também.

 

dbaddmany.asp

 

 

<TITLE>dbaddmany.asp</TITLE>
<body bgcolor="#FFFFFF">
<HTML>
<!--#include file="lib_errors.asp"-->
<%
on error resume next
myDSN = "DSN=Student;uid=student;pwd=magic"
mySQL = "INSERT INTO authors (AU_ID,author,year_born) "
mySQL = mySQL & "VALUES (200,'Charles M. Carroll',1964)"

Set Conn = Server.CreateObject("ADODB.Connection")
conn.open myDSN

for counter=1 to 200
   thistask="Task #" & counter & "<br>"
   response.write thistask
   Conn.Execute(mySQL)
   Call ErrorVBScriptReport(thistask)
   Call ErrorADOReport(mySQL,conn)
next
Conn.Close
set conn=nothing
%>
</BODY>
</HTML>

 

Agora aqui está um script que irá apagar todos os registros do script acima acrescentou:

 

dbdeletemany.asp

 

<TITLE>dbdeletemany.asp</TITLE>
<body bgcolor="#FFFFFF">
<HTML>
<!--#include file="lib_errors.asp"-->
<%
on error resume next
myDSN = "DSN=Student;uid=student;pwd=magic"
mySQL = "DELETE FROM authors WHERE au_id=200"

Set Conn = Server.CreateObject("ADODB.Connection")
conn.open myDSN

Conn.Execute mySQL,howmany
response.write "A declaração" & mySQL & "<b> deletada " & howmany & " records</b><br>"
Call ErrorVBScriptReport("Deletiando...")
Call ErrorADOReport(mySQL,conn)

Conn.Close
set conn=nothing
%>
</BODY>
</HTML>
biblioteca de erros:

 

lib_errors.asp

 

 

<%
SUB ErrorVBScriptReport(parm_msg)
   If  err.number=0 then
	   exit sub
   end if
   pad="    "
   response.write "<b>VBScript Errors Occured!<br>"
   response.write parm_msg & "</b><br>"
   response.write pad & "Número de erro= #<b>" & err.number & "</b><br>"
   response.write pad & "Erro Desc.= <b>" & err.description & "</b><br>"
   response.write pad & "Ajuda Contexto= <b>" & err.HelpContext & "</b><br>"
   response.write pad & "Ajuda File Path=<b>" & err.helpfile & "</b><br>"
   response.write pad & "Erro Fonte= <b>" & err.source & "</b><br><hr>"
END SUB

 

SUB ErrorADOReport(parm_msg,parm_conn)
   HowManyErrs=parm_conn.errors.count
   IF  HowManyErrs=0 then
	   exit sub
   END IF
   pad="    "
   response.write "<b>ADO Relatórios estes Database Error (s) executando:<br>"
	   response.write SQLstmt & "</b><br>"
   for counter= 0 to HowManyErrs-1
	   errornum=parm_conn.errors(counter).number
	   errordesc=parm_conn.errors(counter).description
	   response.write pad & "Erro#=<b>" & errornum & "</b><br>"
	   response.write pad & "descrição do erro=<b>"
	   response.write errordesc & "</b><p>"
   next
END SUB
%>

Compartilhar este post

Link para o post
Compartilhar em outros sites
Ir para a lista de tópicos ASP Clássico
×

Informação importante

Ao usar o fórum, você concorda com nossos Termos e condições.

  Aceito