[Resolvido] verifica a existência de unidade

[xanburzum 169]

A função Drive verifica a existência de uma unidade, em seguida, verifica a prontidão.

Há um argumento necessário, drivespec que deve ser uma letra que representa uma

drive (A-Z) no servidor.

 

A função Drive retorna a letra da unidade, se ele existe e está pronto.

Se a unidade existe, mas não está pronto, retorna nulo. Se a unidade não

existir, retorna unidade vazia.

 

sintaxe:

 

string = Drive(drivespec)

 

exemplo:

 

Retorna uma lista de todas as unidades existentes e prontas no servidor.

 

<%
Call ListaDrive()

Private Sub ListaDrive()
	Dim i, a, drv, readydrives
	Dim availablebutnotready

	readydrives = ""
	availablebutnotready = ""
	for i = 65 to 90	 ' A - Z
		drv = chr(i)
		a = Drive(drv)
		If IsNull(a) Then
			availablebutnotready = _
			availablebutnotready & _
			drv & ", "
		ElseIf IsEmpty(a) Then
		Else
			readydrives = _
			readydrives & _
			a & ", "	
		End If
	next
	Response.Write "Unidades Prontas:<BR>"
	Response.Write readydrives & "<BR><BR>"
	Response.Write "Unidades Not Ready:<BR>"
	Response.Write availablebutnotready & "<BR><BR>"
End Sub
%>

code:

 

<%
Private Function Drive(byVal driveSpec)
	Dim objFSO, boolFound, objDrive
	Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
	boolFound = objFSO.DriveExists(driveSpec)
	if boolFound then
		Set objDrive = objFSO.GetDrive(driveSpec)
		if objDrive.IsReady Then
			Drive = objDrive.DriveLetter
		else
			Drive = Null
		end if
		Set objDrive = Nothing
	else
		Drive = Empty
	End If
	Set objFSO = Nothing
End Function
%>