Como fazer esse calculo?

[WellingtonSG 0]

Bom pessoal, Tenho esse excercicio:

 

 

Código do Produto Tipo da Carga Preço Unitário

1 Cachorro Quente R$ 4,00

2 X-Salada R$ 4,50

3 X-Frango R$ 5,00

4 Torrada Simples R$ 2,00

5 Refrigerante R$ 1,50

 

 

Escrever um algoritmo, utilizando o AMBAP, que apresente as informações da tabela acima ao usuário e leia os seguintes dados:

 

o código do produto (de 1 a 5);

a quantidade do produto.

 

e calcule o preço final da compra, apresentando este para o usuário.

Considere ainda que:

se o código do produto for 1, 2, 3 ou 4, perguntar ao usuário se ele deseja comprar junto um refrigerante, se o usuário responder sim, dar um desconto de 5% sobre o preço final;

se o preço final ultrapassar R$ 20,00, é dado um desconto de 10% sobre este (mesmo que já tenha sido dado o desconto de 5% anteriormente).

 

Já fiz quase tudo, menos o final:

variaveis
	   numerico p1,p2,p3,p4,p5,preco_final,quantidade,final_2,final_3, pedido
	   caracter resposta,total
Inicio 
	  escrever "Lista de Produtos"
	  escrever "p1 Cachorro Quente R$ 4,00 unidade"
	  escrever "p2 X-salada R$ 4,50 unidade"
	  escrever "p3 X-Frango R$ 5,00 unidade"
	  escrever "p4 Torrada Simples R$ 2,00 unidade"
	  escrever "p5 Refrigerante R$ 1,50 unidade"
	  escrever "Qual o Pedido?"
	  ler pedido
	  escrever "Quantidade do pedido"
	  ler quantidade
	  se (pedido "p1")entao
		  final:=4*quantidade
	  fim_se
	  Se (pedido "p2")entao
		  final:=4.5*quantidade
	  fim_se
	  Se (pedido "p3")entao
		  final:=5.00*quantidade
	  fim_se
	  Se (pedido "p4")entao
		  final:=1.50*quantidade
	  fim_se
	  
	  se (pedido "p1") ou (pedido "p2") ou (pedido "p3") ou (pedido "p4") ou (pedido "p5")entao
	  escrever " Gostaria de acrescentar um refrigerante?"
	  ler resposta
	  fim_se
	  se (resposta = "Nao")entao
	  escrever "total"
	  escrever total
	  fim_se	  
	  senao
	  se (resposta = "Sim")entao
	  final_2:=(final+1.5)*0.95

Tem algum erro, e não tive uma ideia de como fazer o final

 

Obrigado

[quitZAUMMM 18]

ql o erro apresentado?

oq ele ainda num ta fazendo correto?

 

[]s

[Arnaldo M. Hidalgo Jr. 0]

Amigo, utilizando programação algoritmica (baseado no VisualG), esse código ficaria da seguinte forma:

 

algoritmo "Imasters"
// Função :
// Autor :
// Data : 19/03/2009
// Seção de Declarações
var
  codigo : inteiro //receberá o código do produto que pode variar de 1 a 5.
  qtdeproduto : inteiro //receberá a quantidade de produto que você necessita comprar
  total : real // irá calcular o total baseado na quantia de produtos e do preço
  qtderefr : inteiro //receberá qtos refrigerantes foram solicitados
  SN : caractere // receberá S para SIM e N para NÃO
inicio
	  LimpaTela
	  Escreval ("Lista de Produtos") // escreve informacoes entre aspas e muda de linha
	  Escreval ("1 - Cachorro Quente - Unidade: R$4,00")
	  Escreval ("2 - X-Salada		- Unidade: R$4,50")
	  Escreval ("3 - X-Frango		- Unidade: R$5,00")
	  Escreval ("4 - Torrada Simples - Unidade: R$2,00")
	  Escreval ("5 - Refrigerante	- Unidade: R$1,50")
	  Escreva ("Escolha seu produto pelo código... (1 a 5): ")
	  Leia (Codigo)
	  Se ((Codigo >= 1) e (Codigo <= 5)) entao
		 Escreva ("Informe a quantidade de produtos: ")
		 Leia (QtdeProduto)
		 Se (Codigo = 1) entao
			total <- QtdeProduto * 4
		 FimSe
		 Se (Codigo = 2) entao
			 total <- QtdeProduto * 4.5
		 FimSe
		 Se (Codigo = 3) entao
			 total <- QtdeProduto * 5
		 FimSe
		 Se (Codigo = 4) entao
			 total <- QtdeProduto * 2
		 FimSe
		 Se (Codigo = 5) entao
			 total <- QtdeProduto * 1.5
		 FimSe
		 Escreval ("O total gasto até aqui com a compra de ",qtdeproduto," do código ",codigo," foi de ",total)
		 Se ((Codigo >= 1) e (Codigo <= 4)) entao
			Escreva ("Deseja levar um refrigerante da promocao? ")
			Leia (SN)
			Se (SN = "S") entao
			   Escreva ("Quantos produtos deseja comprar? ")
			   Leia (QtdeRefr)
			   total <- total+(qtderefr*1.5) //Atualiza o total e soma a compra de refrigerantes
			   total <- total*0.95  //Computa o desconto de 5% sobre o total por ter participado da promoção
			FimSe
		 FimSe
		 Escreval("Sua compra até aqui está no valor de ",total)
		 Se (total >= 20) entao
			 total <- total * 0.9 //Desconto de 10% por ter ultrapassado R$20,00
			 Escreval ("Já que sua compra passou de R$20,00 estamos dando um desconto de 10%.")
			 Escreval ("Total atual: ",total)
		 FimSe
		 Senao
		   Escreva ("Opcao invalida. Finalizando o programa.")
	  FimSe
fimalgoritmo

 

Analise-o e qualquer dúvida me avise, abraços