[Resolvido] Formatos

[xanburzum 169]

A função Format formata um número, data ou hora baseada no tipo de formato que o usuário digitou. Há duas declarações exigidas: expressão e de formato.

 

Expressão representa o número, a data ou a hora que você está tentando formatar.

 

O argumento formato informa ao sistema como exibir a entrada expressão.

Valores aceitáveis para o formato argumento são: Short Time, Long Time, Short

Date, Long Date, General Date, General Number, Currency, Fixed, Standard,

Percent, Yes/No, True/False, ou On / Off.

 

sintaxe:

string = Format(expression, format)

exemplo:

<%
 ' declara e set variaveis
dim num, datetime
num = 1741534.542058484
datetime = Now()
%>
Short Time:
<% = Format( datetime, "Short Time" ) %><BR>
Long Time:
<% = Format( datetime, "Long Time" ) %><BR>
Short Date:
<% = Format( datetime, "Short Date" ) %><BR>
Long Date:
<% = Format( datetime, "Long Date" ) %><BR>
General Date:
<% = Format( datetime, "General Date" ) %><BR>
General Number:
<% = Format( num, "General Number" ) %><BR>
Currency:
<% = Format( num, "Currency" ) %><BR>
Fixed:
<% = Format( num, "Fixed" ) %><BR>
Standard:
<% = Format( num, "Standard" ) %><BR>
Percent:
<% = Format( num, "Percent" ) %><BR>
Yes/No:
<% = Format( num, "Yes/No" ) %><BR>
True/False:
<% = Format( num, "True/False" ) %><BR>
On/Off:
<% = Format( num, "On/Off" ) %><BR>

code:

 

<%
Private Function Format(byVal expression, byVal strFormat)
	On Error Resume Next
	Select Case lcase( strFormat )
		Case "general date"
			Format = FormatDateTime(expression, 0)
		Case "long date"
			Format = FormatDateTime(expression, 1)
		Case "short date"
			Format = FormatDateTime(expression, 2)
		Case "long time"
			Format = FormatDateTime(expression, 3)
		Case "short time"
			Format = FormatDateTime(expression, 4)
		Case "general number"
			Format = Replace( expression, ",", "" )
		Case "currency"
			Format = FormatCurrency(expression, 2)
		Case "fixed"
			Format = Replace( FormatNumber(expression, _
				 2, -1), ",", "" )
		Case "standard"
			Format = FormatNumber(expression, 2, -1)
		Case "percent"
			Format = FormatPercent(expression, 2)
		Case "yes/no"
			expression = cLng(expression)
			If expression = 0 then 
				Format = "No" 
			else 
				Format = "Yes"
			end if
		Case "true/false"
			expression = cLng(expression)
			If expression = 0 then 
				Format = "False" 
			else 
				Format = "True"
			end if
		Case "on/off"
			expression = cLng(expression)
			If expression = 0 then 
				Format = "Off" 
			else 
				Format = "On"
			end if
		Case Else
			Format = expression
	End Select
	On Error GoTo 0
End Function
%>