Recuperar valores de form multipart

[FabianoSouza 5]

Eu uso um form multipart para poder enviar dados e arquivo junto.

Para manipular o arquivo (imagem) uso um script para fazer upload sem uso de componentes. Tudo funciona.
Só ocorre erro quando tento recuperar valores de checkbox e radio se não estiverem marcados.

 

Queria saber se alguém pode ter ideia  onde possa estar o problema.

 

 

Para recuperar o valor dos campos uso dessa forma:

 

	Dim byteCount
	byteCount = Request.TotalBytes
	RequestBin = Request.BinaryRead(byteCount)
	Set UploadRequest = CreateObject("Scripting.Dictionary")
	BuildUploadRequest RequestBin

'Aqui recupero os valores do form
nome = UploadRequest.Item("nome").Item("Value")
dataNascimento = UploadRequest.Item("dataNascimento").Item("Value")

'Aqui ocorre erro se o checkbox do form não estiver marcado
favorito = UploadRequest.Item("favorito").Item("Value")

 

A "biblioteca" que faz o upload é essa (eu uso como um include):

 

<%
' Upload Sem componentes ---------------------------------------
Sub BuildUploadRequest(RequestBin)
on error resume next

PosBeg = 1
PosEnd = InStrB(PosBeg, RequestBin, getByteString(Chr(13)))
boundary = MidB(RequestBin, PosBeg, PosEnd - PosBeg)
BoundaryPos = InStrB(1, RequestBin, boundary)

Do Until (BoundaryPos = InStrB(RequestBin, boundary & getByteString("--")))

Dim UploadControl
Set UploadControl = CreateObject("Scripting.Dictionary")

Pos = InStrB(BoundaryPos, RequestBin, getByteString("Content-Disposition"))
Pos = InStrB(Pos, RequestBin, getByteString("name="))
PosBeg = Pos + 6
PosEnd = InStrB(PosBeg, RequestBin, getByteString(Chr(34)))
Name = getString(MidB(RequestBin, PosBeg, PosEnd - PosBeg))
PosFile = InStrB(BoundaryPos, RequestBin, getByteString("filename="))
PosBound = InStrB(PosEnd, RequestBin, boundary)

If PosFile <> 0 And (PosFile < PosBound) Then
PosBeg = PosFile + 10
PosEnd = InStrB(PosBeg, RequestBin, getByteString(Chr(34)))
FileName = getString(MidB(RequestBin, PosBeg, PosEnd - PosBeg))
UploadControl.Add "FileName", FileName
Pos = InStrB(PosEnd, RequestBin, getByteString("Content-Type:"))
PosBeg = Pos + 14
PosEnd = InStrB(PosBeg, RequestBin, getByteString(Chr(13)))
ContentType = getString(MidB(RequestBin, PosBeg, PosEnd - PosBeg))
UploadControl.Add "ContentType", ContentType

PosBeg = PosEnd + 4
PosEnd = InStrB(PosBeg, RequestBin, boundary) - 2
Value = MidB(RequestBin, PosBeg, PosEnd - PosBeg)
Else
Pos = InStrB(Pos, RequestBin, getByteString(Chr(13)))
PosBeg = Pos + 4
PosEnd = InStrB(PosBeg, RequestBin, boundary) - 2
Value = getString(MidB(RequestBin, PosBeg, PosEnd - PosBeg))
End If

UploadControl.Add "Value", Value
UploadRequest.Add Name, UploadControl
BoundaryPos = InStrB(BoundaryPos + LenB(boundary), RequestBin, boundary)
Loop
End Sub

Function getByteString(StringStr)
For i = 1 To Len(StringStr)
Char = Mid(StringStr, i, 1)
getByteString = getByteString & ChrB(AscB(Char))
Next
End Function

Function getString(StringBin)
getString = ""
For intCount = 1 To LenB(StringBin)
getString = getString & Chr(AscB(MidB(StringBin, intCount, 1)))
Next
End Function
Server.ScriptTimeout=900
' Fim upload sem Componentes -----------------------------------------
%>

 

 

[s3c0 0]

boa noite @FabianoSouza

 

já tentou recuperar com checked? 

favorito = UploadRequest.Item("favorito").Item("checked")

 

 

[FabianoSouza 5]

Olá s3c0.

 

Já testei dessa maneira que sugeriu. Não funcionou.

Se eu usar

favorito = UploadRequest.Item("favorito").Item("checked")

o checkbox precisa estar sempre marcado, senão ocorre erro.

 

Consegui resolver usando isso.

 

  If UploadRequest.Exists("favorito") Then : favorito = 1 : Else : favorito = 0 : End if	

A lógica é:

-Se checkbox "favorito" existir (equivale a estar marcado no HTML) então faça a variável favorito = 1

-Se checkbox "favorito" não existir (equivale a não estar marcado no HTML) então faça a variável favorito = 0

 

Acho essa solução meio gambiarra. Mas resolveu.

 

 

Agora estou enfrentando problema com charset (trunca o texto em palavras com acento).

Já coloquei isso no topo da página e não resolveu :-( 
Se puder ajudar isso ficarei muuuuuito agradecido hehehe

Response.AddHeader "Content-Type", "text/html;charset=UTF-8" 'caractéres em PT-BR
Response.ContentType = "text/html"
Response.CharSet = "UTF-8"