Erro VBScript

analeao2 · Janeiro 28, 2009

Amigos,

Na área administrativa de meu site (que não foi feito por mim, peguei pronto), ao excluir um cadastro o seguinte erro aparece:

Microsoft VBScript runtime error '800a01b6'

Object doesn't support this property or method: 'em.body'

/adm/AlteraStatusEntidade.asp, line 88

Alguém pode me ajudar?

Abraços,

:D

xanburzum · Janeiro 28, 2009

Objeto não oferece suporte a esta propriedade ou método

o que é o 'em.body', posta a linha de erro com o trecho de código

analeao2 · Janeiro 29, 2009

Objeto não oferece suporte a esta propriedade ou método

o que é o 'em.body', posta a linha de erro com o trecho de código

Obrigada pela atenção, Xanburzum! Segue o código completo:

Início

<!--#include file="verifysession.asp"-->
<!--#include file="../include/funcoes_auxiliares.asp"-->
<%
const adVarChar=200
const adParamInput=1
const adDBDate = 133
const adDBTimeStamp= 135
const adChar=129
const adInteger=3
const adInt=3
idEntidade = request("idEntidade")
idStatus = request("Status")
if isNumeric(idStatus) and isNumeric(idEntidade) then
	call abreCon
	if idstatus=1 then
		'''''Confirmacao
		set lCmd = server.createObject("ADODB.Command")
		with lCmd
			.CommandType = 4 'stored procedure
			.CommandText = "pr_upd_AlteraStatusEntidade"
			.ActiveConnection = Con
			.Parameters.Append lCmd.CreateParameter("@idEntidade" ,adInteger , 1, , Cint(idEntidade) )
			.Parameters.Append lCmd.CreateParameter("@idStatus" ,adInteger , 1, , Cint(idStatus) )
		end with
		lCmd.Execute ,  , adCmdStoredProc
		if err.number=0 then
			msg="Entidade Confirmada"
			'call enviaEmailConfirmacao request("email")
		end if
	elseif idstatus=3 then
		''''''exclusao
		set rs=con.execute("select contato, nome from entidade where identidade = " & idEntidade)
		set lCmd = server.createObject("ADODB.Command")
		with lCmd
			.CommandType = 4 'stored procedure
			.CommandText = "pr_del_Entidade"
			.ActiveConnection = Con
			.Parameters.Append lCmd.CreateParameter("@idEntidade" ,adInteger , 1, , Cint(idEntidade) )
		end with
		lCmd.Execute ,  , adCmdStoredProc
		if err.number=0 then
			call enviaEmailExclusao(request("email"), request("mensagem"), rs("contato") , rs("nome"))
		end if
	elseif idstatus=2 then
		set lCmd = server.createObject("ADODB.Command")
		with lCmd
			.CommandType = 4 'stored procedure
			.CommandText = "pr_upd_AlteraStatusEntidade"
			.ActiveConnection = Con
			.Parameters.Append lCmd.CreateParameter("@idEntidade" ,adInteger , 1, , Cint(idEntidade) )
			.Parameters.Append lCmd.CreateParameter("@idStatus" ,adInteger , 1, , Cint(idStatus) )
		end with
		lCmd.Execute ,  , adCmdStoredProc
		con.execute("update entidade set suspenso='"& request("mensagem")&"' where identidade = "& idEntidade)
		if err.number=0 then
			msg="Entidade Suspensa"
			'call enviaEmailConfirmacao request("email")
		end if
	end if
	if err.number<>0 then
		msg="ERRO"& err.number & err.description
	end if
end if
%>
<HTML>
<HEAD>
<TITLE>Administração AjudaBrasil - Altera Status de Entidade</TITLE>
<META NAME="GENERATOR" Content="Microsoft Visual Studio 6.0">
</HEAD>
<BODY>
<P> </P>
<font face=Arial size=2 color=red><%=Msg%></font>
<p><a href=# onClick="java script:window.close();">Fechar esta janela</a></p>
</BODY>
</HTML>
<%
function enviaEmailExclusao( email, mensagem, nomecontato , nome)
	set fso=server.CreateObject("scripting.filesystemobject")
	set fil=fso.OpenTextFile(server.MapPath("../email/exclusaoEntidade.txt"))
	body = fil.readAll()
	body=replace(body,"<<nomecontato>>", nomecontato)
	body=replace(body,"<<nomeentidade>>", nome)
	body=replace(body,"<<motivo>>", mensagem)
	set em = server.CreateObject("CDO.Message")
	em.To = emal
	em.From = "Equipe AjudaBrasil <faleconosco@ajudabrasil.org>"
	em.subject = "Exclusão de cadastro no AjudaBrasil"
	em.Body = body
	em.send
	set em=nothing
end function

%>

Fim

Abraços,

http://forum.imasters.com.br/public/style_emoticons/default/thumbsup.gif

DSerma · Janeiro 29, 2009

Ou é

em.TextBody

Ou então

em.HTMLBody

Só em.Body não existe =)

analeao2 · Janeiro 29, 2009

Ou é
em.TextBody
Ou então
em.HTMLBody
Só em.Body não existe =)

Então devo substituir o em.Body para em.TextBody e em.HTMLBody e vem o que funciona, certo? :huh:

Obrigada e abraços,

http://forum.imasters.com.br/public/style_emoticons/default/thumbsup.gif

xanburzum · Janeiro 30, 2009

coloca o

em.HTMLBody = body

ou

em.TextBody="sua mensagem"

body = fil.readAll()
	body=replace(body,"<<nomecontato>>", nomecontato)
	body=replace(body,"<<nomeentidade>>", nome)
	body=replace(body,"<<motivo>>", mensagem)
	set em = server.CreateObject("CDO.Message")
	em.To = emal
	em.From = "Equipe AjudaBrasil <faleconosco@ajudabrasil.org>"
	em.subject = "Exclusão de cadastro no AjudaBrasil"
	em.HTMLBody = body
	em.send

dá uma olhada nos exemplos abaixo:

Enviar um texto de e-mail:

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="seuemail@dominio.com"
myMail.To="destinatario@dominio.com"
myMail.TextBody="sua mensagem."
myMail.Send
set myMail=nothing
%>

Enviar um texto de e-mail com Bcc e CC :

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="seuemail@dominio.com"
myMail.To="destinatario@dominio.com"
myMail.Bcc="outro@dominio.com"
myMail.Cc="someoneelse2@somedomain.com"
myMail.TextBody="sua mensagem."
myMail.Send
set myMail=nothing
%>

Enviar ume-mail em HTML:

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="seuemail@dominio.com"
myMail.To="destinatario@dominio.com"
myMail.HTMLBody = "<h1>sua mensagem.</h1>" 
myMail.Send
set myMail=nothing
%>

Enviar um e-mail HTML que envia uma página de um site:

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="seuemail@dominio.com"
myMail.To="destinatario@dominio.com"
myMail.CreateMHTMLBody "http://www.imasters.com.br" 
myMail.Send
set myMail=nothing
%>

Enviar um e-mail HTML que envia uma página Web a partir de um arquivo no seu computador:

<%

Set myMail=CreateObject("CDO.Message")

myMail.Subject="Sending email with CDO"

myMail.From="seuemail@dominio.com"

myMail.To="destinatario@dominio.com"

myMail.CreateMHTMLBody "file://c:/documentos\teste.htm"

myMail.Send

set myMail=nothing

%>

Enviar um texto de e-mail com um anexo:

<%

Set myMail=CreateObject("CDO.Message")

myMail.Subject="Sending email with CDO"

myMail.From="seuemail@dominio.com"

myMail.To="destinatario@dominio.com"

myMail.TextBody="sua mensagem."

myMail.AddAttachment "c:\documentos\teste.txt"

myMail.Send

set myMail=nothing

%>

Enviar um texto de e-mail usando um servidor remoto:

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="seuemail@dominio.com"
myMail.To="destinatario@dominio.com"
myMail.TextBody="sua mensagem."
myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing")=2
'Name or IP of remote SMTP server
myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") _
="smtp.server.com"
'Server port
myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") _
=25 
myMail.Configuration.Fields.Update
myMail.Send
set myMail=nothing
%>

analeao2 · Janeiro 30, 2009

Muito obrigada pela ajuda de vocês! Vou testar e depois posto o resultado!

Abraços,

http://forum.imasters.com.br/public/style_emoticons/default/joia.gif

analeao2 · Fevereiro 15, 2009

Amigos, ainda não consegui testar o que me passaram. Estou num corre corre danado aqui e ainda estou quebrando acabeça com meu pc. http://forum.imasters.com.br/public/style_emoticons/default/ermm.gif Vou postar esta situação no lugar certo aqui dentro, mas asim que acalmar respondo aqui, ok?

Abraços,

http://forum.imasters.com.br/public/style_emoticons/default/thumbsup.gif

xanburzum · Fevereiro 15, 2009

coloca o

em.HTMLBody = body

ou

em.TextBody="sua mensagem"

e dá uma analisada nos exemplos que coloquei

Arquivado

Erro VBScript

Recommended Posts

analeao2 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

xanburzum 169

Compartilhar este post

Link para o post

Compartilhar em outros sites

analeao2 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

DSerma 19

Compartilhar este post

Link para o post

Compartilhar em outros sites

analeao2 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

xanburzum 169

Compartilhar este post

Link para o post

Compartilhar em outros sites

analeao2 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

analeao2 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

xanburzum 169

Compartilhar este post

Link para o post

Compartilhar em outros sites

Javascript - Passar Parâmetros para uma Função.

Tem como JS executar/chamar um programa externo?

PHP+Codeigniter - Importar Dados de uma Tabela para outra - MySql

Fóruns

Tempo Real

Informação importante