[Resolvido] Generador De Meta Tag

[xanburzum 169]

Fornece uma interface para criar um número ilimitado de meta tags

Que pode ser copiado e colado em um documento html.An object that creates meta tags.

 

 

 

'*********************** INICIO CLASS************************
Class MetaGenerator
'************************* INICIO 
' 
'
 'PROPRIEDADES: 
 'MetaFormInputs [int =] 
 'Opcional. Leitura / gravação. Inteiro. O número de formulário 
 'Inputs para exibir. Padrão se não for fixado 5. 
 ' 
 'Versão 
 'Opcional. Somente leitura. Seqüência. Retorna a versão como 
 '" maior.menor ".
'
'
'  METODO: 
 'Execute () 
 'Obrigatório. Retorna Nulo. A classe irá determinar a sua 
 'Própria ação: display formulário ou criar metatags.
'

'	  - classe VBScript 
'- Permite meta tags personalizados 
 '- Pode criar um número ilimitado de tags em uma hora (configurável) 
 '- Permite HTTP-EQUIV NOME ou metatags para ser criada

'
'
'************************** FIM


Public MetaFormInputs

Public Property Get Version
 Version = "2.0"
End Property

Public Sub Execute
 If Request.QueryString.Count > 0 Then 
  ResolveAndDisplayTags 
 Else 
  Show_Form
 End If
End Sub

Private Sub Class_Initialize
 MetaFormInputs = 5
End Sub

Private Sub ResolveAndDisplayTags
 Dim i, s
 For i = 1 to Request.QueryString("metatype").Count
  If Len(Request.QueryString("metatype")(i)) > 0 And _
	 Len(Request.QueryString("metaname")(i)) > 0 And _
	 Len(Request.QueryString("metacontent")(i)) > 0 Then
   s = s & Server.HTMLEncode("<META " & _
	UCase(Request.QueryString("metatype")(i)) & _
	"=""" & Request.QueryString("metaname")(i) & _
	""" CONTENT=""" & _
	Request.QueryString("metacontent")(i) & _
	""" />") & vbCrLf & vbCrLf
  End If
 Next

 If InStr(s, "META") Then 
  Response.Write("<FORM><TEXTAREA COLS=70 ")
  Response.Write("ROWS=10 STYLE=""font-size:9pt;"">")
  Response.Write(s)
  Response.Write(Server.HTMLEncode("<META NAME=""generator"" "))
  Response.Write(Server.HTMLEncode("CONTENT=""MetaGenerator "))
  Response.Write(Server.HTMLEncode("Object v" & Version & """ />"))
  Response.Write("</TEXTAREA></FORM>")
  Response.Write("<A HREF=""" & _
   request.servervariables("PATH_INFO") & _
	""">fazê-lo novamente</A>") 
 Else 
  Show_Form
 End if
End Sub

Private Sub Show_Form
 dim i
%>
 <FORM METHOD="GET" NAME=frm1 
	   ACTION="<% = request.servervariables("PATH_INFO") %>">
 <TABLE ALIGN=CENTER CELLPADDING=1 CELLSPACING=1 BORDER=0 
		BGCOLOR="#60786B" STYLE="font-size:10pt;font-family:tahoma;">
  <TR>
   <TH COLSPAN=2 BGCOLOR="#EEEEEE">meta tipo</TH>
   <TH BGCOLOR="#EEEEEE">nome</TH>
   <TH BGCOLOR="#EEEEEE">conteudo</TH>
  </TR>
 <%
 For i = 1 to MetaFormInputs
 %>
  <TR>
   <TD BGCOLOR="#EEEEEE"> <% = i %>.) </TD>
   <TD BGCOLOR="#FFFFEE">
   <SELECT NAME="metatype">
	<OPTION VALUE="">--selecionado--</OPTION>
	<OPTION VALUE="name">NOME</OPTION>
	<OPTION VALUE="http-equiv">HTTP-EQUIV</OPTION>
   </SELECT>
   </TD>
   <TD BGCOLOR="#FFFFEE">
   <INPUT TYPE=TEXT NAME="metaname" 
		  VALUE="" SIZE=25>
   </TD>
   <TD BGCOLOR="#FFFFEE">
   <TEXTAREA NAME="metacontent" COLS=35 
			 WRAP=VIRTUAL ROWS=2></TEXTAREA>
   </TD>
  </TR>
 <%
 Next
 %>
 </TABLE><BR><CENTER>
 <INPUT TYPE=SUBMIT VALUE="Criar Tags ">
 <INPUT TYPE=BUTTON VALUE="Gerar algumas tags" 
		ONCLICK="java script:generateTags();">
 </CENTER></FORM>


<script LANGUAGE=javascript>
function generateTags() {
 var t = "";
 var s = navigator.appName;
 if (s.toLowerCase() != "microsoft internet explorer") {
  t += "A tag generation funciona somente para o IE! "; 
T + = "Digite algumas tags e clique em"; 
t + = "a \" Criar a tag acima \ "botão."; 
t + = "Devido a limitações de tempo"; 
t = + "para criar o código específico do netscape aqui - Eu calculei"; 
t + = "95% do meu tráfego usa IE 5 ou 6.";   alert(t);
  return;
 }

 var frmname = document.frm1.metaname;
 var frmcont = document.frm1.metacontent;
 var frmtype = document.frm1.metatype;

 frmtype.metatype[0].selectedIndex = 1;
 frmname.metaname[0].value = "keywords";
 frmcont.metacontent[0].value = 
	 "asp code, AJAX, vbscript, jscript, COM";

 frmtype.metatype[1].selectedIndex = 1;
 frmname.metaname[1].value = "description";
 frmcont.metacontent[1].value = 
 "VBScript e JScript código fonte";

 frmtype.metatype[2].selectedIndex = 2;
 frmname.metaname[2].value = "refresh";
 frmcont.metacontent[2].value = 
	 "0; URL=/aspImasters/index.asp";

 document.frm1.submit();
}
</SCRIPT>


<%
End Sub
End Class
'************************ FIM CLASS