Ir para conteúdo

POWERED BY:

Arquivado

Este tópico foi arquivado e está fechado para novas respostas.

sylar_head

Sistema de login simples num ta funfando

Por , em ASP Clássico

Recommended Posts

sylar_head    0

sylar_head
Postado

Oi pessoal, fiz um sisteminha bem simples de login, mas não está funcionando, a pessoa faz o login e ele sempre volta pra pagina de login.

 

Segue o código abaixo:

 

config.asp

<% 
'altere aqui os seu login e senha
user = "usuario" 'user administrativo
senha = "senha" 'senha administrativa
%>

validalogin.asp

<!--#include file="config.asp"-->
<% nome = Request.form("nome")
   senha = Request.form("senha")
If nome = user AND senha = senha Then
	Session("login") = TRUE
	Response.Redirect("index.asp")
Else
	Response.Redirect("login.asp")
end If %>

restrito.asp

<% response.expires = "0" 
if session("logado") <> "logou" then 
response.write "<script language='javascript'>alert('Você não tem permissão para utilizar esta página')</script>"
response.Redirect "login.asp"
end if %>

 

Ajuda aí pessoal, já fiz o mesmo sistema de login e funcionou, só que agora não está mais funcionando. :unsure:

Compartilhar este post

Link para o post
Compartilhar em outros sites

xanburzum    169

xanburzum
Postado

tenta assim:

 

 

<% 
user = "usuario" 'user administrativo
senha = "senha" 'senha administrativa
nome = Request.form("nome")
   senha = Request.form("senha")
If nome = user AND senha = senha Then
	Session("login") = TRUE
	Response.Redirect("index.asp")
Else
	Response.Redirect("login.asp")
end If %>

por ser um simples código, você pode colocar o user e senha no mesmo arquivo.

 

e dá uma olhada aqui, pode te ajudar aqui

Compartilhar este post

Link para o post
Compartilhar em outros sites

sylar_head    0

sylar_head
Postado

Quanto ao fato de colocar em outro arquivo, foi pra eu dizer ao administrador do site que ele podia mudar em config.asp o usuario e senha

 

E eu coloquei em um só arquivo e ficou a mesma coisa.

 

 

E quanto ao link que você me mandou, é com o sql server, e eu não trabalho com ele e nem a hospedagem.

 

 

E agora?

 

Obrigado pela ajuda.

Compartilhar este post

Link para o post
Compartilhar em outros sites

xanburzum    169

xanburzum
Postado

só mudar o banco, conexao...

mas se quiser me mando uma mensagem em pvt pelo fórum

que te envio um sisteminha de login...

 

mas olha este exemplo, é simples , mas melhor do que usar com uma senha estabelecida

 

create.asp

<%
	'recupera nome de usuário e senha
	Username = Request.Form("txtUsername")
	Password = Request.Form("txtPassword")
	Fullname = Request.Form("txtFullname")
		
	'Verifique se nome de usuário ea senha são inscritas
	if Username = "" then Response.redirect("login.asp?login=createnamefailed")
	if Password = "" then Response.Redirect("login.asp?login=createpassfailed")
	
	'Construa conexão
	set conn = server.CreateObject ("ADODB.Connection")
	conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & server.MapPath ("users.mdb")
	set rs = server.CreateObject ("ADODB.Recordset")
	'Open records
	rs.Open "SELECT * FROM userlist", conn, 1, 3 
	
	'Verifique se nome_de_usuário ainda não existe
	do while not rs.EOF
		if rs("username")=Username then
			set rs=nothing
			set conn=nothing
			Response.Redirect("login.asp?login=createnamefailed")
		end if
		rs.MoveNext
	loop
		
	'Add record
	rs.AddNew 
	'colocar nome de usuário e senha
	rs("username")=Username
	rs("password")=Password
	rs("fullname")=Fullname
	'Salva record
	rs.Update 
	
	set rs=nothing
	set conn=nothing

	Response.Redirect("login.asp?login=creatednew")
%>

default.asp

<%
'Verifique se o usuário é registrado
if Session("name") = "" then
	'Se não, vá para a página de login
	Response.Redirect("login.asp")
else
	'Se, exibe a pagina , ou você pode redirecioná-lo para outra
	Response.Write("<title>ASP Page</title>")
	Response.write("<center>Bem-vindo " & Session("name") & "<br><a href=logout.asp>Logout</a></center>")
end if
%>

login.asp

<%
	'Green colorset
	'BackgroundColor="#C9DDB3"
	'BorderColor="#006600"
	
	'Blue colorset
	BackgroundColor="#AFD1F8"
	BorderColor="#000080"
	
	'Purple colorset
	'BackgroundColor="#FDC8F2"
	'BorderColor="#800080"
	
	Content = ""							'Clear the Content string
	QStr = Request.QueryString("login")		'Save the login querystring to QStr

	if ucase(left(QStr,6))="CREATE" then 
		Title = "Register"
	else
		Title = "Login"
	end if
	
	'The code below saves the contents the table must have in the variable Content
	'The content depends on what's in the QueryString
		
	if QStr="passfailed" then				
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center><P>Wrong password</P><A href=java script:history.go(-1)>Back</A></td></tr>"
	elseif QStr="createpassfailed" then		
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center><P>Wrong password</P><A href=java script:history.go(-1)>Back</A><BR><BR><A HREF=login.asp>Cancel registration</A></td></tr>"
	elseif QStr="namefailed" then
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center><P>username Invalido</P><A HREF=login.asp?login=createnew>Clique aqui para criar uma acount</A><BR><BR><A HREF=java script:history.go(-1)>Voltar</A></td></tr>"
	elseif QStr="createnamefailed" then
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center><P>username Invalido</P><A HREF=java script:history.go(-1)>Back</A><BR><BR><A HREF=login.asp>Cancelar inscrição</A></td></tr>"
	elseif QStr="creatednew" then
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center><P>Sua conta foi criada</P><A HREF=login.asp>Login</A></td></tr>"
	elseif QStr="createnew" then
		Content = Content & "<form name=frmCreate method=POST action=create.asp>"
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center><br>Username: <input type=text name=txtUsername></td></tr>"
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center>Password: <input type=password name=txtPassword></td></tr>"
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center><br>Full name: <input type=text name=txtFullname></td></tr>"
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center><input type=submit name=cmdSubmit value=Register></td></tr>"
		Content = Content & "</form>"
	else
		Content = Content & "<form name=frmMain method=POST action=verify.asp>"
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center><br>Username: <input type=text name=txtUsername></td></tr>"
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center>Password: <input type=password name=txtPassword></td></tr>"
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center><input type=submit name=cmdSubmit value=Login></td></tr>"
		Content = Content & "</form>"
		Content = Content & "<tr><td valign=top bordercolor="& BackgroundColor &" align=center><A HREF=login.asp?login=createnew>Click here to create an acount</A></td></tr>"
	end if

%>

<! - Crie a página com a tabela ->
 
<head>  
<title>ASP Login</title>
</head>

<body link="<% Response.Write(BorderColor) %>" vlink="<% Response.Write(BorderColor) %>" alink="<% Response.Write(BorderColor) %>" text="<% Response.Write(BorderColor) %>">
<br>
<div align="center">
	
<table border="2" cellspacing="5" bgcolor="<% Response.Write(BackgroundColor) %>" bordercolor="<% Response.Write(BorderColor) %>"width="250px">
		
		
	<%
	Response.Write("<tr><td valign=top align=center><b>" & Title & "</b></td></tr>")
	Response.Write(Content)	 ' Colar o conteúdo da tabela	%>
				
</table>
	
</div>
		
</body>

logout.asp

<%

Session("name")=""
Response.Redirect("login.asp")

%>

verify.asp

<%
	
	Username = Request.Form("txtUsername")	
	Password = Request.Form("txtPassword")
	
	
	set conn = server.CreateObject ("ADODB.Connection")		
	conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & server.MapPath ("users.mdb")
	set rs = server.CreateObject ("ADODB.Recordset")		
'Abrir com registro entrou usuário
	rs.Open "SELECT * FROM userlist where username='"& Username &"'", conn, 1 
	
	'Se não houver nenhum registro com o usuário , fecha conexão
'E voltar ao início de uma sessão com QueryString	
If rs.recordcount = 0 then
		rs.close
		conn.close
		set rs=nothing
		set conn=nothing
		Response.Redirect("login.asp?login=namefailed")
	end if
	
	
		if rs("password") = Password then
		Session("name") = rs("fullname")
		rs.Close
		conn.Close
		set rs=nothing
		set conn=nothing
		Response.Redirect("default.asp")
		else
		rs.Close
		conn.Close
		set rs=nothing
		set conn=nothing
		Response.Redirect("login.asp?login=passfailed")
	end if	

%>

Compartilhar este post

Link para o post
Compartilhar em outros sites

Mário Monteiro    179

Mário Monteiro
Postado

voce tem que usar a mesma session de controle

 

no login define

 

Session("login") = TRUE

 

e depois tenta usar

 

if session("logado") <> "logou" then

 

nao tem como funcionar

Compartilhar este post

Link para o post
Compartilhar em outros sites
Ir para a lista de tópicos ASP Clássico
×

Informação importante

Ao usar o fórum, você concorda com nossos Termos e condições.

  Aceito