Gráfico

cesarhtc · Novembro 6, 2013

Boa tarde,

Gostaria de aprender com gerar gráfico via asp, alguém poderia ajudar?

Obrigado

usando este codigo como posso gerar um grafico?

nmensalidades =24

valortotal = 1200000

valormensalidade1 = valortotal / nmensalidades

' aqui vai entrar o array necessário: os valores

' vou criar um array para conter os valores

dim valor()

ReDim valor(nmensalidades)

for i=1 to nmensalidades

valor(i) = formatnumber(valormensalidade1,4)

response.write "Parcela " & i & " - " & valor(i) & "<br>"

xanburzum · Novembro 6, 2013

dá uma pesquisada no fórum que postei vários códigos para isso, inclusive usando componentes.

cesarhtc · Novembro 18, 2013

Xanburzum,

O codigo abaixo traz o ano e valor gasto.

<%
  'definindo a largura e a altura em pixels 
 Const grafaltura = 300
  Const graflargura = 600
  Const barImage = "img_graf.jpg"

  sub BarChart(ano, rotulos , titulo, eixos)
    'Imprime o cabeçalho
    Response.Write("<TABLE CELLSPACING=0 CELLPADDING=1 BORDER=0 WIDTH=" & graflargura & ">"    )
    Response.Write("<TR><TH COLSPAN=" & UBound(ano) - LBound(ano) + 2 & ">")
    Response.Write("<FONT SIZE=+2>" & titulo & "</FONT></TH></TR>" & chr(13))
    Response.Write("<TR><TD VALIGN=TOP ALIGN=RIGHT>" & chr(13))
    
    'encontra o maior valor
    Dim maior_valor
    maior_valor = LBound(ano)
    
    Dim i
     for i = LBound(ano) to UBound(ano) - 1
      if ano(i) > maior_valor then maior_valor = ano(i)
     next
    
    'imprime o maior valor no topo do gráfico
    Response.Write("<b>" & maior_valor & "</b>-" & "</TD>")
    
    Dim largura_percentual
    largura_percentual = (1 / (UBound(ano) - LBound(ano) )) * 100
    
     For i = LBound(ano) to UBound(ano) - 1
      Response.Write(" <TD VALIGN=BOTTOM ROWSPAN=2 WIDTH=" & largura_percentual & "% >" & chr(13))
      Response.Write("<img src=" & barImage & " " &"width=100%" & " height=" & CInt((ano(i) / maior_valor) * grafAltura) & ">")
      Response.Write(" </TD>")
     Next
    
    Response.Write("</TR>")
    Response.Write("<TR><TD VALIGN=BOTTOM ALIGN=RIGHT><b>0</b></TD></TR>")
    
    'Imprime o rodape
    Response.Write("<TR><TD ALIGN=RIGHT VALIGN=BOTTOM>" & eixos & "</TD>" & chr(13))
    
     for i = LBound(rotulos) to UBound(rotulos) - 1
      Response.Write("<TD VALIGN=BOTTOM ALIGN=CENTER>" & rotulos(i) & "</TD>" & chr(13))
    
     next
    Response.Write("</TR>" & chr(13))
    Response.Write("</TABLE>")
  end Sub
  

'<!-- ****************************** -->
'response.End 
  'abre conexao com banco de dados
 ' Dim objConnection
 ' Set objConnection = Server.CreateObject("ADODB.Connection")
 ' strConn = "Provider = Microsoft.jet.oledb.4.0; Data Source =" & Server.MapPath("grafico.mdb")
  'objConnection.Open(strConn)

  'Dim SQL
  'SQL = "SELECT Aluno,Faltas FROM Alunos"

'<!-- ****************************** -->

  '1) Montar a String de Conexão

'Cria um objeto recordset
set rstMain = Server.CreateObject("ADODB.Recordset")

		strSQL="SELECT previsao.ANO," & _
				      "SUM(previsao.Valor_Previsto) AS Total_Previsto," & _
				      "SUM(previsao.Valor_Realizado) AS Total_Realizado " & _
			   "FROM previsao " & _			 
				    "GROUP BY previsao.ANO " & _					
					"ORDER BY previsao.ANO"

'Conecta ao BD pelo DSN e abre a consulta
'Como resultado, o recordset conterá a tabela-resposta
rstMain.Open StrSQL, Application("CONEXAO"),3
  

  Dim numRegistros
  numRegistros = rstMain.RecordCount
  Response.Write(numRegistros)

  Dim VetorAno(), VetorTotal_Previsto()
  Redim VetorAno(numRegistros)
  Redim VetorTotal_Previsto(numRegistros)


  Dim i
  for i = 0 to numRegistros-1
    VetorAno(i) = rstMain("Ano")
    VetorTotal_Previsto(i) = rstMain("Total_Previsto")

    rstMain.MoveNext 	
	
  next

%>
<HTML>
<BODY>
<CENTER>
<% BarChart VetorAno,VetorTotal_Previsto,"Faltas dos Alunos da 1a. Serie - Março/Abril ","Alunos" %>
</CENTER>
</BODY>
</HTML>

<%
rstMain.Close
Set rstMain = Nothing

'rstMain.Close
'Set rstMain=Nothing
%>

xanburzum · Novembro 18, 2013

exemplos:

Gráficos com OWC Chart do Office

ASP/VML Line Chart Version

Line Chart

CódigoFonte de Gráficos

InteliGraph

cesarhtc · Novembro 21, 2013

Estou nesses links que vc enviou, meus conhecimentos em asp é pequeno.

O que mandei não está correto?

Fiquei voando nesse código:

<BODY>

<font style="font-family: tahoma; font-size: 8pt">Abaixo você vê exemplos de como criar gráficos de cada tipo. <a href="mailto:lukevit@bol.com.br">Luciano</a></font><BR>

<%

path=left(Request.ServerVariables("PATH_INFO"),InstrRev(Request.ServerVariables("PATH_INFO"),"/"))

path=right(path,len(path)-1)

if InStr(path,"/") then

path=left(path,len(path)-1)

end if

Dim catnom(), valor(), caminho

caminho="/"&path

With Server.CreateObject("OWC.Chart")

set c = .constants

With .charts.add

.HasTitle=True

if .HasTitle then

.Title.Caption = "Frutas Hoje"

.Title.Font.Size = 10

.Title.Font.Name = "Tahoma"

.Title.Font.Bold = True

.Title.Font.Italic = False

.Title.Font.Underline = False

end if

.HasLegend = True

if .HasLegend then

.Legend.Font.Size = 10

.Legend.Font.Name = "Tahoma"

.Legend.Font.Bold = False

.Legend.Font.Italic = False

.Legend.Font.Underline = False

end if

tipo=11

Select Case tipo

Case 1

.Type = c.chChartTypeArea

Case 2

.Type = c.chChartTypeAreaStacked

Case 3

.Type = c.chChartTypeBarClustered

Case 4

.Type = c.chChartTypeBarStacked

Case 5

.Type = c.chChartTypeBubble

Case 6

.Type = c.chChartTypeColumnClustered

Case 7

.Type = c.chChartTypeColumnStacked

Case 8

.Type = c.chChartTypeLine

Case 9

.Type = c.chChartTypeLineMarkers

Case 10

.Type = c.chChartTypeLineStacked

Case 11

.Type = c.chChartTypePie

Case Default

'.Type = c.chChartTypeArea3D

'.Type = c.chChartTypeBar3D

'.Type = c.chChartTypeColumn3D

'.Type = c.chChartTypeColumnStacked3D

'.Type = c.chChartTypeCombo

'.Type = c.chChartTypeCombo3D

End Select

x=5

ReDim catnom(x), valor(x)

catnom(0) = "Pera"

valor(0) = 10

catnom(1) = "Maça"

valor(1) = 20

catnom(2) = "Uva"

valor(2) = 10

catnom(3) = "Banana"

valor(3) = 20

catnom(4) = "Kiwi"

valor(4) = 30

catnom(5) = "Laranja"

valor(5) = 20

With .seriescollection.add

.caption = "Frutas"

.setdata c.chdimcategories,c.chdataliteral, catnom

.setdata c.chdimvalues,c.chdataliteral, valor

End With

.border.color = c.chColorNone

Set arquivo=Server.CreateObject("Scripting.FileSystemObject")

arquivo=arquivo.GetTempname & ".gif"

.ExportPicture Server.MapPath(caminho) &"/"& arquivo, "gif", 200, 200

Response.Write "<img src="""&arquivo&""">"

End With

%>

</BODY>

xanburzum · Novembro 21, 2013

Um gráfico de barras empilhadas com várias cores. Usando uma cor diferente para cada stacks e cada stacks terá sua Tool Tip própria também! Basta passar uma matriz com suas cores, uma para cada bar. As cores são especificadas por nome, o nome de cada cor corresponde a um spacer, um arquivo de imagem gif que é dinamicamente ligado ao atributo de marca IMG SRC através do nosso código asp. Certifique-se de colocar esses arquivos na pasta images.

%

Sub ShowStackedBarChart(ByRef aValues, ByRef aLabels, ByRef strTitle, _
    ByRef strXAxisLabel, ByRef strYAxisLabel, ByRef aColors, ByRef aToolTip, ByRef aBars)

    ' definir constantes
    ' Todas as unidades são em pixels da tela
    Const GRAPH_WIDTH  = 400  ' A largura do body do gráfico
    Const GRAPH_HEIGHT = 300  ' A altura do body do gráfico
    Const GRAPH_BORDER = 4    ' O tamanho da borda preta
    Const GRAPH_SPACER = 2    ' O tamanho do espaço entre as barras

    Const TABLE_BORDER = 0
    'Const TABLE_BORDER = 10

    ' Declarar asr variaveis
    Dim i, ii, iTmp, aTmp()
    Dim iMaxValue
    Dim iBarWidth
    Dim iBarHeight
    Dim strColumnColor

    ' Obtenha o valor máximo do conjunto de dados
    iMaxValue = 0
    For I = 0 To UBound(aValues)
        If iMaxValue  aValues(I) Then iMaxValue = aValues(I)
    Next

    If iMaxValue  = 0 Then Exit Sub
    'Response.Write iMaxValue &    ' Debugging line

    ReDim Preserve aTmp(UBound(aColors))

' Calcular a largura das barras
'Largura total e dividir pelo número de itens.

    iBarWidth = (GRAPH_WIDTH  (UBound(aValues) + 1)) - GRAPH_SPACER
    'Response.Write iBarWidth ' Debugging line

    ' Começar a desenhar o gráfico
    %
    TABLE BORDER=%= TABLE_BORDER % CELLSPACING=0 CELLPADDING=0
        TR
            TD COLSPAN=3 ALIGN=centerH2%= strTitle %H2TD
        TR
        TR
            TD VALIGN=centerB%= strYAxisLabel %BTD
            TD VALIGN=top
                TABLE BORDER=%= TABLE_BORDER % CELLSPACING=0 CELLPADDING=0
                    TR
                        TD ROWSPAN=2
                            IMG SRC=.imagesspacer.gif BORDER=0
                                WIDTH=1 HEIGHT=%= GRAPH_HEIGHT %
                        TD
                        TD VALIGN=top ALIGN=right%= iMaxValue % TD
                    TR
                    TR
                        TD VALIGN=bottom ALIGN=right0 TD
                    TR
                TABLE
            TD
            TD
                TABLE BORDER=%= TABLE_BORDER % CELLSPACING=0 CELLPADDING=0
                    TR
                        TD VALIGN=bottomIMG SRC=.imagesspacer_black.gif
                            BORDER=0
                            WIDTH=%= GRAPH_BORDER %
                            HEIGHT=%= GRAPH_HEIGHT %TD
                        %
                        ' Estamos agora no corpo do gráfico.
'Loop através dos dados que mostram as barras!
                        For I = 0 To UBound(aValues)
                            iBarHeight = Int((aValues(I)  iMaxValue)  GRAPH_HEIGHT)

                            ' ignorar um 0 como uma dimensão da imagem!
                            If iBarHeight = 0 Then iBarHeight = 1
                            %
                            TD VALIGN=bottomIMG SRC=.imagesspacer.gif
                                BORDER=0
                                WIDTH=%= GRAPH_SPACER %
                                HEIGHT=1TD
                            TD VALIGN=bottom%   
                                For ii = UBound(aColors) - 1 To 0 Step - 1
                                    aTmp(ii) = Int((aBars(ii+1,I)  iMaxValue)  GRAPH_HEIGHT)
                                    %IMG SRC=.imagesspacer_%= aColors(ii) %.gif
                                    BORDER=0 WIDTH=%= iBarWidth %
                                    HEIGHT=%= aTmp(ii) %
                                    ALT=%= aBars(ii + 1, I) & vbTab & aToolTip(ii) %br %
                                Next 'ii
                            %TD%                               
                        Next 'I
                        %
                    TR
                TABLE
                TABLE BORDER=0 CELLSPACING=0 CELLPADDING=0
                   
                    TR
                        TD COLSPAN=%= (UBound(aValues) + 1) %IMG SRC=.imagesspacer_black.gif
                            WIDTH=%= GRAPH_BORDER + ((UBound(aValues) + 1)  (iBarWidth + GRAPH_SPACER)) %
                            HEIGHT=%= GRAPH_BORDER % BORDER=0TD
                    TR
                        %
                        ' a label array é opcional e só é realmente útil
'para pequenos conjuntos de dados com label´s muito curta!
                        %
                        % If IsArray(aLabels) Then %
                            TR
                            % For I = 0 To UBound(aValues)
                                iTmp = (GRAPH_BORDER + ((UBound(aValues) + 1)  _
                                    (iBarWidth + GRAPH_SPACER)))  (UBound(aValues) +1)
                                iTmp = Int(Round(iTmp))
                                %
                                TD WIDTH=%= iTmp % ALIGN=centerFONT SIZE=2%= aLabels(I) %FONTTD
                            % Next 'I %
                            TR
                        % End If %
                TABLE
            TD
        TR
    TABLE
    %
End Sub

' Aqui está o exemplo de código a partir de uma aplicação real,
' vamos usar os dados estáticos para a nossa amostra.

' Para este exemplo nosso gráfico será cinco colunas
' e quatro stacks
Dim i, ii, iNumSensors, iNumStates
Dim aValues(), aLabels(), aTooltip(), aColors(), aBars()

iNumSensors = 5
iNumStates = 4
ReDim Preserve aValues(iNumSensors)
ReDim Preserve aLabels(iNumSensors)
ReDim Preserve aTooltip(iNumStates)
ReDim Preserve aColors(iNumStates)

' Criar a barra do array uma linha por sensor
ReDim Preserve abars(iNumStates,iNumSensors)
For i = 0 to Ubound(abars,1)
   For ii = 0 to Ubound(abars,2)
      abars(i,ii) = 0
   Next 'ii
Next 'i

' definir a altura total de cada coluna         
aValues(0) = 5
aValues(1) = 171
aValues(2) = 62
aValues(3) = 66
aValues(4) = 87
aValues(5) = 391

' definir os dados para as barras          
aBars(0,0) = 1
aBars(0,1) = 1
aBars(0,2) = 1
aBars(0,3) = 1
aBars(0,4) = 1
aBars(0,5) = 5

aBars(1,0) = 32
aBars(1,1) = 112
aBars(1,2) = 6
aBars(1,3) = 11
aBars(1,4) = 10
aBars(1,5) = 171

aBars(2,0) = 6
aBars(2,1) = 18
aBars(2,2) = 4
aBars(2,3) = 14
aBars(2,4) = 20
aBars(2,5) = 62

aBars(3,0) = 13
aBars(3,1) = 0
aBars(3,2) = 10
aBars(3,3) = 13
aBars(3,4) = 30
aBars(3,5) = 66

aBars(4,0) = 10
aBars(4,1) = 7
aBars(4,2) = 30
aBars(4,3) = 0
aBars(4,4) = 40
aBars(4,5) = 87

' definir os rótulos para o gráfico          
aLabels(0) = S1
aLabels(1) = S2
aLabels(2) = S3
aLabels(3) = S4
aLabels(4) = S5
aLabels(5) = Total

' definir as cores do gráfico
aColors(0) = red
aColors(1) = blue
aColors(2) = yellow
aColors(3) = lime
' definir as Tool Tips para o gráfico
aTooltip(0) = Critical
aTooltip(1) = Serious
aTooltip(2) = Routine
aTooltip(3) = Cleared
' Esta é a linha que chama a função para exibir o gráfico
ShowStackedBarChart aValues, aLabels, Sensor Summary, Sensor ID, N, aColors, aTooltip, aBars
%

Gustavo Emygdio Barboza · Novembro 22, 2013

que tal usar API do google

exemplo: http://chart.apis.google.com/chart?cht=p3&chd=t:100,50,60&chs=260x110&chl=iMasters%7CCesar%7CGustavo

faça sua aplicação carregar uma página alimentando esse parametros via GET e pronto ... melhor trabalha com ajax? fica show!!

tem outros modelos o google resolve....

<img src="http://chart.apis.google.com/chart?cht=p3&chd=t:45,20,20,15&chs=340x200&chdl=Janeiro|Fevereiro|Março|Abril

4.

&chl=45%|20%|20%|15%&chco=67087b|e3007a|00a8eb|79c471" alt="" width="350" height="203" />

fique a vontade...

att;

xanburzum · Novembro 22, 2013

outro exemplo:

<HTML>
<HEAD>

<TITLE>:: Gráfico</TITLE>
<STYLE TYPE="text/css">
    BODY{ font-family:Arial, "Helvetica"; font-size:smaller }
</STYLE>
</HEAD>

<%
Dim I, J            ' contadores
Dim iMaxValue            ' possui valor máximo de linha para o gráfico de escala
Dim tmp                ' temp
Dim caminho
' definir o caminho completo do arquivo de dados de entrada; dados de tabelas e tabulação
'caminho=Server.MapPath("data1.txt")
'Const DATA_FILE = caminho
'"c:\Inetpub\wwwroot\db\data1.txt"

Sub ShowChart(ByRef aValues, ByRef rowLabels, ByRef colLabels, ByRef strTitle, ByRef strXAxisLabel, ByRef strYAxisLabel)

' ATodas as unidades são em pixels da tela

Const CHART_WIDTH = 425        ' A largura do corpo do gráfico
Const CELL_HEIGHT = 25        ' A altura da célula que contém a barra empilhada
Const BAR_WIDTH  = 15        ' A largura das barras empilhadas
Const STACK_NUMBER = 25        ' Número de imagens disponível para pintura na stack bar

' Debugging constante para que eu possa mudar facilmente as bordas
' deixar em zero

Const TABLE_BORDER = 0
'Const TABLE_BORDER = 5

' Declara as variaveis
Dim iBarLength                ' contem a altura da barra
Dim rowMarkZero()            ' array  para indicar que uma linha (ou seja, soma de todos os valores em uma linha)
                    ' é zero
' inicializa o numero de rowLabels
ReDim rowMarkZero(UBound(rowLabels))

' validar o número de labels de coluna, não deve ultrapassar o número da stack de imagens
if UBound(colLabels) > STACK_NUMBER - 1 then
    Response.Write "<B>Error</B>: Colunas ultrapassou a stack images[ " & STACK_NUMBER - 1 & " ].<BR>"
    Response.Write "Desculpe, o gráfico de barras não pode ser criado.</BODY></HTML>"
    Response.End
end if

' erificar se há valores válidos em cada linha a ser exibida como uma stack bar.
' Se não marcar os valores inválidos como -1 para pular ,
' Encontrar o máximo (soma dos valores em uma linha) para dimensionar a largura do gráfico.
' Se a soma dos valores em uma linha for inferior a 1, marcar essa linha
tmp = 0
For J = 0 To UBound(aValues, 2)
    tmp = 0
    For I = 0 To UBound(aValues)
        if IsNumeric(aValues(I, J)) = False then
            aValues(I, J) = -1 ' -1 Significa NULL, usado para pular sem pintar a tela
        elseif aValues(I, J) = 0 then
            aValues(I, J) = -1 ' -1 Significa NULL, usado para pular sem pintar a tela
        else
            tmp = tmp + aValues(I, J)
        end if
    Next 'I
    If iMaxValue < CDbl(tmp) Then iMaxValue = CDbl(tmp)
    ' rowMarkZero array set (J) para TRUE se o somatório dos valores col <1 (inválido)
'Vamos deixar uma linha em branco, se a soma dos valores de cada linha são <1.    
    If tmp < 1 then rowMarkZero(J) = "TRUE" else rowMarkZero(J) = "FALSE"
Next 'J
%>

<!-- Começar a desenhar o gráfico -->
<TABLE BORDER="<%= TABLE_BORDER %>" CELLSPACING="0" CELLPADDING="0">
    <TR>
    <TD>
    <TABLE BORDER="<%= TABLE_BORDER %>" CELLSPACING="0" CELLPADDING="0">
        <TR>
        <TD COLSPAN="4" ALIGN="center"><H4><%= strTitle %></H4></TD>
        </TR>
        
        <TR>
        <TD VALIGN="center"><B><SMALL><%= strYAxisLabel %></B>    </SMALL></TD>
        <TD>
        <!-- rotulando as linhas -->
        <TABLE BORDER="<%= TABLE_BORDER %>" CELLSPACING="0" CELLPADDING="0">

<%

For J = 0 To UBound(rowLabels)
      Response.Write vbTab & vbTab & vbTab & vbTab &"<TR>" & vbCrLf
      Response.Write vbTab & vbTab & vbTab & vbTab &"<TD height=""" & CELL_HEIGHT & """><SMALL>" & rowLabels(J) &" </SMALL></TD>" & vbCrLf
      Response.Write vbTab & vbTab & vbTab & vbTab &"</TR>" & vbCrLf
Next

%>

        </TABLE>
        </TD>
        <!-- pintar a borda vertical do gráfico, adicionando imagem para trabalhar com o Netscape -->
        <TD BGCOLOR="#000000" WIDTH="2"><IMG SRC="../images/spacer.gif" BORDER="0" HEIGHT="1" WIDTH="1"></TD>
        <TD>
        <TABLE BORDER="<%= TABLE_BORDER %>" CELLSPACING="0" CELLPADDING="0" WIDTH="<%= CHART_WIDTH %>">
<%
For J = 0 To UBound(aValues, 2)

      Response.Write vbTab & vbTab & vbTab & vbTab &"<TR>" & vbCrLf
      Response.Write vbTab & vbTab & vbTab & vbTab &"<TD>" & vbCrLf                                            
      Response.Write vbTab & vbTab & vbTab & vbTab &"<TABLE BORDER="""& TABLE_BORDER &""" CELLSPACING=""0"" CELLPADDING=""0"">" & vbCrLf
      Response.Write vbTab & vbTab & vbTab & vbTab & vbTab &"<TR>" & vbCrLf

      ' Estamos agora no body do chart
      'Fazer a stack de barras apenas quando os dados estão disponíveis para a pintura
      if rowMarkZero(J) = "FALSE" then ' row data não é zero!!
    'Loop através dos dados mostrando seus valores como barras!
    For I = 0 To UBound(aValues)
        if aValues(I, J) <> -1 then        ' -1 É pular sem pintura
            iBarLength = CInt( (aValues(I, J) * CHART_WIDTH)/ iMaxValue  )
                                    
            ' Este é um hack desde browsers ignoram a 0 ou 0 .** (algo) como uma dimensão da imagem!
            If iBarLength < 1 Then iBarLength = 1
    
            Response.Write vbTab & vbTab & vbTab & vbTab & vbTab &"<TD WIDTH=""" & iBarLength & """ HEIGHT=""" & CELL_HEIGHT & """><A TITLE=""" & colLabels(I) & ": " & FormatNumber(aValues(I, J),,,,-2) & """><IMG SRC=""../images/stack" & I & ".gif"" BORDER=""0"" WIDTH=""" & iBarLength & """ HEIGHT=""" & BAR_WIDTH & """ ALT=""" & colLabels(I) & ": " & FormatNumber(aValues(I, J),,,,-2) & """></A></TD>" & vbCrLf
        End if
    Next ' I
      Else        ' rowMarkZero(J) = "TRUE"; soma dos valores de uma linha é zero!!
    Response.Write vbTab & vbTab & vbTab & vbTab & vbTab &"<TD HEIGHT=""" & CELL_HEIGHT & """> </TD>" & vbCrLf
      End if                    

      Response.Write vbTab & vbTab & vbTab & vbTab & vbTab &"</TR>" & vbCrLf
      Response.Write vbTab & vbTab & vbTab & vbTab &"</TABLE>" & vbCrLf
                        
      Response.Write vbTab & vbTab & vbTab & vbTab &"</TD>" & vbCrLf
      Response.Write vbTab & vbTab & vbTab & vbTab &"</TR>" & vbCrLf
Next
%>
        </TABLE>
        </TD>
        </TR>
        <TR>
        <TD HEIGHT="2" COLSPAN="2"></ TD>
<- Pintar a borda horizontal do gráfico;! Adicionar imagem para trabalhar com o Netscape-->
        <TD BGCOLOR="#000000" HEIGHT="2" COLSPAN="2" WIDTH="<%= CHART_WIDTH %>"><IMG SRC="../images/spacer.gif" BORDER="0" HEIGHT="1" WIDTH="1"></TD>
        </TR>
        <TR>
        <TD height="2" COLSPAN="2" VALIGN="top" ALIGN="right"></TD>
        <TD COLSPAN="2">
        <TABLE BORDER="<%= TABLE_BORDER %>" CELLSPACING="0" CELLPADDING="0" WIDTH="100%">
            <TR>
            <TD height="2" VALIGN="top"><SMALL>0</SMALL></TD>
            <TD VALIGN="top" ALIGN="right"><SMALL><%= FormatNumber(iMaxValue,,,,-2) %></SMALL></TD>
            </TR>
        </TABLE>
        </TD>
        </TR>
        <TR>
        <TD COLSPAN="3"><!-- Lugar do titulo para o X rótulo Eixo centrado--></TD>
        <TD ALIGN="center"><SMALL><B><%= strXAxisLabel %></B></SMALL></TD>
        </TR>
    </TABLE>
    </TD>    
    <TD>   </TD>
    
    <TD VALIGN="top"><BR><BR>
    <TABLE BORDER="1" CELLSPACING="0" CELLPADDING="0">
        <TR>
        <TD>
        <TABLE BORDER="<%= TABLE_BORDER %>" CELLSPACING="0" CELLPADDING="0">
            <TR>
            <TD COLSPAN="2"><SMALL><B>  Legenda - <%= strXAxisLabel %> </SMALL></B><BR> </TD>
            </TR>
            <TR>
            <TD><SMALL>
<%
            
For I = 0 To UBound(colLabels) %>                            
                  <IMG SRC="../images/stack<%= I %>.gif" BORDER="0" HEIGHT="10" WIDTH="10">
                   <%= colLabels(I) %><BR>
    <% if I Mod 12 = 0 and I > 0 then
        Response.Write "</SMALL></TD><TD VALIGN=""TOP""><SMALL>" & vbCrLf
    end if
Next ' I

%>
            </SMALL></TD>
            </TR>
        </TABLE>
        </TD>
        </TR>
    </TABLE>
    </TD>
    </TR>
</TABLE>

<%
End Sub

Dim ts, fso, s
Dim arrValues, grid()
Dim Cnt

' Abrindo a entrada de arquivo de dados
Const ForReading = 1
Set fso = CreateObject("Scripting.FileSystemObject")
If (fso.FileExists(Server.MapPath("data1.txt"))) = False Then
    Response.Write "Arquivo( " & DATA_FILE &" ) não encontrado.<br>"
    Response.Write "</BODY></HTML>"
    Response.End
End if
Set ts = fso.OpenTextFile( Server.MapPath("data1.txt"), ForReading)

I = 0
J = 0

'recebendo os valores numéricos do fluxo de arquivo
For Cnt = 1 to 5
    s = ts.ReadLine      
    arrValues = Split(s, vbTab, -1, 1)
      
    ReDim Preserve grid(UBound(arrValues), J)    ' declarar 2d grid
      
    For I = 0 To UBound(arrValues)
          grid( I, J ) = arrValues(I)        
      Next ' I

  J = J + 1      
Next ' Cnt

ts.Close        ' fechar  text stream

' mostra bar chart...  
ShowChart grid, Array ("Itaquera", "Rebouças", "Saõ José dos Campos", "Tatuapé", "Thomas Alves"), Array ("Computadores"), "Total de micros nas Unidades", "Possuem Micros", "Unidades"

%>
</BODY>
</HTML>

Arquivado

Gráfico

Recommended Posts

cesarhtc 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

xanburzum 169

Compartilhar este post

Link para o post

Compartilhar em outros sites

cesarhtc 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

xanburzum 169

Compartilhar este post

Link para o post

Compartilhar em outros sites

cesarhtc 0

Compartilhar este post

Link para o post

Compartilhar em outros sites

xanburzum 169

Compartilhar este post

Link para o post

Compartilhar em outros sites

Gustavo Emygdio Barboza 24

Compartilhar este post

Link para o post

Compartilhar em outros sites

xanburzum 169

Compartilhar este post

Link para o post

Compartilhar em outros sites

Estou criando uma calculadora de m2 e litros de tinta

Cruzamento de Bases

Consulta sem duplicação

Fóruns

Tempo Real

Informação importante