[Resolvido] Imprimir Array Javascript

[xanburzum 169]

Imprimir Array Javascript

 

Uma função otimizada para impressão de uma lista de elementos array Javascript .

 

 

<%
'  PrintJavascriptArray é uma função para impressão otimizada 
'Defini um resultado como uma lista separados por vírgulas
' Parametros:
' objCN [in] - string Conexão ou objeto connection .
' strsql [in] - Uma consulta que recupera os dados que devem ser impressos
'
' Usando:
'   <script type="text/javascript">
'	  myJavascriptArray = Array(
'		  <%  ImprimeJavascriptArray "DSN=MyDSN", _
'			  "SELECT ObjectID, ObjectName FROM tblObjects"   %>
'		 );
'   </script>
'

Function ImprimeJavascriptArray(ByRef objCN, strsql)
	Dim objRS, ArrayRecords, i, j
	Dim NumRows, NumColumns

	Set objRS = Server.CreateObject("ADODB.Recordset")
	objRS.Open strsql,objcn,adOpenForwardOnly,adLockReadOnly,adCmdText

	Do While Not objRS.EOF
		ArrayRecords = objRS.GetRows(50)

		NumRows = UBound(ArrayRecords,2)
		NumColumns = UBound(ArrayRecords,1)

		For i = 0 To NumRows
			For j = 0 To NumColumns
				Response.write Chr(34)
				If Not IsNull(ArrayRecords(j, i)) Then
					Response.write Replace(ArrayRecords(j, i), _
						Chr(34),Chr(34)&"+String.fromCharCode(34)+"&Chr(34))
				End If
				Response.write Chr(34)
				' Print comma, except at last record
				If Not objRS.EOF Or i <> NumRows _
					Or j <> NumColumns Then
					Response.write ","
				End If
			Next
		Next
		Response.write vbCrLf
	Loop
	objRS.Close
	Set objRS = nothing
End Function

%>