Converter em Link

[xanburzum 169]

Esta função recebe uma string como entrada e quaisquer link "http" que encontra, para então deixá-lo clicáveis em um navegador.

 

Exemplo de utilização:

 

URLSLink Response.Write ( "Por favor, visite o meu site em http://www.xanburzum.com").

 

Isto irá inserir automaticamente a tag a href no local apropriado.

 

<%
Function URLSLink(strInput)

Dim iCurrentLocation  ' posição atual na seqüência de entrada
Dim iLinkStart        ' A partir da posição atual link
Dim iLinkEnd          ' final da atual posição do link
Dim strLinkText       ' convertendo para um link
Dim strOutput         ' Retornar string com links na mesma

'Iniciar no primeiro caractere da string
iCurrentLocation = 1

'Olhe para http:// no texto da atual posição 
'No final da string. iniciar o processo linking que estamos a fazer outra porque não existem 
'Mais http:// 's na string

Do While InStr(iCurrentLocation, strInput, "http://", 1) <> 0

' 'Definir a posição de início do ulo link
iLinkStart = InStr(iCurrentLocation, strInput, "http://", 1)

'Definir a posição do final do link. Eu uso o 
'Primeiro espaço como o fator determinante.
iLinkEnd = InStr(iLinkStart, strInput, " ", 1)

'certifique-se que não havia linha. Se houve uma quebra de linha antes do 
'Espaço
checkBreak=InStr(iLinkStart, strInput, chr(13), 1)
if checkBreak>0 and checkBreak<iLinkEnd then iLinkEnd=checkbreak


'Se nós não encontramos um espaço, então temos link para a 
'Fim da string

If iLinkEnd = 0 Then iLinkEnd = Len(strInput) + 1
    Select Case Mid(strInput, iLinkEnd - 1, 1)
            Case ",",".", "!", "?"
             iLinkEnd = iLinkEnd - 1
        End Select

'Isto adiciona à saída todas as output string não linkadas
'Até o link que estamos

strOutput = strOutput & Mid(strInput, iCurrentLocation, _
      iLinkStart - iCurrentLocation)

'Obter o texto que está linkando e armazená-lo em uma variável
strLinkText = Mid(strInput, iLinkStart, iLinkEnd - iLinkStart)

' Construir o link e anexar para a seqüência de saída

strOutput = strOutput & "<A HREF=""" & strLinkText & """>" _
   & strLinkText & "</A>"

'Alguns bons velhos depuração
'Response.Write iLinkStart & "," & iLinkEnd & "<BR>" & vbCrLf

'Redefinir a nossa localização atual até ao final desse link
  iCurrentLocation = iLinkEnd

Loop
'Tack no final da string. Preciso fazer isso para que 
'Não perca nenhuma trailing non-linked 

strOutput = strOutput & Mid(strInput, iCurrentLocation)

'Definir o valor de retorno
URLSLink = strOutput

End Function 'URLsLink
%>

[Mário Monteiro 179]

muito útil

[xanburzum 169]

ja usei bastante...