[Resolvido] Converter strings em links clicáveis ​​Ht

[xanburzum 169]

<%
Function LinkURLs(strInput)

Dim iCurrentLocation  ' Nossa posição atual na seqüência de entrada
Dim iLinkStart        ' Posição de início do vínculo atual
Dim iLinkEnd          'Acabar com a posição do link atual
Dim strLinkText       ' Text we're converting to a link
Dim strOutput         ' Retorna uma string com links nele

' Comece pelo primeiro caractere na string
iCurrentLocation = 1

' Procure http:// no texto a partir da posição atual para
'O fim da string. Se encontrá-lo, em seguida, começamos a
'Processo de vinculação de outra forma estamos a fazer porque não há
'Mais http:// 's na string.

Do While InStr(iCurrentLocation, strInput, "http://", 1) <> 0

' Definir a posição do início da ligação
iLinkStart = InStr(iCurrentLocation, strInput, "http://", 1)

' Definir a posição do final do link. Eu uso o
'Primeiro espaço como fator determinante.

iLinkEnd = InStr(iLinkStart, strInput, " ", 1)

'certifique-se que não havia quebra de linha. Se houvesse uma quebra de linha antes do
'Espaço, defina-o como o fim.

checkBreak=InStr(iLinkStart, strInput, chr(13), 1)
if checkBreak>0 and checkBreak<iLinkEnd then iLinkEnd=checkbreak


'Se nós não encontramos um espaço, então ligamos para o
'Fim da cadeia

If iLinkEnd = 0 Then iLinkEnd = Len(strInput) + 1
   ' Cuidar de qualquer pontuação que pegou
   Select Case Mid(strInput, iLinkEnd - 1, 1)
           Case ",",".", "!", "?"
            iLinkEnd = iLinkEnd - 1
       End Select

'Isso contribui para a string de saída todo o material não ligado
'Até o link que está processando.

strOutput = strOutput & Mid(strInput, iCurrentLocation, _
     iLinkStart - iCurrentLocation)

' Obter o texto que está ligando e armazená-lo em uma variável
strLinkText = Mid(strInput, iLinkStart, iLinkEnd - iLinkStart)

' Construir o link e anexá-lo para a string de saída

strOutput = strOutput & "<A HREF=""" & strLinkText & """>" _
  & strLinkText & "</A>"

' depuração 
'Response.Write iLinkStart & "," & iLinkEnd & "<BR>" & vbCrLf

' Redefinir posição atual até o fim dessa ligação
 iCurrentLocation = iLinkEnd

Loop
'Tack no final da string. 
'Não percder texto não-ligados

strOutput = strOutput & Mid(strInput, iCurrentLocation)

' Definir o valor de retorno
LinkURLs = strOutput

End Function 'LinkURLs
%>