CDONTS para CDOSYS

[Fabiano Magno Pechibella 0]

Fala galera, to precisando de um help sobre o envio de email. Trabalho mais com Coldfusion e peguei esta empreitada em ASP, o site estava hospedado em outra servidor e a funcao CDONTS/ASPMAIL/ funcionava perfeitamente, mais como a empresa decidiu mudar para a melhoria de suporte e navegabilidade do site, tenho que adaptar algumas coisas e uma delas é a função de CDONTS para CDOSYS, vou postar o codigo abaixo para ter idéia por onde começar.

 

Function enviar(de, para, assunto, mensagem)
  		Select Case loja("componente_email")
		Case "ASPMAIL"
		On Error Resume Next
			Set objEmail = Server.CreateObject("SMTPsvg.Mailer")
				objEmail.FromName = de
				objEmail.FromAddress = de
				objEmail.RemoteHost = loja("host_email")
				objEmail.AddRecipient "", para
				objEmail.Subject = assunto
				objEmail.ContentType = "text/html"
				objEmail.BodyText = mensagem	    
				objEmail.SendMail
			Set objEmail = Nothing
		Case "ASPEMAIL"
		On Error Resume Next
			Set objEmail = Server.CreateObject("Persits.MailSender")
				objEmail.Host = loja("host_email")
				objEmail.From = de
				objEmail.FromName = de
				objEmail.AddAddress para
				objEmail.Subject = assunto
				objEmail.isHTML = True
				objEmail.Body = Mensagem	 	
				objEmail.Send
			Set objEmail = Nothing
		Case "ASPQMAIL"
		On Error Resume Next
			Set objEmail = Server.CreateObject("SMTPsvg.Mailer")
				objEmail.QMessage = 1
				objEmail.FromName = de
				objEmail.FromAddress = de
				objEmail.RemoteHost = loja("host_email")
				objEmail.AddRecipient "", para
				objEmail.Subject = assunto
				objEmail.BodyText = mensagem
				objEmail.SendMail
			Set objEmail = Nothing
		Case "CDONTS"
		On Error Resume Next
			Set objEmail = Server.CreateObject("CDONTS.NewMail")
				objEmail.to = para
				objEmail.from = de
				objEmail.subject = assunto
				objEmail.Importance = 1
				objEmail.BodyFormat = 0
				objEmail.MailFormat = 0
				objEmail.body = mensagem		
				objEmail.send
			Set objEmail = Nothing
		End Select
end function

Vlw galera....[ ]'s - :(

[hargon 64]

Qual a sua dúvida realmente? Não encontrou nada sobre CDOSYS?

 

Dependendo, dê uma pesquisada aqui no Fórum, pois existem vários tópicos explicando como utilizar o CDOSYS, entre eles, como migrar do CDONTS para o CDOSYS.

 

Qualquer outra dúvida, poste aqui.

[xanburzum 169]

olha estes exemplos:

 

Examples using CDOSYS

O envio de um texto de e-mail:

 

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="mymail@mydomain.com"
myMail.To="someone@somedomain.com"
myMail.TextBody="This is a message."
myMail.Send
set myMail=nothing
%>

O envio de um texto de e-mail com Bcc e os campos CC:

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="mymail@mydomain.com"
myMail.To="someone@somedomain.com"
myMail.Bcc="someoneelse@somedomain.com"
myMail.Cc="someoneelse2@somedomain.com"
myMail.TextBody="This is a message."
myMail.Send
set myMail=nothing
%>

Enviando uma mensagem de e-mail HTML:

 

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="mymail@mydomain.com"
myMail.To="someone@somedomain.com"
myMail.HTMLBody = "<h1>This is a message.</h1>"
myMail.Send
set myMail=nothing
%>

Enviando um e-mail HTML que envia uma página de um site:

 

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="mymail@mydomain.com"
myMail.To="someone@somedomain.com"
myMail.CreateMHTMLBody "http://www.w3schools.com/asp/"
myMail.Send
set myMail=nothing
%>

Enviando um e-mail HTML que envia uma página de um arquivo no seu computador:

 

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="mymail@mydomain.com"
myMail.To="someone@somedomain.com"
myMail.CreateMHTMLBody "file://c:/mydocuments/test.htm"
myMail.Send
set myMail=nothing
%>

Enviando um email com um anexo de texto:

 

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="mymail@mydomain.com"
myMail.To="someone@somedomain.com"
myMail.TextBody="This is a message."
myMail.AddAttachment "c:\mydocuments\test.txt"
myMail.Send
set myMail=nothing
%>

Enviando um e-mail de texto usando um servidor remoto:

 

<%
Set myMail=CreateObject("CDO.Message")
myMail.Subject="Sending email with CDO"
myMail.From="mymail@mydomain.com"
myMail.To="someone@somedomain.com"
myMail.TextBody="This is a message."
myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing")=2
'Name or IP of remote SMTP server
myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver")="smtp.server.com"
'Server port
myMail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport")=25 
myMail.Configuration.Fields.Update
myMail.Send
set myMail=nothing
%>