ASPJpeg

Patrique · Agosto 25, 2009

Galera, estou pesquisando aqui em relação ao aspjpeg mais não encontrei nada que pudesse me ajudar no que estou precisando.

O que eu estou precisando é fazer o seguinte.

Através do aspjpeg eu queria saber se é possível mudar a cor de um elemento, suponhamos que eu tenha um quadrado em png em 10x10, ele estaria em branco, dae eu gostaria de saber se é possível mudar este quadrado com o aspjpeg para vermelho... azul... amarelo... sacou? existe algum comando no aspjpeg que tenha a capacidade para mudar a cor do objeto?

Pesquisei no site mais não encontrei nada, porém tenho quase certeza que a um tempo atrás eu vi algo que falava sobre isso pelo aspjpeg.

Agradeço desde já a quem puder me dar uma ajuda.

Obrigado.

hargon · Agosto 25, 2009

Até onde eu sei é possível criar um quadrado através do AspJpeg. Não seria isso? Sobrepôr um quadrado em cima do local que você quer não resolveria?

Patrique · Agosto 25, 2009

Não resolveria não hargon, citei o quadrado como exemplo, na verdade os objetos terão N formas, caso não tiver como vou ter que fazer vários objetos com varias cores diferentes, isso me daria um trabalhaçooooooo hehe.

hargon · Agosto 25, 2009

Dê exemplos, monta um exemplo no Photoshop, Paint, etc, e posta para entendermos melhor.

xanburzum · Agosto 25, 2009

verifique no ASPJpeg tem a opção de Canvas.Brush.Color

recordset.Canvas.Brush.Color = &HFFCCCC

Patrique · Agosto 25, 2009

Vou te da um exemplo online mano hargon

Tem um site de criação de avatares que faz isso

note na url, o valor da variavel "s" esta como branco que é "FFFFFF"

Veja como ficou o avatar -> clique aqui

Agora veja se eu colocar "444444"

Agora veja como ficou -> clique aqui

Seria mais ou menos isso, o aspjpeg eu sei que trabalha com mascara, porém esta mudança de cor eu não tenho certeza.

Xam, essa eu já tenha tentado porém não funfou, agradeço pela atenção cara.

[]'s

hargon · Agosto 25, 2009

Patrique, sem querer te desanimar, mas com AspJpeg, acho que você não vai conseguir fazer isso.

Lembre-se que o componente é limitado perto de soluções em ASP.NET e PHP. :mellow:

xanburzum · Agosto 25, 2009

sei k dá pra trabalhar com Grayscale e Sepia, mas dependendoda situacaun, você consegue um trabalho melhor usando Flash ou silverlight, depois você só passa a imagem no ASP para salvar...

ou você tb pode Desenhando um Quadrado na Imagem, pegando a dimensaun e escolhendo a cor da caneta

Patrique · Agosto 25, 2009

Entendo, eu tinha ficado animado pois este site em questão utiliza asp como linguagem dinâmica dae fiquei com esperanças, mais realmente não deve da mesmo não <_< em relação ao uso de outras plataformas como no exemplo o flash eu não queria, pois estou enferrujado em flash e acho que não conseguiria http://forum.imasters.com.br/public/style_emoticons/default/blush.gif mais acho que vou fazer na mão mesmo heheehehe

[]'s e obrigado pela ajuda.

xanburzum · Agosto 25, 2009

faz como te falri, por exemplo você tendo uma imagem , você desenha um quadrado por exemplo em cia dela...

Patrique · Agosto 25, 2009

Mais ae não da cara o sistema é de avatar, tu viu aquele exemplo de site que eu passei, a imagem quadrada no primeiro post foi apenas um exemplo.

Estou aqui procurando referencias asp com flash para exportar a imagem, achei este aqui em php

http://www.sephiroth.it/tutorials/flashPHP/print_screen/

Mais não entendi como poderia fazer em asp, alguém ae tem alguma idéia?

[]'s

xanburzum · Agosto 25, 2009

sim, entendi...

dá uma olhada nesse aki,permite-lhe carregar um arquivo de modelo e definir os

Cores de primeiro e último de uma paleta. As cores são calculadas para você e para o resultado final é uma imagem que pode mudar

demo.asp

<%
SRC = Request.QueryString("SRC")
FirstHex = Request.QueryString("FirstHex")
LastHex = Request.QueryString("LastHex")
%>
<HTML>
	<HEAD>
		<TITLE></TITLE>
	</HEAD>
	<BODY>

		<FORM name="MyForm">

			<SELECT name="PrePop" onChange="document.MyForm.SRC.value = this[this.selectedIndex].value">
				<OPTION value="">Images Predefidas </OPTION>
				<OPTION value="GoButton.txt">Go Button</OPTION>
				<OPTION value="TopLeftCorner16.txt">Top Left Corner</OPTION>
				<OPTION value="TopRightCorner16.txt">Top Right Corner</OPTION>
				<OPTION value="BottomLeftCorner16.txt">Bottom Left Corner</OPTION>
				<OPTION value="BottomRightCorner16.txt">Bottom Right Corner</OPTION>
			</SELECT><BR>

			Template File Source:<BR>
			<INPUT name="SRC" value="<%=SRC%>" size="50"><BR><BR>

			First Hex: <INPUT name="FirstHex" value="<%=FirstHex%>" size="6" maxlength="6"><BR>

			Last Hex: <INPUT name="LastHex" value="<%=LastHex%>" size="6" maxlength="6"><BR>
			
			<INPUT type="Submit" value="Create Image">
		</FORM>

		Image:
		<IMG src="Image.asp?<%=Request.QueryString%>" align="absmiddle"><BR>
	</BODY>
</HTML>

image.asp

<%

Option Explicit

Dim gStrTransparent	
Dim gStrData		

' Define the transparent image
gStrTransparent = _
	"4749463839610100010080FF00C63535" & _
	"00000021F90401000000002C00000000" & _
	"010001000002024401003B"

Call Main()
' ------------------------------------------------------------------------------
Sub Main()
	
	Dim lStrSRC				
	Dim lStrDataAry			
	Dim lStrPalette			
	Dim lStrPaletteAry		
	Dim lLngColors			
	Dim lStrFirstHex		
	Dim lStrLastHex			
	Dim lStrTemplate		
	Dim lLngIndex			
	

	lStrSRC = Request.QueryString("SRC")
	lStrFirstHex = Request.QueryString("FirstHex")
	lStrLastHex = Request.QueryString("LastHex")


	lStrFirstHex = ValidColor(lStrFirstHex)
	lStrLastHex = ValidColor(lStrLastHex)
	

	If lStrSRC = "" Then
		

		Call ReturnImage(gStrTransparent, "File Not Specified")
		Exit Sub
	
	End If
	

	If Not Load(lStrSRC) Then
		

		Call ReturnImage(gStrTransparent, "Arquivo não encontrado")
		Exit Sub
		
	End If


	lStrDataAry = Split(gStrData, ";",4)
	lLngColors		= CInt(lStrDataAry(0))
	lStrTemplate	= lStrDataAry(3)


	If lStrFirstHex = "" Then lStrFirstHex = lStrDataAry(1)
	If lStrLastHex = "" Then lStrLastHex = lStrDataAry(2)
	

	lStrPalette = DefinePalette(lLngColors, lStrFirstHex, lStrLastHex)
	

	If lStrPalette = "" Then
		

		Call ReturnImage(gStrTransparent, "Palette Not Defined")
		Exit Sub
		
	End If
	

	lStrpaletteAry = Split(lStrPalette, ";", lLngColors)
	

	For lLngIndex = 1 To lLngColors
		lStrTemplate = Replace(lStrTemplate, "[" & lLngIndex & "]", lStrPaletteAry(lLngIndex -1))
	Next
	

	Call ReturnImage(lStrTemplate, "Success")
	
End Sub
' ------------------------------------------------------------------------------
Function ValidColor(ByVal pStrColor)



	Dim lLngIndex	
	

	pStrColor = Replace(pStrColor, "#", "")
	pStrColor = Replace(pStrColor, "0x", "", 1, -1, vbTextCompare)
	
	
	If Not Len(pStrColor) = 6 Then Exit Function
	

	For lLngIndex = 1 To 6
		
		
		If InStr(1, "0123456789ABCDEF", Mid(pStrColor, lLngIndex, 1), vbTextCompare) = 0 Then
			Exit Function
		End If
	
	Next
	

	ValidColor = pStrColor
	
End Function
' ------------------------------------------------------------------------------
Function Load(ByRef pStrSRC)

	Dim lObjFSO		
	Dim lStrData	
	Dim lStrPath	
	

	If InStr(1, pStrSrc, ":\") = 0 Then

		
		lStrPath = Server.MapPath(pStrSrc)

	Else
	

		lStrPath = pStrSrc
	
	End If
	

	Set lObjFSO = Server.CreateObject("Scripting.FileSystemObject")
	If lObjFSO.FileExists(lStrPath) Then
		gStrData = lObjFSO.OpenTextFile(lStrPath).ReadAll
		Load = True
	Else
		Load = False
	End If
	Set lObjFSO = Nothing
	

	gStrData = Replace(gStrData, " ", "")
	gStrData = Replace(gStrData, vbTab, "")
	gStrData = Replace(gStrData, vbCr, "")
	gStrData = Replace(gStrData, vbLf, "")

End Function
' ------------------------------------------------------------------------------
Function DefinePalette(ByRef pLngColors, pStrFirstHex, pStrLastHex)

	Dim lDblPhaseAry	
	Dim lBytRedAry		
	Dim lBytGreenAry	
	Dim lBytBlueAry	
	Dim lLngIndex		
	Dim lStrPaletteAry	
	

	lDblPhaseAry	= Split(String(pLngColors -1, ","), ",")
	lBytRedAry		= Split(String(pLngColors -1, ","), ",")
	lBytGreenAry	= Split(String(pLngColors -1, ","), ",")
	lBytBlueAry		= Split(String(pLngColors -1, ","), ",")
	lStrPaletteAry	= Split(String(pLngColors -1, ","), ",")		
	

	lDblPhaseAry(0) = 0
	For lLngIndex = 1 To pLngColors - 2
		lDblPhaseAry(lLngIndex) = (lLngIndex * ((256/pLngColors)/256))
	Next
	lDblPhaseAry(pLngColors - 1) = 1
	

	lBytRedAry(0) = CInt("&h" & Left(pStrFirstHex, 2))
	lBytGreenAry(0) = CInt("&h" & Mid(pStrFirstHex, 3, 2))
	lBytBlueAry(0) = CInt("&h" & Right(pStrFirstHex, 2))


	lBytRedAry(pLngColors - 1) = CInt("&h" & Left(pStrLastHex, 2))
	lBytGreenAry(pLngColors - 1) = CInt("&h" & Mid(pStrLastHex, 3, 2))
	lBytBlueAry(pLngColors - 1) = CInt("&h" & Right(pStrLastHex, 2))


	For lLngIndex = 1 To pLngColors - 2
		
		lBytRedAry(lLngIndex) = lBytRedAry(0) + ((lBytRedAry(pLngColors - 1) - lBytRedAry(0)) * lDblPhaseAry(lLngIndex))
		lBytGreenAry(lLngIndex) = lBytGreenAry(0) + ((lBytGreenAry(pLngColors - 1) - lBytGreenAry(0)) * lDblPhaseAry(lLngIndex))
		lBytBlueAry(lLngIndex) = lBytBlueAry(0) + ((lBytBlueAry(pLngColors - 1) - lBytBlueAry(0)) * lDblPhaseAry(lLngIndex))
		

		lStrPaletteAry(lLngIndex) = _
			Right("0" & Hex(lBytRedAry(lLngIndex)), 2) & _
			Right("0" & Hex(lBytGreenAry(lLngIndex)), 2) & _
			Right("0" & Hex(lBytBlueAry(lLngIndex)), 2)
	Next


	lStrPaletteAry(0) = _
		Right("0" & Hex(lBytRedAry(0)), 2) & _
		Right("0" & Hex(lBytGreenAry(0)), 2) & _
		Right("0" & Hex(lBytBlueAry(0)), 2)


	lStrPaletteAry(pLngColors - 1) = _
		Right("0" & Hex(lBytRedAry(pLngColors - 1)), 2) & _
		Right("0" & Hex(lBytGreenAry(pLngColors - 1)), 2) & _
		Right("0" & Hex(lBytBlueAry(pLngColors - 1)), 2)


	DefinePalette = Join(lStrPaletteAry, ";")
	
End Function
' ------------------------------------------------------------------------------
Sub ReturnImage(ByRef pStrImage, ByRef pStrDebug)

	Dim lLngMaxIndex	
	Dim lLngIndex	
	
	
	If LCase(Request.QueryString("Debug")) = "true" Then
		
	
		Response.Write("Debug: " & pStrDebug & "<BR>")
		

		Response.Write("Hex Data:<PRE>")
		For lLngIndex = 1 To Len(pStrImage) Step 2
			Response.Write(Mid(pStrImage, lLngIndex, 2) & " ")
			If (lLngIndex + 1) Mod 32 = 0 Then Response.Write(vbCrLf)
		Next
		Response.Write("</PRE>")
	Else
		
		
		Response.ContentType = "image/gif"

	
		lLngMaxIndex = Len(pStrImage) \ 2
		
		
		For lLngIndex = 1 To lLngMaxIndex
		
			Response.BinaryWrite(ChrB("&h" & Mid(pStrImage, ((lLngIndex - 1) * 2) + 1, 2)))
		Next
	End If
End Sub
' ------------------------------------------------------------------------------
%>

se kiser me manda um email, k te passo as imagens, tb

Patrique · Agosto 25, 2009

Opa, valew xam, vou da uma estudada neste script que você me passou, vamos ver se sai alguma coisa!

valew ae cara!

Arquivado

ASPJpeg

Recommended Posts

Patrique 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

hargon 64

Compartilhar este post

Link para o post

Compartilhar em outros sites

Patrique 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

hargon 64

Compartilhar este post

Link para o post

Compartilhar em outros sites

xanburzum 169

Compartilhar este post

Link para o post

Compartilhar em outros sites

Patrique 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

hargon 64

Compartilhar este post

Link para o post

Compartilhar em outros sites

xanburzum 169

Compartilhar este post

Link para o post

Compartilhar em outros sites

Patrique 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

xanburzum 169

Compartilhar este post

Link para o post

Compartilhar em outros sites

Patrique 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

xanburzum 169

Compartilhar este post

Link para o post

Compartilhar em outros sites

Patrique 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

PHP+Codeginiter - Orientação para Impressão

Ajuda com Extends e envio para o banco

Fixar div até atingir uma certa altura

Fóruns

Tempo Real

Informação importante