SiteMap em asp

[Marcos Coelho2 2]

Alguem sabe de algum sitemap para asp que minhas urls e coloca corretamente?

ja usei em php mas em asp nao conheco.

[xanburzum 169]

olha este exemplo

<%

' sitemap_gen.asp

' Um script simples para produzir automaticamente sitemaps para um servidor web, no Google Sitemap Protocolo (SPG)

 

‘modificar esta opção para alterar o site, diretório virtual e o diretório físico

session("server")="http://www.sweudominio.net"

vDir = "/"

phisicalDir="C:\Inetpub\wwwroot\"

 

utcOffset=1

 

 

set objfso = CreateObject("Scripting.FileSystemObject")

root = Server.MapPath(vDir)

 

response.ContentType = "text/xml"

response.write "<?xml version='1.0' encoding='UTF-8'?>"

response.write "<!-- generator='http://www.teste.net/xan/sitemap_gen'-->"

response.write "<urlset xmlns='http://www.google.com/schemas/sitemap/0.84'>"

 

Set objFolder = objFSO.GetFolder(root)

'response.write getfilelink(objFolder.Path,objFolder.dateLastModified)

Set colFiles = objFolder.Files

For Each objFile In colFiles

response.write getfilelink(objFile.Path,objfile.dateLastModified)

Next

ShowSubFolders(objFolder)

 

response.write "</urlset>"

set fso = nothing

 

 

Sub ShowSubFolders(objFolder)

Set colFolders = objFolder.SubFolders

For Each objSubFolder In colFolders

if folderpermission(objSubFolder.Path) then

response.write getfilelink(objSubFolder.Path,objSubFolder.dateLastModified)

Set colFiles = objSubFolder.Files

For Each objFile In colFiles

response.write getfilelink(objFile.Path,objFile.dateLastModified)

Next

ShowSubFolders(objSubFolder)

end if

Next

End Sub

 

 

Function getfilelink(file,data)

file=replace(file,phisicalDir,"")

file=replace(file,"\","/")

If FileExtensionIsBad(file) then Exit Function

If FileNameIsBad(file) then Exit Function

filelmdate=iso8601date(data,utcOffset)

 

getfilelink = "<url><loc>"&server.htmlencode(session("server")&file)&"</loc><lastmod>"&filelmdate&"</lastmod><priority>1.0</priority></url>"

session("URLS")=session("URLS")+1

Response.Flush

End Function

 

 

Function Folderpermission(pathName)

‘modificar esse caminho para excluir

PathExclusion=Array("\temp","\_vti_cnf","\_vti_pvt","\_vti_log","\cgi-bin")

Folderpermission =True

for each PathExcluded in PathExclusion

if instr(ucase(pathName),ucase(PathExcluded))>0 then

Folderpermission = False

exit for

end if

next

End Function

 

 

Function FileExtensionIsBad(sFileName)

Dim sFileExtension, bFileExtensionIsValid, sFileExt

'http://www.googleguide.com/file_type.html

Extensions = Array("png","gif","jpg","zip","pdf","ps","html","htm","asp","wk1","wk2","wk3","wk4","wk5","wki","wks","wku","lwp","mw","xls","ppt","doc","wks","wps","wdb","wri","rtf","ans","txt")

 

if len(trim(sFileName)) = 0 then

FileExtensionIsBad = true

Exit Function

end if

 

sFileExtension = right(sFileName, len(sFileName) - instrrev(sFileName, "."))

bFileExtensionIsValid = false 'assume extension is bad

for each sFileExt in extensions

if ucase(sFileExt) = ucase(sFileExtension) then

bFileExtensionIsValid = True

exit for

end if

next

FileExtensionIsBad = not bFileExtensionIsValid

End Function

 

Function FileNameIsBad(sFileName)

if len(trim(sFileName)) = 0 then

FileNameIsBad = true

Exit Function

end if

Filename = Array("/alive.asp","/404.asp","/500.asp","/sitemap_gen.asp")

FileNameNumber = ubound(Filename)

for i=0 to FileNameNumber

if Filename(i) = sFileName then

FileNameIsBad = True

end if

next

End Function

 

Function iso8601date(dLocal,utcOffset)

Dim d

' converter a hora local em UTC

d = DateAdd("H",-1 * utcOffset,dLocal)

 

' compõem a data

iso8601date = Year(d) & "-" & Right("0" & Month(d),2) & "-" & Right("0" & Day(d),2) & "T" & _

Right("0" & Hour(d),2) & ":" & Right("0" & Minute(d),2) & ":" & Right("0" & Second(d),2) & "Z"

End Function

%>

 

:

[Marcos Coelho2 2]

to querendo um que busque todas minhas urls pq eu utilizo um unico arquivo para abrir varias postagens

tipo como se faz nesse site

http://www.xml-sitemaps.com/

 

so que quero que pegue todas as urls

 

quero que me ajudem a encontrar um site que crie para mim um sitemap com todos meus links ou um codigo que funcione como esse acima mas que busque nao somente do ftp mas tmb as paginas que sao geradas dinamicamente

[xanburzum 169]

você pode adaptá-lo a sua necessidade, também

ou usar ASP .Net que tem controles destinados a navegação SiteMap