Marca d'agua

[bsaleze 0]

Tenho um script pra colocar marca d'agua nas fotos. Está funcionando, mas minha hospedagem nao funciona ("Persits.Jpeg").

 

Alguém tem outro código??

 

' Instancia Componente
Set Jpeg1 = Server.CreateObject("Persits.Jpeg")
Set Jpeg2 = Server.CreateObject("Persits.Jpeg")

' Caminho das imagens
Path1 = "c:\images\fotos\" & rs("FOTO")
Path2 = "c:\images\logo.png"


' Caminho das imagens
Jpeg1.Open Path1
Jpeg2.Open Path2


' Executa as funcoes para inserir a marca com transparencia de fundo branco FFFFFF
Jpeg1.Canvas.DrawImage 0, (Jpeg1.Height/1)-(Jpeg2.Height), Jpeg2, 2, &HFFFFFF, 10


' Salva a Imagem com Marca
Jpeg1.Save "c:\images\fotos\" & rs("FOTO")

[Vinicius Ianni 189]

Acho que seria interessante primeiro verificar quais componentes sua hospegem oferece suporte, assim fica mais fácil adaptar o código existente para o componente suportado.

[xanburzum 169]

se funciona na sua maquina ou no localhost, e no server não provavelmente nao tem o componente instalado, qual é o seu host ?

rode este code para ver quais COM+ estão instalados.

 

componentes instalado.
<%
Dim arrListaComponentes(48)

arrListaComponentes(0)  = Array( "AB Mailer","ABMailer.Mailman" )
arrListaComponentes(1)  = Array( "ABC Upload","ABCUpload4.XForm" )
arrListaComponentes(2)  = Array( "ActiveFile","ActiveFile.Post" )
arrListaComponentes(3)  = Array( "ActiveX Data Object","ADODB.Connection" )
arrListaComponentes(4)  = Array( "Adiscon SimpleMail","ADISCON.SimpleMail.1" )
arrListaComponentes(5)  = Array( "ASP DNS", "AspDNS.Lookup" )
arrListaComponentes(6)  = Array( "ASP HTTP","AspHTTP.Conn" )
arrListaComponentes(7)  = Array( "ASP Image","AspImage.Image" )
arrListaComponentes(8)  = Array( "ASP Mail","SMTPsvg.Mailer" )
arrListaComponentes(9)  = Array( "ASP NNTP News", "AspNNTP.Conn" )
arrListaComponentes(10) = Array( "ASP POP 3", "POP3svg.Mailer" )
arrListaComponentes(11) = Array( "ASP Simple Upload","ASPSimpleUpload.Upload" )
arrListaComponentes(12) = Array( "ASP Smart Cache","aspSmartCache.SmartCache" )
arrListaComponentes(13) = Array( "ASP Smart Mail","aspSmartMail.SmartMail" )
arrListaComponentes(14) = Array( "ASP Smart Upload","aspSmartUpload.SmartUpload" )
arrListaComponentes(15) = Array( "ASP Tear","SOFTWING.ASPtear" )
arrListaComponentes(16) = Array( "ASP Thumbnailer","ASPThumbnailer.Thumbnail" )
arrListaComponentes(17) = Array( "ASP WhoIs","WhoIs2.WhoIs" )
arrListaComponentes(18) = Array( "ASPSoft NT Object","ASPSoft.NT" )
arrListaComponentes(19) = Array( "ASPSoft Upload","ASPSoft.Upload" )
arrListaComponentes(20) = Array( "CDO NTS","CDONTS.NewMail" )
arrListaComponentes(21) = Array( "Chestysoft Image","csImageFile.Manage" )
arrListaComponentes(22) = Array( "Chestysoft Upload","csASPUpload.Process" )
arrListaComponentes(23) = Array( "Dimac JMail","JMail.Message" )
arrListaComponentes(24) = Array( "Distinct SMTP","DistinctServerSmtp.SmtpCtrl" )
arrListaComponentes(25) = Array( "Dundas Mailer","Dundas.Mailer" )
arrListaComponentes(26) = Array( "Dundas Upload","Dundas.Upload.2" )
arrListaComponentes(27) = Array( "Dundas PieChartServer", "Dundas.ChartServer.2")
arrListaComponentes(28) = Array( "Dundas 2D Chart", "Dundas.ChartServer2D.1")
arrListaComponentes(29) = Array( "Dundas 3D Chart", "Dundas.ChartServer")
arrListaComponentes(30) = Array( "Dynu Encrypt","Dynu.Encrypt" )
arrListaComponentes(31) = Array( "Dynu HTTP","Dynu.HTTP" )
arrListaComponentes(32) = Array( "Dynu Mail","Dynu.Email" )
arrListaComponentes(33) = Array( "Dynu Upload","Dynu.Upload" )
arrListaComponentes(34) = Array( "Dynu WhoIs","Dynu.Whois" )
arrListaComponentes(35) = Array( "Easy Mail","EasyMail.SMTP.5" )
arrListaComponentes(36) = Array( "File System Object","Scripting.FileSystemObject" )
arrListaComponentes(37) = Array( "Ticluse Teknologi HTTP","InteliSource.Online" )
arrListaComponentes(38) = Array( "Last Mod","LastMod.FileObj" )
arrListaComponentes(39) = Array( "Microsoft XML Engine","Microsoft.XMLDOM" )
arrListaComponentes(40) = Array( "Persits ASP JPEG","Persits.Jpeg" )
arrListaComponentes(41) = Array( "Persits ASPEmail","Persits.MailSender" )
arrListaComponentes(42) = Array( "Persits ASPEncrypt","Persits.CryptoManager" )
arrListaComponentes(43) = Array( "Persits File Upload","Persits.Upload.1" )
arrListaComponentes(44) = Array( "SMTP Mailer","SmtpMail.SmtpMail.1" )
arrListaComponentes(45) = Array( "Soft Artisans File Upload","SoftArtisans.FileUp" )
arrListaComponentes(46) = Array( "Image Size", "ImgSize.Check" )
arrListaComponentes(47) = Array( "Microsoft XML HTTP", "Microsoft.XMLHTTP" )
arrListaComponentes(48) = Array( "CDOSYS", "CDO.Message" )

' Rotina que verifica o componente do array é um objeto.
Function VerificaObjeto(pComponente)
Dim objComponente
On Error Resume Next
VerificaObjeto = False
Err.Clear
Set objComponente = Server.CreateObject(pComponente)
If Err = 0 Then VerificaObjeto = True
Set objComponente = Nothing
Err.Clear
End Function

Public Function VerificaComponentes()
Dim intCont, strTxt
Dim intIndex, strProv

intCont = 0
strTxt = "<table border='1' bordercolor='black' cellspacing='0' cellpadding='0' align='center' width='400'>"
For intIndex = LBound(arrListaComponentes) To UBound(arrListaComponentes)
 strProv = intIndex
 strTxt = strTxt & "<tr><td width='200'><font face='tahoma' size='1'>" & arrListaComponentes(intIndex)(0) & "</font></td>"
 If VerificaObjeto(arrListaComponentes(intIndex)(1)) Then
   strTxt = strTxt & "<td align=center><font color='red' face='tahoma' size='1'>Instalado</font></td>"
   intCont = intCont + 1
 Else
   strTxt = strTxt & "<td align='center'><font face='tahoma' size='1'>Não Instalado</font></td>"
 End If
 strTxt = strTxt & "</tr>"
Next
strTxt = strTxt & "</table><p align='center'><font face='tahoma' size='2'><b>" & intCont & "</b> componentes instalados de "
strTxt = strTxt & "<b>" & UBound(arrListaComponentes) + 1 & "</b> no provedor.</font> </p>"
VerificaComponentes = strTxt 
End Function

Response.Write VerificaComponentes
%>

[bsaleze 0]

ActiveX Data Object Instalado

ASP HTTP Instalado

ASP Image Instalado

ASP Mail Instalado

ASP Smart Mail Instalado

Dundas Mailer Instalado

Dundas Upload Instalado

File System Object Instalado

Microsoft XML Engine Instalado

Persits ASP JPEG Instalado

Persits ASPEmail Instalado

Persits File Upload Instalado

Microsoft XML HTTP Instalado

CDOSYS Instalado

[xanburzum 169]

ele gera algum numero de erro ?

[bsaleze 0]

Microsoft VBScript runtime error '800a01b6'

 

Object doesn't support this property or method: 'DrawImage'

 

/fotos.asp, line 116

[wilnet 92]

Verifique com seu Host, a versão da DLL do AspJpeg. Muitos usam versões antigas que não dão suporte a todas as propriedades.

 

Response.Write Jpeg1.Version
Response.End

 

Veja qual é a versão que está em uso.

 

Veja na documentação deles que explicam.

Site da ASPJpeg

 

AspJpeg 1.3 permite que você coloque imagens sobre outras através do método DrawImage.

 

Se sua versão for antiga, não vai funcionar mesmo.

 

Espero que tenha ajudado.

[xanburzum 169]

Normalmente, isso é porque você usou uma propriedade ou método que não existe, ou não existe na versão do objeto que você está usando. Por exemplo, se você tiver o MSXML 3.0 instalado, e você tenta um code com o MSXML2.