Abrir Smarth Phone

Web 1 · Setembro 21, 2010

Pessoal sei que nao é a sessão correta, mas gostaria de saber como é o processo de abrir determinado endereço somente nos smarth phones exemplo

se eu acessar via IPHONE o www.itau.com.br ele automaticamente redireciona para m.itau.com.br

Como proceder desta forma? alguem ai sabe?

xanburzum · Setembro 22, 2010

você utilizar WAP para programacao movel, e você pode ver daonde esta acessando, o tipo do browser

<%
     '******************************************************************************
     ' HTML/XHTML MP/WML Mobile Redirect
     'Isto permitirá que você só precisa para publicitar o seu URL principal. 
      'A razão para ter todos os três tipos é o de reduzir o risco de alguém 
      'Não ser capaz de acessar seu site com qualquer tipo de dispositivo móvel. 
      'Você deve incluir esse script no topo de cada uma de suas páginas em cada tipo, 
      'Só no caso de alguém não acessa seu site através da página padrão. 
      'Dependendo do dispositivo que irão receber a versão correcta do seu site. 
     '
     '******************************************************************************


     'listade agentes móveis 
     Dim AgentArr
     AgentArr = Array("midp", "j2me", "avantg", "docomo", "novarra", "palmos", _
                      "palmsource", "240x320", "opwv", "chtml", "pda", "windows\ ce", _
                      "mmp\/", "blackberry", "mib\/", "symbian", "wireless", "nokia", _
                      "hand", "mobi", "phone", "cdm", "up\.b", "audio", "sie\-", "sec\-", _
                      "samsung", "htc", "mot\-", "mitsu", "sagem", "sony", "alcatel", "lg", _
                      "erics", "vx", "nec", "philips", "mmm", "xx", "panasonic", "sharp", "wap", _
                      "sch", "rover", "pocket", "benq", "java", "pt", "pg", "vox", "amoi", _
                      "bird", "compal", "kg", "voda", "sany", "kdd", "dbt", "sendo", _
                      "sgh", "gradi", "jb", "\d\d\di", "moto")
     
     HTTP_ACCEPT = LCase(Request.ServerVariables("HTTP_ACCEPT"))
     HTTP_USER_AGENT = LCase(Request.ServerVariables("HTTP_USER_AGENT"))
     
     WMLBrowser = False
     XHTMLMPBrowser = False
     HTMLBrowser = False

     ThisSite = LCase("http://" & Request.ServerVariables("SERVER_NAME"))
     WMLSite = "http://wap.seu_site.com"
     XHTMLMPSite = "http://mobile.seu_site.com"
     HTMLSite = "http://www.seu_site.com"

     'Check WML
     If Instr(1,HTTP_ACCEPT,"vnd.wap.wml") > 0 Then
       WMLBrowser = True
     End If

     'Check XHTML Mobile 
     If Instr(1,HTTP_ACCEPT,"vnd.wap.xhtml") > 0 Then
       XHTMLMPBrowser = True
     End If

     'Check normal HTML
     If Instr(1,HTTP_ACCEPT,"*/*") > 0 Then
       HTMLBrowser = True
     End If

     ' Enviar para XHTML Mobile se WML e XHTML Mobile
     If WMLBrowser = True AND XHTMLMPBrowser = True Then
        WMLBrowser = False
     End If

     If HTMLBrowser = True Then
        For x = 0 To Ubound(AgentArr)
        'Verificar XHTML MP browser aceitar normal Texto / HTML
           If Instr(1,HTTP_USER_AGENT,AgentArr(x)) > 0 Then
              HTMLBrowser = False
              XHTMLMPBrowser = True
           End If
        Next
        'Trate iPhone como navegador regular 
        If Instr(1,HTTP_USER_AGENT,"iphone") > 0 Then
           XHTMLMPBrowser = False
           HTMLBrowser = True
        End If
     End If

     'Enviar para local adequado 
    'Comparar com o endereço atual para evitar looping
     If WMLBrowser = True AND ThisSite <> WMLSite Then
        Response.Redirect WMLSite
     ElseIf XHTMLMPBrowser = True AND ThisSite <> XHTMLMPSite Then
        Response.Redirect XHTMLMPSite
     ElseIf HTMLBrowser = True AND ThisSite <> HTMLSite Then
        Response.Redirect HTMLSite
     End If

  %>

exemplo de WAP

<%@ Language=VBScript %>
<% 
'send the right MIME type
Response.ContentType = "text/vnd.wap.wml" 
%>
<%
if NOT isempty(Request.Form("OK")) then
	Dim wmlmail
	Set wmlmail = CreateObject("CDONTS.Newmail")
	wmlmail.TO = "" & Request.Form("toadd") & ""
	wmlmail.From = "" & Request.Form("fromadd") & ""
	wmlmail.Subject = "" & Request.Form("subject") & ""
	wmlmail.MailFormat = cdoMailFormatMime
	'cdobodyformattext for text format
	wmlmail.BodyFormat = cdoBodyFormatHTML
	wmlmail.Body = "" & Request.Form("body") & ""
	wmlmail.send
	set wmlmail = Nothing
	msg = "Email sent"
end if
%>
<?xml version="1.0"?>
<!-- Code is copyright of xh. Please do not delete this away -->
<!DOCTYPE wml PUBLIC "-//WAPFORUM//DTD WML 1.1//EN" "http://www.wapforum.org/DTD/wml_1.1.xml">
<wml>
 <template>
 <do type="prev">
<prev/>
 </do>
 </template>
<card id="InfoCard" title="xh Wap Email Service">
 <p align="center">
 <big>Wap Email Service</big><br/>
 <% response.write msg %><br/>
 <fieldset title="Email">
To : <input type="text" name= "toadd" maxlength="32"/>
From : <input type="text" name= "fromadd" maxlength="32"/>
Subject : <input type="text" name= "subject" maxlength="32"/>
Body : <input type="text" name= "body" maxlength="32"/>
 </fieldset>
 <do type="accept" label="Send" name="OK">
<go href="wmlemail.asp" method="post" >
 <postfield name="toadd" value="$toadd" />
 <postfield name="fromadd" value="$fromadd" />
 <postfield name="subject" value="$subject" />
 <postfield name="body" value="$body" />
 <postfield name="OK" value="OK" />
</go>
 </do>
</p>
</card>
</wml>

Web 1 · Setembro 22, 2010

Interessante!

Eu coloco esses codigos acima no inicio das minhas paginas?

SOu usuario iniciante e só preciso saber como migrar o internauta para o endereço certo dependendo de onde ele vem!

Web 1 · Setembro 22, 2010

Vejam esse exemplo

www.globo.com

m.globo.com

Vi alguns codigo simples que fazem esse processo, mas nao sei o caminho!

Vinicius Ianni · Setembro 22, 2010

Normalmente usa-se o user agent para saber qual o navegador do usuário e fazer as transições / adaptações necessárias.

Dê uma pesquisada em Browser capabitlies, aqui tem alguma coisa: http://www.w3schools.com/asp/asp_browser.asp

Idenditificando o navegador do usuário, redireciona ele para a pagina correta que no seu caso seria a pagina adaptada para ser vista em celulares.

Alguns sites redirecionam para um outro endereço, que é o caso do globo.com que você cita.

Web 1 · Setembro 23, 2010

Vinicius Ianni Muito boa sua indicação fiz alguns testes mas sem sucesso! na verdade ele mostra as funcoçes do navegador, mas ainda não é bem o que procuro.

xanburzum · Setembro 23, 2010

'listade agentes móveis

Dim AgentArr

AgentArr = Array("midp", "j2me", "avantg", "docomo", "novarra", "palmos", _

"palmsource", "240x320", "opwv", "chtml", "pda", "windows\ ce", _

"mmp\/", "blackberry", "mib\/", "symbian", "wireless", "nokia", _

"hand", "mobi", "phone", "cdm", "up\.b", "audio", "sie\-", "sec\-", _

"samsung", "htc", "mot\-", "mitsu", "sagem", "sony", "alcatel", "lg", _

"erics", "vx", "nec", "philips", "mmm", "xx", "panasonic", "sharp", "wap", _

"sch", "rover", "pocket", "benq", "java", "pt", "pg", "vox", "amoi", _

"bird", "compal", "kg", "voda", "sany", "kdd", "dbt", "sendo", _

"sgh", "gradi", "jb", "\d\d\di", "moto")

HTTP_ACCEPT = LCase(Request.ServerVariables("HTTP_ACCEPT"))

HTTP_USER_AGENT = LCase(Request.ServerVariables("HTTP_USER_AGENT"))

WMLBrowser = False

XHTMLMPBrowser = False

HTMLBrowser = False

ThisSite = LCase("http://" & Request.ServerVariables("SERVER_NAME"))

WMLSite = "http://wap.seu_site.com"

XHTMLMPSite = "http://mobile.seu_site.com"

HTMLSite = "http://www.seu_site.com"

Web 1 · Setembro 29, 2010

Ok! estou usando o codigo abaixo que ação uso agora pra redirecionar para determinado endereço?

xanburzum · Setembro 29, 2010

recupera o HTTP_USER_AGENT

HTTP_USER_AGENT = LCase(Request.ServerVariables("HTTP_USER_AGENT"))
     
     WMLBrowser = False
     XHTMLMPBrowser = False
     HTMLBrowser = False

e depois redireciona conforme o tipo

ThisSite = LCase("http://" & Request.ServerVariables("SERVER_NAME"))
     WMLSite = "http://wap.seu_site.com"
     XHTMLMPSite = "http://mobile.seu_site.com"
     HTMLSite = "http://www.seu_site.com"

Web 1 · Setembro 30, 2010

Usaria desta forma?

<%

'listade agentes móveis