Ir para conteúdo

POWERED BY:

Arquivado

Este tópico foi arquivado e está fechado para novas respostas.

xanburzum

[Resolvido] Admin Explorer

Por , em ASP Clássico

Recommended Posts

xanburzum    169

xanburzum
Postado

Administrador do site. Este arquivo permitem que você administrar seu site. Inclui função como upload de arquivos, Copiar ou mover arquivos em pastas, renomear, apagar e outros pensa

 

<%' Password é 'xan'
IntPass = "xan"
RedirName = Mid(Request.ServerVariables("Script_Name"),InstrRev(Request.ServerVariables("Script_Name"),"/") + 1)
PTitulo = "Site Web"
Response.Buffer = True
Response.Clear
Dim Myname,MyPass,Pasa
If Not Session("Open") = "True" then%>
<%= Encabezado("http://" & Request.ServerVariables("SERVER_NAME"),1)%>
<BODY bgcolor=#FFCC00 onLoad="window.Introd.PassW.focus();">
<FORM name="Introd" method="post" action="<%=RedirName%>">
<p align=left><a href="http://<%=Request.ServerVariables("SERVER_NAME") & "/"%>" class=normalN>
http://<%=Request.ServerVariables("SERVER_NAME") & "/"%></a></p>
<table align=left border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" width=250 bgcolor="#FFFFCC">
<tr><td align="center">
<P><font class=normal>Senha:</font> <input type=password name=PassW ID=PassW size=8> <input type=submit class=boton2 name=Entrar ID=Entrar value=" Enter "></P>
</td></tr></table></form><br><br><br>
<p align=left style="font-family:verdana,helvetica,arial,sans serif;color:#000000;font-size:8pt;font-weight:bold;"><%= date%></p>
</BODY></HTML>
<%	Session("Open") = "True"
	Response.End
else
	if Session("Permiso") = "1" then
	else	
		Pasa = "True"
		MyPass = Request.Form("PassW")
		If not MyPass = IntPass then Pasa = "False"
		If Pasa = "False" then
			Session.Abandon
			Response.Redirect RedirName
			Response.End
		else
			Session("Permiso") = "1"
			Session("FolderPrim") = left(Request.ServerVariables("PATH_TRANSLATED"),instrrev(Request.ServerVariables("PATH_TRANSLATED"),"\",len(Request.ServerVariables("PATH_TRANSLATED"))))
			Session("Inter") = left(Request.ServerVariables("PATH_TRANSLATED"),instrrev(Request.ServerVariables("PATH_TRANSLATED"),"\",len(Request.ServerVariables("PATH_TRANSLATED"))))
			Session("ChkSpace") = "1"
			Session("NumFol") = 0
		end if
	end if
End If
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Dim Espa
Set Fso = CreateObject("Scripting.FileSystemObject")
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Function SpaceFiles(Direc)
Set fx1 = FSO.GetFolder(Direc)
Set fx2 = fx1.Files
For Each f1 In fx2
    Espa = Espa + cdbl(f1.Size)
Next
End Function
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Function SpaceFolders(Directo)
Dim f, f1, sf
Set f = FSO.GetFolder(Directo)
Set sf = f.SubFolders
For Each f1 In sf
	Session("NumFol") = cint(Session("NumFol")) + 1
	Session("Fol" & Session("NumFol")) = f1.Path & "\"
    SpaceFiles (f1.Path)
    SpaceFolders (f1.Path)
Next
End Function
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
function SpaceKB(Ruta)
	Session("NumFol") = 1
	Session("Fol" & 1) = Session("FolderPrim")
	SpaceFiles (Ruta)
	SpaceFolders (Ruta)
	SpaceKB = Espa
end function
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
function Encabezado(Titulo,index)
Response.Write "<!-- Inicio Intranet -->" & vbcr
Response.Write "<html><head>" & vbcr
Response.Write "<META NAME=""GENERATOR"" Content=""Microsoft Visual Studio 6.0"">" & vbcr
Response.Write "<META HTTP-EQUIV=""REFRESH"" CONTENT=""1800; URL=" & RedirName & "?timeout=Si"">" & vbcr
Response.Write "<title>" & Titulo & " - Web Admin</title>" & vbcr
Response.Write "</head>" & vbcr
Response.Write "<Style Type=""text/css"">" & vbcr
Response.Write "<!--" & vbcr
Response.Write "	p, dt, dd, dl, ul, ol, li, font.main{font-family:arial,sans serif;font-size:9pt;color:#000000;}" & vbcr
Response.Write "	.grande{font-family:verdana,helvetica,arial,sans serif;font-size:18pt;}" & vbcr
Response.Write "	.normalB{font-family:verdana,helvetica,arial,sans serif;color:#0033CC;font-size:10pt;font-weight:bold;}" & vbcr
Response.Write "	.normalN{font-family:verdana,helvetica,arial,sans serif;color:#000000;font-size:10pt;font-weight:bold;}" & vbcr
Response.Write "	.normalL{font-family:verdana,helvetica,arial,sans serif;color:#FFFFFF;font-size:10pt;Cursor:hand;}" & vbcr
Response.Write "	.normalNroja{font-family:verdana,helvetica,arial,sans serif;color:#FF0000;font-size:10pt;font-weight:bold;}" & vbcr
Response.Write "	.normal{font-family:verdana,helvetica,arial,sans serif;color:#000000;font-size:10pt;}" & vbcr
Response.Write "	.vin{font-family:verdana,helvetica,arial,sans serif;color:#0033CC;font-size:11pt;Cursor:hand;}" & vbcr
Response.Write "	.Count{font-family:verdana,helvetica,arial,sans serif;color:#FFCC00;font-size:11pt;font-weight:bold;}" & vbcr
Response.Write "	.chica{font-family:verdana,helvetica,arial,sans serif;font-size:7pt;}" & vbcr
Response.Write "	.hige{font-family:verdana,helvetica,arial,sans serif;color:#000000;font-size:10pt;}" & vbcr
Response.Write "	.T1{font-family:verdana,arial,sans serif;font-weight:bold;color:#FFCC00;font-size:48pt;}" & vbcr
Response.Write "	.cabz{font-family:verdana,arial,sans serif;font-weight:bold;color:#FFCC00;font-size:12pt;}" & vbcr
Response.Write "	.tbl2{font-family:verdana,arial,sans serif;font-weight:bold;color:#FFCC00;font-size:11pt;}" & vbcr
Response.Write "	.pie{font-family:verdana,arial,sans serif;font-weight:bold;color:#FFCC00;font-size:8pt;}" & vbcr
Response.Write "	.boton1{background-Color:#FFCC00;Cursor:hand;}" & vbcr
Response.Write "	.boton2{background-Color:#CCFFCC;Cursor:hand;}" & vbcr
Response.Write "	a:link{color:#0033CC;}" & vbcr
Response.Write "	a:active{color:#990000;}" & vbcr
Response.Write "	a:visited{color:#0033CC;}" & vbcr
Response.Write "	a:hover{color:#ff3300;}" & vbcr
Response.Write "-->" & vbcr
Response.Write "</Style>" & vbcr
if index = 0 then 
	Response.Write "<body bgcolor=#FFCC00 topmargin=2 leftMargin=2 rightMargin=2>" & vbcr
	Response.Write "<P align=center><font class=grande>Web Admin</font><br><font class=chica>" & DirLoc & "</font></P>"
end if
end function
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
function Pie(index)
Response.Write "<P align=center class=normal></p>" & vbcr
If index = 1 then 
Response.Write "<P align=center class=normal><a href=" & RedirName & " title=""Back to Web Admin"">Back to Web Admin</a></P>" & vbcr
end if
Response.Write "<P align=center class=normalB><a href=" & RedirName & "?Cerrar=1 title=""Close Session"">Close</a></P>" & vbcr
Response.Write "</body>" & vbcr
Response.Write "</html>" & vbcr
Response.Write "<!-- Fin Intranet -->"
end function
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
function getString(StringBin)
	getString =""
	For intCount = 1 To LenB(StringBin)
		getString = getString & chr(AscB(MidB(StringBin,intCount,1))) 
	Next
end function
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
function getByteString(StringStr)
	For i = 1 To Len(StringStr)
		char = Mid(StringStr, i, 1)
		getByteString = getByteString & chrB(AscB(char))
	Next
end function
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
function BuildUploadRequest(RequestBin)
	Dim scrDict
	Set scrDict = Server.CreateObject("Scripting.Dictionary")
	PosBeg = 1
	PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13)))
	boundary = MidB(RequestBin,PosBeg,PosEnd-PosBeg)
	boundaryPos = InstrB(1,RequestBin,boundary)
	Do until (boundaryPos=InstrB(RequestBin,boundary & getByteString("--")))
		Dim UploadControl
		Set UploadControl = CreateObject("Scripting.Dictionary")
		Pos = InstrB(BoundaryPos,RequestBin, getByteString("Content-Disposition"))
		Pos = InstrB(Pos,RequestBin,getByteString("name="))
		PosBeg = Pos+6
		PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(34)))
		Name = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
		PosFile=InstrB(BoundaryPos,RequestBin,getByteString("filename="))
		PosBound = InstrB(PosEnd,RequestBin,boundary)
		If PosFile<>0 AND (PosFile<PosBound) Then
			PosBeg = PosFile + 10
			PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(34)))
			FileName = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
			UploadControl.Add "FileName", FileName
			Pos = InstrB(PosEnd,RequestBin,getByteString("Content-Type:"))
			PosBeg = Pos+14
			PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13)))
			ContentType = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
			UploadControl.Add "ContentType",ContentType
			PosBeg = PosEnd+4
			PosEnd = InstrB(PosBeg,RequestBin,boundary)-2
			Value = MidB(RequestBin,PosBeg,PosEnd-PosBeg)
		Else
			Pos = InstrB(Pos,RequestBin,getByteString(chr(13)))
			PosBeg = Pos+4
			PosEnd = InstrB(PosBeg,RequestBin,boundary)-2
			Value = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
		End If
		UploadControl.Add "Value" , Value
		scrDict.Add Name, UploadControl
		BoundaryPos=InstrB(BoundaryPos+LenB(boundary),RequestBin,boundary)
	Loop	
	Set BuildUploadRequest = scrDict
	Set scrDict = Nothing
end function
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
function ParseFileFromPath(iStr)
	Dim tPos
	tPos = InStrRev(iStr, "\")
	If tPos = 0 Or IsNull(tPos) Then
		ParseFileFromPath = iStr
		Exit Function
	End If
	ParseFileFromPath = Right(iStr, Len(iStr) - tPos)
end function
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
function Guardar( NomFile, Path)
    Dim strRtn
    binData = Dict.Item("fName").Item("Value")
    strRtn = ""
    For intCount = 1 To LenB(binData)
        strRtn = strRtn & Chr(AscB(MidB(binData, intCount, 1)))
    Next
    binData = strRtn
    NomRuta = Path & NomFile
    Set Archivo = FSO.CreateTextFile(NomRuta, True)
    Archivo.Write(binData)
    Archivo.Close
    Guardar = True
end function
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
If Request.QueryString("Cerrar") = "1" then
	Session.Abandon
	Response.Redirect RedirName
	Response.End
end if
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
DirRaiz = "http://" & Request.ServerVariables("SERVER_NAME") & Replace(Request.ServerVariables("SCRIPT_NAME"),"/" & RedirName,"")
DirLoc = replace(DirRaiz & Replace(Mid(Session("Inter"),len(Session("FolderPrim")),250),"\","/")," ","%20")
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
If Request.QueryString("SubFolder") = "True" then 
	Session("Inter") = Request.QueryString("Loc")
	Response.Redirect RedirName
	Response.End
end if
If Request.QueryString("UpFolder") = "True" then
	Session("Inter") = Request.QueryString("Ruta")
	Response.Redirect RedirName
	Response.End
end if
If Request.QueryString("DelFolder") = "True" then
	Session("DelFolder") = "True"
	Session("DelFolName") = Request.QueryString("Nombre")
	Response.Redirect RedirName
	Response.End
end if
If Request.QueryString("ModFolder") = "True" then
	Session("ModFolder") = "True"
	Session("ModFolName") = Request.QueryString("Nombre")
	Response.Redirect RedirName
	Response.End
end if
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
If Request.QueryString("UpFirst") = "True" then
%>
<%= Encabezado("UpLoad Files Form",0)%>
<div align="center"><center>
<FORM name="Enviar" enctype="multipart/form-data" action="<%=RedirName%>?Up=True" method="POST">
<table border="1" bgcolor="#FFFFCC" cellspacing="0" cellpadding="0" bordercolor="#000000">
<tr><td width="100%">
<P align=center class=chica>~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~</P>
<P align=center class=normal>Selecione o arquivo para enviar</P>
<Center><INPUT name=fName type=file></CENTER>
<CENTER><FONT class=chica>O tempo está relacionada ao tamanho do arquivo.</FONT><br><br>
<INPUT name=button2 type=submit class=boton2 value="~Send~"><br><br>
<P align=center class=chica>~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~</P>
</CENTER></td></tr></table></center></div>
</FORM>
<%= Pie(1)%>
<%Response.End
end if
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
If Request.QueryString("Up") = "True" then
Dim tBytes,binData,Dict
tBytes = Request.TotalBytes
binData = Request.BinaryRead(tBytes)
Set Dict = BuildUploadRequest(binData)
FileName = right(Dict.Item("fName").Item("FileName"),len(Dict.Item("fName").Item("FileName"))-instrrev(Dict.Item("fName").Item("FileName"),"\"))
Ruta = Session("Inter")
Nue = ""
For A = 1 To Len(FileName)
    Txt = Mid(FileName, A, 1)
    Txt = LCase(Txt)
    Select Case Txt
    Case "á": Txt = "a"
    Case "é": Txt = "e"
    Case "í": Txt = "i"
    Case "ó": Txt = "o"
    Case "ú": Txt = "u"
    End Select
    Nue = Nue & Txt
Next
FileName = Nue
GetAnExtn = fso.GetExtensionName(FileName)
If lcase(GetAnExtn) = "html" then FileName = left(FileName,len(FileName)-1)
If instr(1,Dict.Item("fName").Item("FileName"),":\") = 2 and len(Dict.Item("fName").Item("FileName")) >= 5 then
	DoGuardar = Guardar(Filename,Ruta)
	Mensaje = "Erro, tente novamente"
else	
	DoGuardar = false
	Mensaje = "Erro,arquivo não existi."
end if
If DoGuardar = true then
%>
<%= Encabezado("Sending File",0)%>
<div align="center"><center>
<table border="1" bgcolor="#FFFFCC" cellspacing="0" cellpadding="0" bordercolor="#000000">
<tr><td width="100%">
<P align=center class=chica>~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~</P>
<P align=center><font class=normal>Name:</font><br><font class=chica><%= FileName%></font></P>
<P align=center><font class=normal>Size:</font><br><font class=chica><%= tBytes%> Bytes</font></P>
<P align=center><font class=normal>Type:</font><br><font class=chica><%= Dict.Item("fName").Item("ContentType")%></font></P>
<br>
<center><a href="<%=RedirName%>?UpFirst=True">Voltar para UpLoad Files Form</a></center>
<P align=center class=chica>~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~</P>
</td></tr></table></center></div>
<%= Pie(1)%>
<%Session("ChkSpace") = "1"
else%>
<%= Encabezado("Erro no envio do arquivo",0)%>
<div align="center"><center>
<table border="1" bgcolor="#FFFFCC" cellspacing="0" cellpadding="0" bordercolor="#000000">
<tr><td width="100%">
<P align=center class=chica>~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~</P>
<FORM name="env" action"<%= RedirName%>?UpFirst=True">
<P align=center><font class=normal><%= Mensaje%></font><br></P>
<br>
<input name="Usuario" type="hidden" value="<%= Session("Nombre")%>">
<center><input name="uplo" type="submit" class=boton2 value="Back to UpLoad Files Form"></center>
<P align=center class=chica>~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~</P>
</td></tr></table></center></form></div>
<%= Pie(1)%>
<%
end if
Response.End
end if
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
If Session("DelFolder") = "True" then
	NomDCar = Session("DelFolName")
	Session("DelFolder") = ""
%>
<%= Encabezado("Delete Folder",0)%>
<div align="center">
<FORM name="NCarpeta" method="post" action="<%=RedirName%>?Bar=True">
<table align=center border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" width=400 bgcolor="#FFFFCC">
<tr>
<td align="center">
<P align=center class=normalB>Excluir pasta</P>
<P align=center class=normal>Você quer apagar <b>'<%= NomDCar%>'</b> e todo o conteúdo? <br> Se você quiser cancelar clique <a href="<%=RedirName%>">aqui</a><br></P>
<input type=submit class=boton2 name=Vol  value="Delete Folder">
<input name="NombreUser" type="hidden" value="True">
<input name="Vacio1" type="hidden" value="True">
<input type=hidden name=Modif  value="True">
<P align=center class=normal></P>
</td>
</table>
</form>
</div>
<%= Pie(1)%>
<%Response.End
end if
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
If Session("ModFolder") = "True" then
	NomDCar = Session("ModFolName")
	Session("ModFolder") = ""
%>
<%= Encabezado("Rename Folder",0)%>
<div align="center">
<FORM name="NCarpeta" method="post" action="<%=RedirName%>?Bar=True">
<table align=center border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" width=400 bgcolor="#FFFFCC">
<tr>
<td align="center">
<P align=center class=normalB>Modificar o nome da pasta</P>
<P align=center class=normal>Você quer mudar o nome da pasta <b>'<%= NomDCar%>'</b>
<br>a: <input type=text name="ModNomCar">
<br><a class=chica>Não use este: *,#,/, \, etc</a>
<br>Se você quiser cancelar clique<a href="<%=RedirName%>">aqui</a><br></P>
<input type=hidden name=CarVie  value="<%= NomDCar%>">
<input type=submit class=boton2 name=Vol  value="Change Folder Name">
<input name="NombreUser" type="hidden" value="True">
<input name="Vacio1" type="hidden" value="True">
<input type=hidden name=Modif  value="True">
<P align=center class=normal></P>
</td>
</table>
</form>
</div>
<%= Pie(1)%>
<%Response.End
end if
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
If Request.QueryString("Bar") = "True" then
Set Directorio = Fso.GetFolder(Session("Inter")).Files
select case Request.Form.Item(Request.Form.Count-3)
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Case "   Rename    "%>
<%= Encabezado("Rename Files",0)%>
<div align="center">
<FORM name="Files" method="post" action="<%=RedirName%>?Bar=True">
<P class=normalb>Rename Files.</P>
<table border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" width=420 bgcolor="#FFFFCC">	
<%Num = 0
for each DD in Directorio
if Request.Form(dd.name) = "ON" then
%>
<tr>
<td width="20"  align="center" class=normal> </td>
<td width="80"  align="center" class=normal>Rename:</td>
<td width="150" align="Left"   class=normal> <%= dd.Name%></td>
<td width="30"  align="center" class=normal>To:</td>
<td width="250" align="Left"   class=normal><input  name=text1<%= dd.name%> type="text"  id=text1<%= dd.name%>> .<%= fso.GetExtensionName(dd.name)%></td>
</tr>
<%
Num = Num  + 1
Session(Num) = dd.name
end if
next
Session("NumFiles") = Num
%>
</table><br>
<%If Num = 0 then%>
<p align=center class=error>Nenhum arquivo foi selecionado</p>
<%Else%>
<input name="DoRen" type="submit" class=boton2 value="Modify">
<input name="NombreUser" type="hidden" value="True">
<input name="Vacio1" type="hidden" value="True">
<input name="Modif" type="hidden" value="True">
<%end If%>
</FORM>
</div>
<%= Pie(1)%>
<%Response.End
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Case "Modify"
	Dim Cuantos(),Ident1,Ident3
	Ident1 = "No":Ident3 = "No"
	for a = 1 to cint(Request.Form.Count) - 4
		redim preserve Cuantos(a)
		Cuantos(a) = Request.Form(a).Item
		if Cuantos(a) = "" then Ident1 = "Si"
		if not ident1 = "Si" then
			for b = 1 to len(Cuantos(a))
				select case mid(Cuantos(a),b,1)
					case "\","/",":","?","<",">","|",chr(34)
						Ident3 = "Si"
				end select
			next
		end if
	next
	if Ident1 = "Si" then
		Encabezado " nome de arquivo válido",0
		Response.Write "<p align=center class=error>nome de arquivo válido. Tente com outro nome.</p>"
		Response.Write "<p align=center></p>"		
		Response.Write "<p align=center><INPUT type=button class=boton2 Value=Back onclick='window.history.back(-1);' id=button1 name=button1></p>"
		Pie(1)
	elseif Ident3 = "Si" then
		Encabezado "Not valid Character",0
		Response.Write "<p align=center class=error>carácter válido no nome do arquivo, você não pode usar: \/:*?" & chr(34) & "<>| Tente com outro nome.</p>"
		Response.Write "<p align=center></p>"		
		Response.Write "<p align=center><INPUT type=button class=boton2 Value=Back onclick='window.history.back(-1);' id=button1 name=button1></p>"
		Pie(1)
	else	
		for a = 1 to ubound(Cuantos)
			If Fso.FileExists(session("Inter") & Cuantos(a) & "." & fso.GetExtensionName(session(a))) = true then
				Encabezado "Nome inválido",0
				Response.Write "<p align=center class=error>Nome do arquivo em uso. Tente outro nome.</p>"
				Response.Write "<p align=center></p>"		
				Pie(1)			
				Response.End
			end if
			Set FILEX = fso.GetFile(session("Inter") & session(a))
			FILEX.name = Cuantos(a) & "." & fso.GetExtensionName(session(a))

		next
		Response.Redirect RedirName
		Response.End
	end if
	Response.End
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Case "      Delete       "%>
<%= Encabezado("Delete Files",0)%>
<div align="center">
<FORM name="Files" method="post" action"<%=RedirName%>?Bar=True">
<P class=normalb>Delete Files.</P>
<table border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" width=170 bgcolor="#FFFFCC">	
<%Num = 0
for each DD in Directorio
if Request.Form(dd.name) = "ON" then%>
<tr>
<td width="20"  align="center" class=normal> </td>
<td width="150" align="Left"   class=normal> <%= dd.Name%></td>
</tr>
<%
Num = Num  + 1
Session(Num) = dd.name
end if
next
Session("NumFiles") = Num
%>
</table><br>
<%If Num = 0 then%>
<p align=center class=error>Nenhum,arquivo selecionado </p>
<%Else%>
<input name="DoRen" type="submit" class=boton2 value="Delete">
<input name="NombreUser" type="hidden" value="True">
<input name="Vacio1" type="hidden" value="True">
<input name="Modif" type="hidden" value="True">
<%End If%>
</FORM>
</P>
</div>
<%= Pie(1)%>
<%Response.End
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Case "Delete"
	for a = 1 to cint(session("NumFiles"))
		fso.DeleteFile(session("inter") & session(a))
	next
	Session("ChkSpace") = "1"
	Response.Redirect RedirName
	Response.End
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Case "  New Folder   "%>
<%= Encabezado("New Folder",0)%>
<div align="center">
<FORM name="NCarpeta" method="post" action="<%=RedirName%>?Bar=True">
<table align=center border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" width=320 bgcolor="#FFFFCC">
<tr>
<td align="center">
<br>
<P align=center class=normal>Novo nome de pasta</P>
<P align=center><input type=text name=NomCarpeta size=15><br><a class=chica>Não use: *,#,/,\,etc</a></P>
<input type=submit class=boton2 name=CCa  value="Make Folder">
<input name="NombreUser" type="hidden" value="True">
<input name="Vacio1" type="hidden" value="True">
<input type=hidden name=Modif  value="True">
<P align=center class=normal></P>
</td>
</table>
</form>
</div>
<%= Pie(1)%>
<%Response.End
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Case "Make Folder"
Idet1 = "No"
NomCar = Request.Form("NomCarpeta")
If len(nomcar) = 0 then Idet1 = "Si"
If len(nomcar) > 24 then Idet1 = "Si"
for b = 1 to len(NomCar)
select case mid(NomCar,b,1)
case "\","/",":","?","<",">","|",chr(34):Idet1 = "Si"
end select
next
If Idet1 = "No" then
If (fso.FolderExists(Session("Inter") & NomCar)) Then 
	Idet1 = "Si"
else
	fso.CreateFolder Session("Inter") & NomCar
	Session("ChkSpace") = "1"
end if
end if
If Idet1 = "Si" then
%>
<%= Encabezado("Error",0)%>
<div align="center">
<FORM name="NCarpeta" method="post" action="<%=RedirName%>?Bar=True">
<table align=center border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" width=350 bgcolor="#FFFFCC">
<tr>
<td align="center">
<P align=center class=normalB>Erro</P>
<P align=center class=normal>O nome da pasta é inválido ou está em uso. <br> Tente outra.</P>
<input type=submit class=boton2 name=Vol  value="  New Folder   ">
<input name="NombreUser" type="hidden" value="True">
<input name="Vacio1" type="hidden" value="True">
<input type=hidden name=Modif  value="True">
<P align=center class=normal></P>
</td>
</table>
</form>
</div>
<%= Pie(1)%>
<%Else
Response.Redirect RedirName
End If
Response.End
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Case "    UpLoad    "
	Response.Redirect RedirName & "?UpFirst=True"
	Response.End
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Case "   Edit TXT   "
for each DD in Directorio
if Request.Form(dd.name) = "ON" then
	Archivo = dd.name
	exit for
end if
next
If not Archivo = "" then
select case lcase(fso.GetExtensionName(archivo))
case "htm","html","txt","asp","asa","php","int"
Set FileX = Fso.OpenTextFile(Session("Inter") & Archivo)
Texto = FileX.readall
set FileX = nothing
Session("Editar") = Archivo
%>
<%= Encabezado("Edit HTML",0)%>
<div align="center">
<FORM name="Editar" method="post" action="<%=RedirName%>?Bar=True">
<table align=center border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" height=460 width=620 bgcolor="#FFCC00">
<tr>
<td align="center">
<P align=center class=normal>File: <%= Archivo%>
<TEXTAREA name=txt style="HEIGHT: 410px; WIDTH: 570px"><%= Texto%></TEXTAREA>
<input type=submit class=boton2 name=gua value=" Save ">
<input type=hidden name=UserName  value="True">
<input name="Vacio1" type="hidden" value="True">
<input type=hidden name=Modif  value="True">
</P>
</td>
</table>
</form>
</div>
<%= Pie(1)%>
<%
Case else
%>
<%= Encabezado("Arquivo invalido",0)%>
<p align=center class=normalB>Not valid file</p>
<%= Pie(1)%>
<%
end select
else
%>
<%= Encabezado("Arquivo invalido",0)%>
<P align=center class=normal>Not valid file</P>
<%= Pie(1)%>
<%
end if
Response.End
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Case " Save "
	Set FFF = fso.OpenTextFile(Session("Inter") & Session("Editar"),2,false)
	FFF.write Request.Form("txt")
	FFF.Close
	Set FFF = nothing
	Session("ChkSpace") = "1"
	Response.Redirect RedirName
	Response.End
Case "  New TXT  "
Texto = Texto & "<HTML>" & chr(13)
Texto = Texto & "<HEAD>" & chr(13)
Texto = Texto & "<TITLE></TITLE>" & chr(13)
Texto = Texto & "</HEAD>" & chr(13)
Texto = Texto & "<BODY>" & chr(13)& chr(13)
Texto = Texto & "<P align=center><font size=4><b>Title</b></font></P>" & chr(13)
Texto = Texto & "<P align=center>SubTitle</P>" & chr(13)& chr(13)
Texto = Texto & "</BODY>" & chr(13)
Texto = Texto & "</HTML>"
%>
<%= Encabezado("New HTML File",0)%>
<div align="center">
<FORM name="Editar" method="post" action="<%=RedirName%>?Bar=True">
<table align=center border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" height=460 width=700 bgcolor="#FFFFCC">
<tr>
<td align="center">
<P align=center class=normal>File Name: 
<input type=text name=NomNewFile size=10 value="Sitio1"> 
<SELECT id=ExtName name=ExtName>
<OPTION value=".htm" selected>.htm</OPTION>
<OPTION value=".html">.html</OPTION>
<OPTION value=".txt">.txt</OPTION>
<OPTION value=".asp">.asp</OPTION>
<OPTION value=".asa">.asa</OPTION>
<OPTION value=".php">.php</OPTION>
<OPTION value=".int">.int</OPTION>
</SELECT>
<TEXTAREA name=txt style="HEIGHT: 410px; WIDTH: 660px"><%= Texto%></TEXTAREA>
<input type=submit class=boton2 name=Gnu value="Save New File">
<input name="NombreUser" type="hidden" value="True">
<input name="Vacio1" type="hidden" value="True">
<input type=hidden name=Modif  value="True">
</P>
</td>
</table>
</form>
</div>
<%= Pie(1)%>
<%Response.End
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Case "Save New File"
	NomFile = Request.Form("NomNewFile") & Request.Form("ExtName")
	Ident1 = "No"
	for b = 1 to len(NomFile)
		select case mid(NomFile,b,1)
			case "\","/",":","?","<",">","|",chr(34)
				Ident1 = "Si"
		end select
	next
	If Len(NomFile) > 24 then Ident1 = "Si"
	if Ident1 = "Si" then
		Encabezado "Nome de arquivo invalido",0
		Response.Write "<p align=center class=error>nome inválido <br> Tente outra.</p>"
		Response.Write "<p align=center></p>"		
		Response.Write "<p align=center><INPUT type=button class=boton2 Value=Back onclick='window.history.back(-1);' id=button1 name=button1></p>"
		Pie(1)
		Response.End
	end if
	If (fso.FileExists(Session("Inter") & NomFile)) Then
		Encabezado "Nome de arquivo invalido",0
		Response.Write "<p align=center class=error>O nome do arquivo está em uso '" & NomFile & "'<br> Tente outro.</p>"
		Response.Write "<p align=center></p>"		
		Response.Write "<p align=center><INPUT type=button class=boton2 Value=Back onclick='window.history.back(-1);' id=button1 name=button1></p>"
		Pie(1)
		Response.End
	End If	
	Set NewArchivo = fso.CreateTextFile(Session("Inter") & NomFile, True)
    NewArchivo.Write(Request.Form("txt"))
    NewArchivo.Close
	Session("ChkSpace") = "1"
	Response.Redirect RedirName
	Response.End
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Case "Delete Folder"
	fso.DeleteFolder(Session("Inter") & Session("DelFolName"))
	Session("ChkSpace") = "1"
	Response.Redirect RedirName
	Response.End
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
Case "Change Folder Name"
Idet1 = "No"
NomCar = Request.Form("ModNomCar")
CarVie = Request.Form("CarVie")
If len(nomcar) = 0 then Idet1 = "Si"
If len(nomcar) > 10 then Idet1 = "Si"
for b = 1 to len(NomCar)
select case mid(NomCar,b,1)
case "\","/",":","?","<",">","|",chr(34):Idet1 = "Si"
end select
next
If Idet1 = "No" then
If (fso.FolderExists(Session("Inter") & NomCar)) Then 
	Idet1 = "Si"
else
	Dim FolACam
	Set FolACam = fso.GetFolder(Session("Inter") & CarVie)
	FolACam.name = NomCar
end if
end if
If Idet1 = "Si" then
%>
<%= Encabezado("Error",0)%>
<div align="center">
<FORM name="NCarpeta" method="post" action="<%=RedirName%>?Bar=True">
<table align=center border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" width=350 bgcolor="#FFFFCC">
<tr>
<td align="center">
<P align=center class=normalB>Erro</P>
<P align=center class=normal>O nome da pasta é inválido ou está em uso. <br> tente outro.</P>
<br>Nome: <input type=text name="ModNomCar">
<br><a class=chica>Não use: *,#,/,\,etc</a>
<br>Se você quiser cancelar clique <a href="<%=RedirName%>">aqui</a><br></P>
<input type=hidden name=CarVie  value="<%= CarVie%>">
<input type=submit class=boton2 name=Vol  value="Change Folder Name">
<input name="NombreUser" type="hidden" value="True">
<input name="Vacio1" type="hidden" value="True">
<input type=hidden name=Modif  value="True">
<P align=center class=normal></P>
</td>
</table>
</form>
</div>
<%= Pie(1)%>
<%Else
Response.Redirect RedirName
End If
Response.End
Case "        Copy         "%>
<%= Encabezado("Copy Files",0)%>
<div align="center">
<FORM name="Files" method="post" action"<%=RedirName%>?Bar=True">
<P class=normalb>Copy Files.</P>
<table border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" width=170 bgcolor="#FFFFCC">	
<%Num = 0
for each DD in Directorio
if Request.Form(dd.name) = "ON" then%>
<tr>
<td width="20"  align="center" class=normal> </td>
<td width="150" align="Left"   class=normal> <%= dd.Name%></td>
</tr>
<%
Num = Num  + 1
Session(Num) = dd.name
end if
next
Session("NumFiles") = Num
%>
</table><br>
<%If Num = 0 then%>
<p align=center class=error>Nenhum arquivo foi selecionado</p>
<%Else%>
<p align=center class=normal>Copiar para a pasta: <%= Request.Form("ListFolders")%></p>
<input name="DoRem" type="checkbox" value="ON" checked>Substituir arquivo.</p>
<input name="DoRen" type="submit" class=boton2 value="Copy Files">
<input name="NombreUser" type="hidden" value="User">
<input name="Folder" type="hidden" value="<%= Request.Form("ListFolders")%>">
<input name="Modif" type="hidden" value="True">
<%End If%>
</FORM>
</P>
</div>
<%= Pie(1)%>
<%Response.End
Case "Copy Files"
	If not Request.Form("DoRem") = "ON" then
		for A = 1 to cint(Session("NumFiles"))
			if fso.FileExists (Request.Form("Folder") & Session(A)) = true then
				Encabezado "File Exist",0
				Response.Write "<p align=center class=error>OArquivo <b>'" & Session(A) & "'</b> já existem na pasta. <br> Se você quiser escrever sobre o arquivo selecione a opção.</p>"
				Response.Write "<p align=center></p>"		
				Pie(1)			
				Response.End			
			end if
		next
		for A = 1 to cint(Session("NumFiles"))
			fso.CopyFile Session("Inter") & Session(A), Request.Form("Folder"),false
		next
	else
		for A = 1 to cint(Session("NumFiles"))
			fso.CopyFile Session("Inter") & Session(A), Request.Form("Folder"),true
		next
	end if
	Session("ChkSpace") = "1"
	Response.Redirect RedirName & "?SubFolder=True&loc=" & Request.Form("Folder")
	Response.End
Case "      Mover      "%>
<%= Encabezado("MOve Files",0)%>
<div align="center">
<FORM name="Files" method="post" action"<%=RedirName%>?Bar=True">
<P class=normalb>Move Files.</P>
<table border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" width=170 bgcolor="#FFFFCC">	
<%Num = 0
for each DD in Directorio
if Request.Form(dd.name) = "ON" then%>
<tr>
<td width="20"  align="center" class=normal> </td>
<td width="150" align="Left"   class=normal> <%= dd.Name%></td>
</tr>
<%
Num = Num  + 1
Session(Num) = dd.name
end if
next
Session("NumFiles") = Num
%>
</table><br>
<%If Num = 0 then%>
<p align=center class=error>Nenhum arquivo foi selecionado</p>
<%Else%>
<p align=center class=normal>Mover para pasta: <%= Request.Form("ListFolders")%></p>
<input name="DoRen" type="submit" class=boton2 value="Move Files">
<input name="NombreUser" type="hidden" value="User">
<input name="Folder" type="hidden" value="<%= Request.Form("ListFolders")%>">
<input name="Modif" type="hidden" value="True">
<%End If%>
</FORM>
</P>
</div>
<%= Pie(1)%>
<%Response.End
Case "Move Files"
	for A = 1 to cint(Session("NumFiles"))
		if fso.FileExists (Request.Form("Folder") & Session(A)) = true then
			Encabezado "File Exist",0
			Response.Write "<p align=center class=error>O Arquivo <b> ' "& Session (A) &"' </ b> já existe no foder. <br> Se você quiser mover o arquivo primeiro apagar da pasta original.</p>"
			Response.Write "<p align=center></p>"		
			Pie(1)			
			Response.End			
		end if
	next
	for A = 1 to cint(Session("NumFiles"))
		fso.MoveFile Session("Inter") & Session(A), Request.Form("Folder")
	next
	Session("ChkSpace") = "1"
	Response.Redirect RedirName & "?SubFolder=True&loc=" & Request.Form("Folder")
	Response.End
end select
end if
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
'~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~¤~
If Session("ChkSpace") = 1 then
	Session("ChkSpace") = 0
	If not Session("NumFol") = 0 then
		for A = 1 to cint(Session("NumFol"))
			Session("Fol" & cstr(A)) = ""
		next
	end if
	Session("Espacio") = SpaceKB(Session("FolderPrim"))
end if
%>
<%= Encabezado("Web Admin",0)%>
<FORM name="Files" method="post" action="<%=RedirName%>?Bar=True">
<div align="center"><center><table border="1" bordercolor="#808080" cellspacing="0" cellpadding="0" width=700 bgcolor=#FFFFFF><tr><td>
<TABLE align=center border=0 borderColor="#808080" cellPadding=0 cellSpacing=0 width=680>
<TR><TD width=680>
<font class=normalN>Folder</font> <font class=normal><%= Session("Inter")%></font>
<%If not lcase(Session("FolderPrim")) = lcase(Session("Inter")) then
RutaBack = left(Session("Inter"),instrrev(Session("Inter"),"\",len(Session("Inter"))-1))%>
    <a class=normal href="<%=RedirName%>?UpFolder=True&Ruta=<%= RutaBack%>" title="Up one level">Ir a Directorio Superior</a>
<%End If%>
</TD></TR></TABLE>
<%
Set Fol = Fso.GetFolder(Session("Inter")).SubFolders
Set Directorio = Fso.GetFolder(Session("Inter")).Files%>
<div align="center"><table border="1" bordercolor="#000000" cellspacing="0" cellpadding="0" width=680 bgcolor="#FFFFCC">
<tr>
<td width="20"  align="middle" bgcolor="#c0c0c0" class=normalb>X</td>
<td width="150" align="middle" bgcolor="#c0c0c0" class=normalb> Name</td>
<td width="70" align="middle" bgcolor="#c0c0c0" class=normalb> View</td>
<td width="100" align="middle" bgcolor="#c0c0c0" class=normalb> Size</td>
<td width="190" align="middle" bgcolor="#c0c0c0" class=normalb> Type</td>
<td width="150" align="middle" bgcolor="#c0c0c0" class=normalb> Modify</td>
</tr>
<%if not Fol.count = 0 then%>
<%for each Fld in Fol%>
<tr>
<td width="20" align="middle"  class=normalN bgcolor="#CCFFCC">¤</td>
<td width="150" align="left"   class=normal bgcolor="#CCFFCC"> <%= Fld.name%></td>
<td width="70" align="middle"  class=normal bgcolor="#CCFFCC"><A href="<%=RedirName%>?SubFolder=True&loc=<%= Session("Inter") & Fld.name%>\" title="Clique aqui para entrar na pasta '<%=Fld.name%>'">Enter</a></td>
<td width="100" align="middle" class=normal bgcolor="#CCFFCC"><A href="<%=RedirName%>?DelFolder=True&Nombre=<%= Fld.name%>" title="Click to delete the folder '<%=Fld.name%>'">Delete</a>-<A href="<%=RedirName%>?ModFolder=True&Nombre=<%= Fld.name%>" title="Clique para renomear a pasta '<%=Fld.name%>'">Modif</a></td>
<td width="190" align="left"   class=chica  bgcolor="#CCFFCC"> Folder.</td>
<td width="150" align="left"   class=chica  bgcolor="#CCFFCC"> </td>
</tr>
<% next %>
<%End if%>
<% FN = 0:SN = 0
for each DD in Directorio 
FN = FN + 1:SN = SN + cdbl(dd.size)%>
<tr>
<%If lcase(Session("Inter") & dd.name) = lcase(Session("FolderPrim") & RedirName) then%>
<td width="20"  align="middle" class=normal><input type="checkbox" name="<%= dd.name%>" value="ON"></td>
<td width="150" align="left"   class=normalnroja> <%= dd.name%></td>
<td width="70" align="middle" class=normal> Current</td>
<%Num = formatnumber((cdbl(dd.size)/1024),0):If Num < 1 then Num = 1%>
<td width="100" align="right"  class=normal> <%= Num%> KB</td>
<td width="190" align="left"   class=chica> <%= dd.type%></td>
<td width="150" align="left"   class=chica> <%= dd.datelastmodified%></td>
<%else%>
<td width="20"  align="middle" class=normal><input type="checkbox" name="<%= dd.name%>" value="ON"></td>
<td width="150" align="left"   class=normal> <%= dd.name%></td>
<td width="70" align="middle" class=normal> <A href="<%= DirLoc%><%= dd.name%>" title="Click to see '<%= dd.name%>'">Preview</a></td>
<%Num = formatnumber((cdbl(dd.size)/1024),0):If Num < 1 then Num = 1%>
<td width="100" align="right"  class=normal> <%= Num%> KB</td>
<td width="190" align="left"   class=chica> <%= dd.type%></td>
<td width="150" align="left"   class=chica> <%= dd.datelastmodified%></td>
<%End If%>
</tr>
<% next %>
<tr>
<td width="20" align="middle" bgcolor="#c0c0c0" class=normalb>X</td>
<td width="150" align="left" bgcolor="#c0c0c0" class=normalb> <%= FN%> arquivos</td>
<td width="70" align="left" bgcolor="#c0c0c0" class=normal> </A></td>
<%Num = formatnumber(SN/1024,0):If num < 1 then Num = 1%>
<td width="100" align="right" bgcolor="#c0c0c0" class=normalb> <%= Num%> KB</td>
<td width="190" align="left" bgcolor="#c0c0c0" class=chica> </td>
<td width="150" align="left" bgcolor="#c0c0c0" class=chica> </td>
</tr>
</table></div>
<center>
<TABLE align=center border=1 bgColor="#FFFFFF" borderColor="#808080" cellPadding=0 cellSpacing=0 width=680>
<tr>
<td width=113 align=center><input name="Ren"   type="submit" class=boton1 title="Rename selected files" value="   Rename    "></td>
<td width=113 align=center><input name="Del"   type="submit" class=boton1 title="Delete selected files"    value="      Delete       "></td>
<td width=114 align=center><input name="Nca"   type="submit" class=boton1 title="Create new folder"               value="  New Folder   "></td>
<td width=113 align=center><input name="Subir" type="submit" class=boton1 title="UpLoad files"          value="    UpLoad    "></td>
<td width=114 align=center><input name="Mov"   type="submit" class=boton1 title="Edit selected files"    value="   Edit TXT   "></td>
<td width=113 align=center><input name="Nar"   type="submit" class=boton1 title="Create new ASCII file"        value="  New TXT  "></td>
</tr>
<tr>
<td width=227 align=center bgColor="#CCFFCC" colspan=2><font class=normalN><%= formatnumber(Session("Espacio")/1024,0)%> KB</font> <font class=chica>in Web Admin.</font></td>
<td width=113 align=center><input name="Copiar" type="submit" class=boton1 title="Copy selected files" value="        Copy         "></td>
<td width=114 align=center><input name="Mover"  type="submit" class=boton1 title="Move selected files"  value="      Mover      "></td>
<td width=226 align=center colspan=2>
<SELECT id=ListFolders name=ListFolders style="WIDTH: 205px;background-Color: #CCFFCC;Cursor: hand;">
<%For A = 1 to cint(Session("NumFol"))%>
<OPTION value="<%= lcase(Session("Fol" & cstr(a)))%>">\<%= replace(lcase(Session("Fol" & cstr(a))),lcase(Session("FolderPrim")),"",1)%></OPTION>
<%next%>
</SELECT>
</td>
</tr>
</table>
<input type=hidden name=Valor Value=1>
<TABLE align=center border=0 borderColor="#808080" cellPadding=0 cellSpacing=0 width=680>
<TR>
<TD width=680><P align=left> </P></TD>
</TR>
</TABLE>
<input name="Modif" type="hidden" value="True">
</center></FORM>
</td></tr></table></center></div>
<br>
</center>
<%= Pie(0)%>
<%'¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤%>

Compartilhar este post

Link para o post
Compartilhar em outros sites
Ir para a lista de tópicos ASP Clássico
×

Informação importante

Ao usar o fórum, você concorda com nossos Termos e condições.

  Aceito