[Resolvido] MOVER informações de uma tabala para outra usando um

[evertonsouza 0]

Ola amigos.

 

Gostaria de saber como faço para mover (literalmente mover) os dados de uma tabela previamente preexida para outra tabela usando um formulario no access?

 

ex:

Tabela1 Formulario Tabela2

item1 >>-> Item1 (sendo que o intem foi removido da tabela1 para a 2.

item2 >>-> item2

 

 

att

Everton Souza

[Julien.Sorel 0]

Olá Everton,

 

Acho que era isso... Caso não, descreva um pouco mais o que deseja...

 

 

Primeiro crie um módulo, com qualquer nome que lhe agrade:

 

Option Compare Database
Public Const strTitle  As String = "Imaster - Access"
Sub modMsgErr()

    modMsg = MsgBox("Erro número: " & Err.Number & vbLf & vbLf & Err.Description, vbCritical, strTitle)

End Sub
Sub modMover()

    'Exemplo de rotina para mover pedidos de 6 meses para outra tabela
    On Error GoTo Err_Mover

    'Primeiro confirmação da operação
    If MsgBox("Deseja excluir os pedidos dos últimos seis meses?", vbQuestion + vbYesNo, strTitle) = vbYes Then

        Dim SQL As String, numDias As Integer 'Declaração das variáveis necessárias à rotina
        numDias = 180 'Atribuição de dias, que pode ser obtida através de um inputbox, por exemplo
        'numDias = InputBox("Informe a quantidade de meses desejada.", strTitle) * 30 'Este é um teste

        DoCmd.SetWarnings False 'Retirar aviso de execução de query

        'Consulta que copia as informação da tabela A para a tabela B
        SQL = "INSERT INTO tblPedidos_BKP ( NrPedido, IDCliente, IDFuncionario, DtPedido, DtEntrega, " & _
        "DtEnvio, Destinatario, Endereco, Cidade, Estado, CEP, Pais, ValorAPagar ) SELECT tblPedidos.NrPedido, " & _
        "tblPedidos.IDCliente, tblPedidos.IDFuncionario, tblPedidos.DtPedido, tblPedidos.DtEntrega, tblPedidos.DtEnvio, " & _
        "tblPedidos.Destinatario, tblPedidos.Endereco, tblPedidos.Cidade, tblPedidos.Estado, tblPedidos.CEP, " & _
        "tblPedidos.Pais, tblPedidos.ValorAPagar From tblPedidos WHERE (((tblPedidos.DtPedido)<Date()-" & numDias & "));"
        DoCmd.RunSQL SQL

        'Após a cópia das informações de A para B, basta deletar as informações de A
        SQL = "DELETE tblPedidos.NrPedido, tblPedidos.IDCliente, tblPedidos.IDFuncionario, tblPedidos.DtPedido, " & _
        "tblPedidos.DtEntrega, tblPedidos.DtEnvio, tblPedidos.Destinatario, tblPedidos.Endereco, tblPedidos.Cidade, " & _
        "tblPedidos.Estado, tblPedidos.CEP, tblPedidos.Pais, tblPedidos.ValorAPagar From tblPedidos " & _
        "WHERE (((tblPedidos.DtPedido)<Date()-" & numDias & "));"
        DoCmd.RunSQL SQL

        'Finalização do processo
        MsgBox "Processo realizado com sucesso!", vbInformation, strTitle

    Else

        Exit Sub

    End If


Exit_Mover:
    Exit Sub

Err_Mover:
    modMsgErr

Resume Exit_Mover

End Sub[/Code]

 

 

Logo após, basta atribuir estas ações à um objeto do formulário:

 

[Code]Private Sub moverCommand_Click()

Call modMover

End Sub[/Code]

 

 

 

 

Sem mais,

 

Julien Sorel

[Elias Sabbag 0]

Ola Maicon

 

Já consegui resolver o problema.

 

Obrigado pela sua atenção

 

Abraços

Elias