Ir para conteúdo

POWERED BY:

Arquivado

Este tópico foi arquivado e está fechado para novas respostas.

xanburzum

[Resolvido] Criar tabela

Por , em ASP Clássico

Recommended Posts

xanburzum    169

xanburzum
Postado

Este é um procedimento que pode ser usado cada vez que você precisa para criar uma tabela na web, uma vez que então poderia ser utilizado sempre que necessário para construir uma tabela na página web.

 

<HTML>
<HEAD>
<TITLE>Criar tabela de teste ASP </TITLE>
</HEAD>
<BODY>
<P><FONT size=5><STRONG>Criar tabela</STRONG>
<%
'#######################################################
'#
'# Procedure para Criar tabela de teste ASP
'#
'#######################################################
Sub MakeTable(p_Source, _
	          p_String)
	'===================================================			  
	' Declarar variáveis
	'===================================================
	Dim oConn
	Dim oRSmt
	'===================================================
	' Abrir connection
	'===================================================
	Set oConn=Server.CreateObject("ADODB.connection")
	oConn.Open p_Source
	'===================================================
	' linhas de registros
	'===================================================
	Set oRSmt = Server.CreateObject("ADODB.recordset")
	oRSmt.Open p_String, oConn
	'===================================================
	' Mover para o primeiro registro
	'===================================================
	oRSmt.MoveFirst
	'===================================================
	' Criar tabela
	'===================================================
	Response.Write "<TABLE BORDER=1 NOWRAP BORDERCOLOR=whiteBGCOLOR=black><TR>"
	For Each Field in oRSmt.Fields
		'-----------------------------------------------
		' Adicionar nomes de campo
		'-----------------------------------------------
		Response.Write "<TH NOWRAP BGCOLOR=navy><FONT COLOR=white>" & Field.Name & "</TH>"
	Next
	Do While Not oRSmt.EOF
		Response.Write "<TR>"
		For Each objField in oRSmt.Fields
			'-------------------------------------------
			'Adicionar os valores de campo até à tabela
			'-------------------------------------------
			Response.Write "<TD NOWRAP BGCOLOR=silver><FONT COLOR=navy>" & objField.value & " </TD>"
		Next
		oRSmt.MoveNext
		Response.Write"</TR>"
	Loop
	Response.Write "</TR></TABLE>"
	oRSmt.Close
	'===================================================
	' Clean-up
	'===================================================
	Set oRSmt = nothing
End Sub								
	
'===================================================
' Construir sintaxe SELECT
'===================================================
l_select = " SELECT Account.AcctNum,"
l_select = l_select & " Account.CompanyName,"
l_select = l_select & " Account.BillingAddress,"
l_select = l_select & " Account.City,"
l_select = l_select & " Account.StateOrProvince,"
l_select = l_select & " Account.PostalCode"
l_select = l_select & " FROM Account"
'===================================================
' Chamada de procedimento para fazer tabela
'===================================================
Call MakeTable("driver={SQL Server};UID=YourUserID;PWD=YourPassword;DATABASE=SQLServerDatabase;SERVER=YourServerName", _
			   l_select)

%>
<P> </P></FONT>

</BODY>
</HTML>

Compartilhar este post

Link para o post
Compartilhar em outros sites
Ir para a lista de tópicos ASP Clássico
×

Informação importante

Ao usar o fórum, você concorda com nossos Termos e condições.

  Aceito