Ritar Tags HTML

[feasso 0]

Tenho um banco de dados que salva tags html para ser usada na diagramação da página posteriormente, porém, gostaria de mostrar o que está salvo lá, sem mostrar as tags html.

 

Como faço para limpar as tags apenas na hora de exibir ??

[Heber Almeida 0]

Dá pra você utilizar o Replacer + ou - assim

texto = Replace(texto, "<", "")
texto = Replace(texto, ">", "")

[xanburzum 169]

olha este exemplo:

 

<%
Function RemoveHTMLTags(ByVal strHTML)
	Dim objER
	Dim strTexto

	'Configurando o objeto de Expressão Regular
	Set objER			= New RegExp 
	objER.IgnoreCase	= True
	objER.Global		= True
	objER.Pattern		= "<[^>]*>"
	
	'Substituindo as tags encontradas pela expressão
	strTexto			= strHTML
	strTexto			= objER.Replace(strTexto, "")
	
	Set objER			= Nothing

	'Retornando a função
	RemoveHTMLTags = strTexto
End Function

'-----------------------------------------------------
'Exemplo de chamada da função
'-----------------------------------------------------
Dim HTML
HTML = "<font face='verdana' size='2'>teste</font> da função de retira as <b>TAGS</b> <font color='red'>HTML</font><br>"
'Texto com TAG
Response.Write HTML
'Texto sem TAG
Response.Write RemoveHTMLTags(HTML)
%>