detalhes de um diretório

[xanburzum 169]

listar os detalhes de um diretório e salvar os resultados em um arquivo de texto.

 

    
    Dim fso, strPath, fsoFolder, fsoTextFile, strTemp, strData, fsoFile, strFile
    Set fso = CreateObject("Scripting.FileSystemObject")
    strPath = "?"
    If WScript.Arguments.Count > 0 Then strPath = WScript.Arguments(0)
    Do While Not fso.FolderExists(strPath)
    	strPath = InputBox ("Digite o diretório para detalhar:","Directory Lister" )
    	If Len(strPath) = 0 Then WScript.Quit
    Loop
    Set fsoFolder = fso.GetFolder(strPath)
    strFile = "dir" & fsoFolder.Name & ".txt"
    strTemp = Left(WScript.ScriptFullName,Len(WScript.ScriptFullName) - Len(WScript.ScriptName))
    Set fsoTextFile = fso.openTextFile(strTemp & strFile, 2, True)
    fsoTextFile.WriteLine "Directório de informação para: " & strPath
    fsoTextFile.WriteBlankLines(1)
    strData = "File Name" & String(16," ")
    strData = strData & "Size" & String(4," ")
    strData = strData & "Date Modified "
    strData = strData & "File Type"
    fsoTextFile.WriteLine (strData)
    fsoTextFile.WriteBlankLines(1)
    For Each fsoFile in fsoFolder.Files
    	If fsoFile.Name <> strFile AND fsoFile.Name <> WScript.ScriptName Then
    		strTemp = Left(fsoFile.Name,24)
    		strData = strTemp & String(25-Len(strTemp)," ")
    		strTemp = CLng(fsoFile.Size / 1024) & " KB"
    		strData = strData & strTemp & String(8-Len(strTemp)," ")
    		strTemp = Month(fsoFile.DateLastModified) & "/" & Day(fsoFile.DateLastModified) & "/" & Year(fsoFile.DateLastModified)
    		strData = strData & strTemp & String(15-Len(strTemp)," ") & fsoFile.Type
    		fsoTextFile.WriteLine (strData)
    	End If
    Next
    WScript.Echo "Detalhamento do diretório " & strPath & " está completo. Os resultados estão no arquivo chamado
 " & strFile
    WScript.Quit

[Patrique 0]

Fonte: http://www.pscode.com/vb/scripts/ShowCode.asp?txtCodeId=6593&lngWId=4

[xanburzum 169]

tenho varios code salvo em minha maquina, na verdade estou a muito tempo fazendo tipo uma biblioteca virtual de code, k muitas vezes naun tenho

a fonte, kem souber ou puder ajudar, e mais uma contribuicaun