[Resolvido] transferir arquivos do servidor

[xanburzum 169]

Este script mostra como usar XMLHTTP para transferir um arquivo (ou lista de arquivos) de um servidor remoto (ou domínio) para o servidor que esse script está sendo executado. Este exemplo também verifica se os arquivos existem. Se isso acontecer, ele apaga o arquivo existente em seguida, cria o novo arquivo. Caso contrário, ele não criará o novo arquivo.

 

<%



  'Cria xmlHTTP Object

   Set xmlHTTP = CreateObject("MSXML2.ServerXMLHTTP")



    'Gravar na pasta no servidor

    SaveToFldr = Server.MapPath("SomeFolder")



    'Criar uma lista de arquivos para recuperar

    TheURLS = "http://www.Este domínio.com/File1.jpg|" & _

              "http://www.Este domínio.com/File2.xls|" & _

              "http://www.outro domínio.com/File3.pdf"



 'Criar  Lista Array File

    UrlArr = Split(TheURLs,"|")



    'Percorrer File List

    For x = 0 To UBound(UrlArr)



       'Salvar Como Nome do arquivo

       SaveAsFile = SaveToFldr & "/" Right(UrlArr(x),Len(UrlArr(x))-InstrRev(UrlArr(x),"/"))



       'pega File

       xmlHTTP.open "GET", UrlArr(x), false

       'envia Request

       xmlHTTP.send()

       'Verifique para ver se o arquivo estiver disponível

       If xmlHttp.Status = "200" AND xmlHttp.Status <> "404" then



         'Criar objeto Datastream para salvar o arquivo
          set DataStream = CreateObject("ADODB.Stream")

          'Open Datastream

          DataStream.Open

          'Definir tipo para binary

          DataStream.Type = 1

          'Criar Datastream bianry do arquivo

          DataStream.Write xmlHTTP.ResponseBody

          DataStream.Position = 0



         'Defina o File System Object, para que possamos verificar para ver se ela já existe.

  	  set FSO = Createobject("Scripting.FileSystemObject")

  	 'Se o arquivo já existe, excluí-lo

         if FSO.FileExists(SaveAsFile) then

            Fso.DeleteFile SaveAsFile

         End If

	 set FSO = Nothing



         'Envie o arquivo para o local do servidor

          DataStream.SaveToFile SaveAsFile

          'Close Datastream

          DataStream.Close

          'Delete objeto Datastream 

          set DataStream = Nothing



       End If





    Next



    'Delete xmlHTTP Object

    Set xmlHTTP = Nothing



     %>