cria um arquivo Microsoft Access database vazio

[xanburzum 169]

CriaDatabase cria um arquivo Microsoft Access database vazio . O

argumento necessário, caminho deve terminar em .mdb e reflete a localização de onde

a nova base de dados será criada. CriaDatabase só pode criar uma base de dados. Uma

erro ocorre se o caminho especificado não for encontrado ou se existir um banco de dados com

o mesmo nome no local especificado no argumento nome_do_caminho . Utilize a Declaração Kill

para eliminar uma base de dados MS Access

 

exemplo:

 

<%
CriaDatabase "C:\meu_banco.mdb"
%>

code:

 

<%
Private Sub CriaDatabase(byVal caminho)
	Dim objAccess, objFSO
	If LCase( Right( caminho, 4 ) ) <> ".mdb" Then
		Err.Raise 5155, "CriaDatabase Statement", _
			  "Nome do banco de dados deve terminar com '.mdb'"
		Exit Sub
	End If
	Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
	If objFSO.FileExists( caminho ) Then
		Set objFSO = Nothing
		Err.Raise 5155, "CriaDatabase Statement", _
			  "O arquivo especificados MS Access database já existe."
		Exit Sub
	End If
	Set objFSO = Nothing
	On Error Resume Next
	Set objAccess = CreateObject("Access.Application")
	If Err Then 
		On Error GoTo 0
		Err.Raise 5155, "Declaração CriaDatabase", _
			  "MS Access não está instalado no servidor."
		Exit Sub
	End If
	With objAccess
		.Echo False
		.NewCurrentDatabase caminho
		.CloseCurrentDatabase
		.Quit
	End With
	Set objAccess = Nothing
	On Error GoTo 0
End Sub
%>

[Ted k' 126]

implementando a criação de tabelas via SQL QUERY fica completo, boa contribuíção amigo xan!!