[Resolvido] Covertendo caracteres para Maiusculo

[Bruno Sam 0]

Boa tarde,

 

Alguem sabe como eu converto o valor do recordset para todas as palavras ficarem com a primeira letra maiúscula??

 

Exemplo:

 

<%=RS("nome")%> retornou LUIS SANTOS DA SILVA. Gostaria de alterar o valor para Luis Santos Da Silva.

 

Alguem sabe?

 

Encontrei na internet, mas nenhuma funcionou no recordset, ou não soube implementar. <%=RS("FILIAL")%>.

 

Se alguem puder ajudar... :unsure:

[desisto 0]

é so chamar a funcao

 

LetraMaiuscula(RS("nome"))

 

se você der um .write direto, RS("nome"), vai mostrar como está no banco, precisa ser pela funcao

[Bruno Sam 0]

é so chamar a funcao

 

LetraMaiuscula(RS("nome"))

 

se você der um .write direto, RS("nome"), vai mostrar como está no banco, precisa ser pela funcao

 

Você tem como me passar essa função essa função "LetraMaiuscula"??

[hargon 64]

Seja bem-vindo ao Fórum Bruno Sam. Caso ainda não tenha lido as Regras do Fórum, clique aqui para conhecê-las.

 

Sobre sua dúvida, dê uma olhada aqui

[Bruno Sam 0]

Seja bem-vindo ao Fórum Bruno Sam. Caso ainda não tenha lido as Regras do Fórum, clique aqui para conhecê-las.

 

Sobre sua dúvida, dê uma olhada aqui

 

 

Valeu pela ajuda galera!

 

Encontrei essa função que resolveu o problema:

 

<%

'-----------------------------------------------------

'Função: FormataNome(ByVal Nome)

'Sinopse: Formata nome próprio para que as primeiras

' letras fiquem maiúsculo (com exceções)

'Parametro:

' Nome = Nome próprio a ser formatado

'Autor: Gabriel Fróes (www.codigofonte.com.br)

'Data: 20/10/2008

'-----------------------------------------------------

Function FormataNome(ByVal Nome)

'Declarações

Dim arrNome

Dim Retorno

Dim Cont

Dim objER

Dim Excecoes

 

'Inicializando e configurando o objeto (expressão regular)

Set objER = New RegExp

objER.IgnoreCase= True

objER.Global = True

Excecoes = "^(da|das|de|do|dos|e)$"

objER.Pattern = Excecoes

 

'Por padrão o nome todo ficará minúsculo

Nome = Lcase(Replace(Nome, " ", " "))

 

'Gerando um array com todas as palavras individualmente

arrNome = Split(Nome, " ")

 

Retorno = ""

 

For Cont = 0 To Ubound(arrNome)

arrNome(Cont) = Trim(arrNome(Cont))

'Colocando a primeira letra de cada palavra maiúscula (salvo exceções)

If Not objER.Test(arrNome(Cont)) Then

If Not arrNome(Cont) = "" Then

arrNome(Cont) = Ucase(Left(arrNome(Cont), 1)) & Right(arrNome(Cont), Len(arrNome(Cont))-1)

End If

End If

Retorno = Retorno & " " & arrNome(Cont)

Next

 

'Destruindo o objeto (expressão regular)

Set objER = Nothing

 

'Retorno da função

FormataNome = Trim(Retorno)

End Function

 

'Teste de utilização da função

Response.Write FormataNome ("JOSÉ FRANCISCO DOS SANTOS") & "<br />"

Response.Write FormataNome ("joão de oliveira chavier e silva") & "<br />"

%>

 

Fica aí para os próximos que precisarem.

 

Valeww

[desisto 0]

eu tenho uma que é mais simples

 

vou procurar e mais tarde eu posto... caso eu esqueca mande uma PM

[Bruno Sam 0]

eu tenho uma que é mais simples

 

vou procurar e mais tarde eu posto... caso eu esqueca mande uma PM

 

ÓTimo. Postaí. Valeu!

[desisto 0]

ta na mao

 

Function minuscula(Texto)
	IF Texto = "" THEN Exit Function
	minuscula = UCase(Mid(Texto,1,1)) & LCase(Mid(Texto,2,Len(Texto)-1))
	End Function
	Function formata(Texto)
	IF Texto = "" THEN Exit Function
	Texto = Trim(Texto)
	IF inStr(Texto," ") = 0 THEN
	formata = minuscula(Texto)
	ELSE
	arrTexto = Split(Texto," ")
	For x = 0 To UBound(arrTexto)
	formata = formata & minuscula(arrTexto(x))& " "
	Next END IF
End Function

response.Write minuscula("mINUSCULO do papai")

esse cod é antigo, nao sei se eu fiz ou se adaptei de algum outro

[xanburzum 169]

mais um exemplo

 

<%

    dim TMPfield, str_Field, str_FieldTotal, int_counter
  
    FUNCTION theField(TMPfield)
        str_Field = SPLIT( TMPfield, " " )
  
        'OBTEMOS o NUMERO DE PALABRAS
        str_FieldTotal = UBOUND( str_Field )
        int_counter = 0
  

        DO WHILE ( int_counter < ( str_FieldTotal + 1 ) )
  
                TMPfield = Response.Write( UCASE( LEFT( str_Field( int_counter ), 1 ) ) & _
                 LCASE( MID( str_Field( int_counter ), 2 ) ) )
  

            IF int_counter < ( str_FieldTotal ) THEN
                TMPfield = Response.Write( TMPfield & " " )
            END IF
  
            int_counter = int_counter + 1
  
        LOOP
    END FUNCTION
'chamando a funçaun
    Response.Write( theField( "xanburzum imasters" ) )
  %>