Requisição Mobile

[feasso 0]

Como faço para saber se a requisição está vindo de uma disposivo móvel ?

[Vinicius Ianni 189]

Uma das possibilidades é pegar o User-Agent via HTTP Server Variables

Mais informações, você pode achar neste link

[Fagner Dos Santos 2]

<%
navegador = LCase(cstr(request.ServerVariables("HTTP_USER_AGENT")))

if inStr(navegador,"msie") then
nav = "ie"
elseif inStr(navegador,"firefox") then
nav = "firefox"
elseif inStr(navegador,"chrome") then
nav = "chrome"
elseif inStr(navegador,"opera") then
nav = "opera"
elseif inStr(navegador,"ipad") then
nav = "ipad"
elseif inStr(navegador,"android") then
nav = "android"
else
nav = navegador
end if

%>

 

Você também pode tentar identificando as versões dos browsers.

[xanburzum 169]

olha este exemplo:

 

<%
    '******************************************************************************
    ' HTML/XHTML MP/WML Mobile Redirect
    'Isto permitirá que você só precisa para publicitar o seu URL principal. 
     'A razão para ter todos os três tipos é o de reduzir o risco de alguém 
     'Não ser capaz de acessar seu site com qualquer tipo de dispositivo móvel. 
     'Você deve incluir esse script no topo de cada uma de suas páginas em cada tipo, 
     'Só no caso de alguém não acessa seu site através da página padrão. 
     'Dependendo do dispositivo que irão receber a versão correcta do seu site. 
    '
    '******************************************************************************


    'listade agentes móveis 
    Dim AgentArr
    AgentArr = Array("midp", "j2me", "avantg", "docomo", "novarra", "palmos", _
                     "palmsource", "240x320", "opwv", "chtml", "pda", "windows\ ce", _
                     "mmp\/", "blackberry", "mib\/", "symbian", "wireless", "nokia", _
                     "hand", "mobi", "phone", "cdm", "up\.b", "audio", "sie\-", "sec\-", _
                     "samsung", "htc", "mot\-", "mitsu", "sagem", "sony", "alcatel", "lg", _
                     "erics", "vx", "nec", "philips", "mmm", "xx", "panasonic", "sharp", "wap", _
                     "sch", "rover", "pocket", "benq", "java", "pt", "pg", "vox", "amoi", _
                     "bird", "compal", "kg", "voda", "sany", "kdd", "dbt", "sendo", _
                     "sgh", "gradi", "jb", "\d\d\di", "moto")

    HTTP_ACCEPT = LCase(Request.ServerVariables("HTTP_ACCEPT"))
    HTTP_USER_AGENT = LCase(Request.ServerVariables("HTTP_USER_AGENT"))

    WMLBrowser = False
    XHTMLMPBrowser = False
    HTMLBrowser = False

    ThisSite = LCase("http://" & Request.ServerVariables("SERVER_NAME"))
    WMLSite = "http://wap.seu_site.com"
    XHTMLMPSite = "http://mobile.seu_site.com"
    HTMLSite = "http://www.seu_site.com"

    'Check WML
    If Instr(1,HTTP_ACCEPT,"vnd.wap.wml") > 0 Then
      WMLBrowser = True
    End If

    'Check XHTML Mobile 
    If Instr(1,HTTP_ACCEPT,"vnd.wap.xhtml") > 0 Then
      XHTMLMPBrowser = True
    End If

    'Check normal HTML
    If Instr(1,HTTP_ACCEPT,"*/*") > 0 Then
      HTMLBrowser = True
    End If

    ' Enviar para XHTML Mobile se WML e XHTML Mobile
    If WMLBrowser = True AND XHTMLMPBrowser = True Then
       WMLBrowser = False
    End If

    If HTMLBrowser = True Then
       For x = 0 To Ubound(AgentArr)
       'Verificar XHTML MP browser aceitar normal Texto / HTML
          If Instr(1,HTTP_USER_AGENT,AgentArr(x)) > 0 Then
             HTMLBrowser = False
             XHTMLMPBrowser = True
          End If
       Next
       'Trate iPhone como navegador regular 
       If Instr(1,HTTP_USER_AGENT,"iphone") > 0 Then
          XHTMLMPBrowser = False
          HTMLBrowser = True
       End If
    End If

    'Enviar para local adequado 
   'Comparar com o endereço atual para evitar looping
    If WMLBrowser = True AND ThisSite <> WMLSite Then
       Response.Redirect WMLSite
    ElseIf XHTMLMPBrowser = True AND ThisSite <> XHTMLMPSite Then
       Response.Redirect XHTMLMPSite
    ElseIf HTMLBrowser = True AND ThisSite <> HTMLSite Then
       Response.Redirect HTMLSite
    End If

 %>