Integracao VB com BROffice

[ederverza 0]

Ola pessoas,

alguem pode ajudar, preciso criar uma planilha do broffice atraves do VB...

 

existe essa possibilidade ?

 

Att.

Eder

[ederverza 0]

Galera...encontrei oq procurava......o programinha ta ai pra quem precisar...flw

 

 

Private Sub Command1_Click()

Dim NewArgs(0)

Dim SaveParam(0)

 

'Define se mostra ou nao o BR Office

Set NewArgs(0) = MakePropertyValue("Hidden", True)

 

'cria o objet service manager

Set oServiceManager = CreateObject("com.sun.star.ServiceManager")

'cria o objeto desktop

Set oDesktop = oServiceManager.createInstance("com.sun.star.frame.Desktop")

'Cria um novo sCALC (Excel) conforme os argumentos do NewArgs

Set oDoc = oDesktop.loadComponentFromURL("private:factory/scalc", "_blank", 0, NewArgs())

 

 

Dim fCaminho As String

fCaminho = "C:\Teste.xls"

 

'Converte o nome do arquivo para o padrao URL (file:///....

fCaminho = FileName2URL(fCaminho)

 

Set oSheet = oDoc.getSheets().getByIndex(0) 'seleciona primeira planilha

 

Call oSheet.getCellByPosition(3, 1).SetValue(111) 'seta valor col,linha

Call oSheet.getCellByPosition(3, 2).SetValue(222) 'seta valor col,linha

Call oSheet.getCellByPosition(3, 3).SetString("Nilson") 'seta valor da celular do tipo string

Call oSheet.getCellByPosition(3, 5).SetFormula("=SUM(D2:D4)") 'seta celula do tipo formula

 

'Define os Argumentos para salvar (use writter_dpf_export se quiser em PDF)

Set SaveParam(0) = MakePropertyValue("FilterName", "MS Excel 97")

 

'Salva conforme os argumentos do SaveArgs

Call oDoc.storeToURL(fCaminho, SaveParam())

 

 

End 'sai do programa

End Sub

 

Function MakePropertyValue(cName, uValue) As Object

Set oServiceManager = CreateObject("com.sun.star.ServiceManager")

Dim oStruct

Set oStruct = oServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue")

oStruct.Name = cName

oStruct.Value = uValue

Set MakePropertyValue = oStruct

End Function

 

Public Function FileName2URL(ByVal pFileName As String, _

Optional ByVal pConvertBackslashesToSlashes As Boolean = True) _

As String

Dim s As String

Dim z As String

Dim j As Long

Dim x As Integer

 

On Error Resume Next

s = ""

For j = 1 To Len(pFileName)

z = Mid(pFileName, j, 1)

x = Asc(z)

Select Case x

Case 9

z = "%09"

Case 13

z = "%0d"

Case 10

z = "%0a"

'Case 32

' z = "+"

Case 32 To 35, 37 To 41, 43, 44, 59 To 63, 91, 93, 94, 96, Is >= 123

z = "%" & Hex(x)

Case 92

If pConvertBackslashesToSlashes Then z = "/"

End Select

s = s & z

Next

s = "file:///" & s

FileName2URL = s

End Function

[jobsongf 0]

Grande EderVerza

 

Seu post me ajudou muito, mais preciso dos Imports para continuar com a programação.

Já instalei o BROffice e adicionei os DLL's que o mesmo fornece.....

Estou trabalhando no VS2008 e não consigo usar seus comandos.

 

Att.

[scorpio 7]

Xi cara, não funciona porque o código é de VB6 e você ta usando .Net. Não sei muito sobre .Net mas tenta referenciar as DLLs e depois dar um Imports com os nomes delas.

 

Poste sua duvida lá na área de Plataforma .Net que é mais provavel que alguém responda. http://forum.imasters.com.br/public/style_emoticons/default/thumbsup.gif

 

Abraços!

[André Capella 0]

Amigos,

 

gostaria de saber como insiro borda em algumas células da planilha do broffice calc.

também gostaria de saber como mudo a cor da fonte na mesma planilha.

 

me ajudem, por favor

 

André Capella