Utilidades

[Eisenheim 67]

Olá a todos!

 

Esse tópico na verdade eu gostaria de transformá-lo num apanhado de funções e procedimentos que sejam úteis para ser utilizadas na montagem de seus algoritmos. Eu mesmo muitas vezes me deparava com alguns problemas que poderiam ficar ainda mais "bonitinhos" se houvesse algo para assim poder utilizar e deixá-lo ainda melhor.

 

Qualquer pessoa que tenha criado ou deseja criar alguma função ou procedimento que possa ser reaproveitado em qualquer situação e desejar poderá compartilhá-la conosco nesse mesmo post.

 

Sem mais delongas vamos começar.

 

Objetivo: Exibir um cabeçalho onde seja exibido o título alinhado em uma desses três opções:

 

E = Alinhamento a Esquerda;

C = Alinhamento Centralizado;

D = Alinhamento a Direita;

 

procedimento Cabecalho( alinhamento, titulo: caractere )
var
 i, e1, e2, c1, c2, d1: inteiro
inicio
 // Calculo para alinhamento a esquerda
 e1 <- compr( titulo )
 e2 <- 80 -1
 // Calculo para alinhamento ao centro
 c1 <- ( 80 - compr( titulo ) ) DIV 2
 c2 <- c1 + compr( titulo )
 // Calculo para alinhamento a direita
 d1 <- 80 - compr( titulo ) - 1

 EscrevaL("---------------------------------------------------------------------------------")
 Escreva("|")
 Se Alinhamento = "E" Entao
   Escreva( titulo )
   para i de e1 ate e2-1 faca
     Escreva(" ")
   fimpara
 Senao
   Se Alinhamento = "C" Entao
     para i de 2 ate c1-1 faca
       Escreva(" ")
     fimpara
     Escreva( titulo )
     para i de c2 ate 80 faca
       Escreva(" ")
     fimpara
   Senao
     Se Alinhamento = "D" Entao
       para i de 1 ate d1 faca
         Escreva(" ")
       fimpara
       Escreva( titulo )
     FimSe
   FimSe
 FimSe
 EscrevaL("|")
 EscrevaL("---------------------------------------------------------------------------------")
fimprocedimento

 

Até a próxima. :thumbsup:

[Eisenheim 67]

Olá amigos.

 

Mais uma utilidade para quem deseja converter números inteiros para binários.

 

 

 
funcao NumParaBin( i: inteiro ): caractere
var
  b: caractere
  t: caractere
  x: inteiro
inicio
  Enquanto i <> 0 faca
    x <- i MOD 2
    t <- t + numpcarac( x )
    i <- i DIV 2
  fimenquanto
  para x de compr( t ) ate 1 passo -1 faca
    b <- b + copia( t, x, 1 )
  fimpara
  retorne b
fimfuncao